sys_execve系統調用

Question

asm_execve.s：

 
.section .data 
file_to_run: 
.ascii  "/bin/sh" 

.section .text 
.globl main 

main: 
    pushl %ebp 
    movl %esp, %ebp 
    subl $0x8, %esp   # array of two pointers. array[0] = file_to_run array[1] = 0 

    movl file_to_run, %edi 
    movl %edi, -0x4(%ebp) 
    movl $0, -0x8(%ebp) 

    movl $11, %eax      # sys_execve 
    movl file_to_run, %ebx    # file to execute  
    leal -4(%ebp), %ecx     # command line parameters 
    movl $0, %edx      # environment block 
    int $0x80    

    leave 
    ret 

生成文件：

 
NAME = asm_execve 
$(NAME) : $(NAME).s 
    gcc -o $(NAME) $(NAME).s 

程序被執行，但sys_execve不叫：

 
alex@alex32:~/project$ make 
gcc -o asm_execve asm_execve.s 
alex@alex32:~/project$ ./asm_execve 
alex@alex32:~/project$ 

預期成果是：

 
alex@alex32:~/project$ ./asm_execve 
$ exit 
alex@alex32:~/project$ 

本屆大會的程序應該像下面的C代碼工作：

 
char *data[2]; 
data[0] = "/bin/sh"; 
data[1] = NULL; 
execve(data[0], data, NULL); 

一些錯誤的系統調用的參數？

Answer 1

execve系統調用是被調用，但你的確在傳遞它壞的參數。

（您可以通過使用strace運行可執行文件看到這一點。）

有三個問題：

1. .ascii沒有0結束的字符串。 （您可能會很幸運，因爲在本例中您的.data部分沒有任何內容，但不能保證......）添加0或使用.asciz（或.string）代替。

2. movl file_to_run, %edi移動指向由file_to_run符號到%edi值，即第一個4個字節串（0x6e69622f）的。該字符串的地址只是該符號本身的值，因此您需要使用$前綴的文字值：movl $file_to_run, %edi。同樣，你需要在下面說幾句movl $file_to_run, %ebx。 （這是AT & T語法和Intel語法之間的混淆的常見來源！）

3. 的參數被放置在錯誤的順序在堆棧上：-0x8(%ebp)比-0x4(%ebp)低位地址。所以命令字符串的地址應該寫入-0x8(%ebp)，0應該寫入-0x4(%ebp)，並且leal指令應該是leal -8(%ebp), %ecx。

---

固定碼：

.section .data 
file_to_run: 
.asciz  "/bin/sh" 

.section .text 
.globl main 

main: 
    pushl %ebp 
    movl %esp, %ebp 
    subl $0x8, %esp   # array of two pointers. array[0] = file_to_run array[1] = 0 

    movl $file_to_run, %edi 
    movl %edi, -0x8(%ebp) 
    movl $0, -0x4(%ebp) 

    movl $11, %eax      # sys_execve 
    movl $file_to_run, %ebx    # file to execute  
    leal -8(%ebp), %ecx     # command line parameters 
    movl $0, %edx      # environment block 
    int $0x80    

    leave 
    ret 

Answer 2

你其實並不需要在其他參數加載任何東西。如果你在86做這下面簡單的代碼也將工作：

.global _main 
.section .text 

.data 
file_to_run: 
.asciz "/bin/sh" 

.section .text 
.globl main 

_main: 
pushl %ebp 
movl %esp, %ebp 

movl $11, %eax      # sys_execve 
movl $file_to_run, %ebx    # file to execute  
movl $0, %ecx      # Null value will work too 
movl $0, %edx      # Null will works too 
int $0x80    

leave 
ret 

調用系統調用後，這將從根本上打開一個shell終端。