循環聲音，但整理最後一次迭代

Question

我想要做的是在鼠標向下事件上循環播放聲音，然後在鼠標向上事件中，我想完成它正在進行的迭代並停止循環。

下面的邏輯應該可以工作，但我不知道爲什麼它不是。

import flash.events.MouseEvent; 
import flash.media.Sound; 
import flash.events.Event; 
import flash.media.SoundChannel; 

//ExplosionSound is .wav file linked in my library. 
var s:Sound=new ExplosionSound(); 
var sc:SoundChannel = new SoundChannel(); 

stage.addEventListener(MouseEvent.MOUSE_DOWN, loopSound); 
stage.addEventListener(MouseEvent.MOUSE_UP, stopLoop); 

function loopSound(e:MouseEvent):void { 
    sc=s.play(0,9999); 

} 

function stopLoop(e:MouseEvent):void { 
    sc.addEventListener(Event.SOUND_COMPLETE, soundCompleteHandler); 
} 

function soundCompleteHandler(e:Event):void{ 
    sc.removeEventListener(Event.SOUND_COMPLETE, soundCompleteHandler); 
    sc.stop(); 
} 

我只能把sc.stop（）;在我的stopLoop（）函數中，但立即停止聲音。

例如，我需要的是：假設您有機槍射擊，當您停止拍攝時，最後一個子彈聲音不會立即停止，它會結束。

希望這是有道理的。

謝謝你的一切幫助。

Answer 1

SOUND_COMPLETE「never」在循環聲音時被觸發 - 只會在第9999次循環後觸發。所以你必須要解決此問題：

import flash.events.MouseEvent; 
import flash.media.Sound; 
import flash.events.Event; 
import flash.media.SoundChannel; 

//ExplosionSound is .wav file linked in my library. 
var s:Sound=new ExplosionSound(); 
var sc:SoundChannel = new SoundChannel(); 

var isMouseDown:Boolean = false; 

stage.addEventListener(MouseEvent.MOUSE_DOWN, loopSound); 
stage.addEventListener(MouseEvent.MOUSE_UP, onMouseUpHandler); 

function loopSound(e:MouseEvent):void { 
    isMouseDown = true; 
    playSound(); 
} 

function playSound():void 
{ 
    sc=s.play(0); 
    sc.addEventListener(Event.SOUND_COMPLETE, soundCompleteHandler); 
} 

function onMouseUpHandler(e:MouseEvent):void { 
    isMouseDown = false; 
} 

function soundCompleteHandler(e:Event):void{ 
    sc.removeEventListener(Event.SOUND_COMPLETE, soundCompleteHandler); 
    sc.stop(); 

    if (isMouseDown) 
    { 
     playSound(); 
    } 
} 

只播放聲音一次在鼠標按下（但保持一個標誌鼠標是否仍然向下），並添加一個SOUND_COMPLETE處理程序。如果聲音完成並且鼠標仍然關閉，請重播聲音。如果鼠標按鈕被釋放，則標誌被重置，並且完成時聲音不會重播。tataaaaa