提取的記錄特定多行被管在Perl

Question

分隔我有一個看起來像

NAME|JOHN|TOKYO|JPN 
AGE|32|M 
INFO|SINGLE|PROFESSIONAL|IT 
NAME|MARK|MANILA|PH 
AGE|37|M 
INFO|MARRIED|PROFESSIONAL|BPO 
NAME|SAMANTHA|SYDNEY|AUS 
AGE|37|F 
INFO|MARRIED|PROFESSIONAL|OFFSHORE 
NAME|LUKE|TOKYO|JPN 
AGE|27|M 
INFO|SINGLE|PROFESSIONAL|IT

我想國家的記錄分開的文件。我已存儲的每一行到數組變量@fields

my @fields = split(/\|/, $_); 

使得$fields[3]作爲我的用於分選它的基礎。我想它分成2個輸出文本文件

輸出文本文件1：

NAME|JOHN|TOKYO|JPN 
AGE|32|M 
INFO|SINGLE|PROFESSIONAL|IT 
NAME|LUKE|TOKYO|JPN 
AGE|27|M 
INFO|SINGLE|PROFESSIONAL|IT 

輸出文本文件2

NAME|MARK|MANILA|PH 
AGE|37|M 
INFO|MARRIED|PROFESSIONAL|BPO 
NAME|SAMANTHA|SYDNEY|AUS 
AGE|37|F 
INFO|MARRIED|PROFESSIONAL|OFFSHORE 

把所有從JPN輸出文本1 &非JPN國家輸出文本文件2

這裏的代碼是什麼試圖解決

use strict; 
use warnings; 
use Data::Dumper; 
use Carp qw(croak); 

my @fields; 
my $tmp_var; 
my $count; 
; 
my ($line, $i); 

my $filename = 'data.txt'; 
open(my $input_fh, '<', $filename) or croak "Can't open $filename: $!"; 


open(OUTPUTA, ">", 'JPN.txt') or die "wsl_reformat.pl: could not open $ARGV[0]"; 
open(OUTPUTB, ">", 'Non-JPN.txt') or die "wsl_reformat.pl: could not open $ARGV[0]"; 

my $fh; 
while (<$input_fh>) { 

    chomp; 
    my @fields = split /\|/; 


    if ($fields[0] eq 'NAME') { 
    for ($i=1; $i < @fields; $i++) { 
     if ($fields[3] eq 'JPN') { 
      $fh = $_; 
      print OUTPUTA $fh; 
     } 
     else { 
      $fh = $_; 
      print OUTPUTB $fh; 
     } 
    } 

} 
} 

close(OUTPUTA); 
close(OUTPUTB) 

仍然沒有運氣就可以了:(

Answer 1

這裏是我想池上是說的方式，但在此之前我從來沒有嘗試過這一點（雖然它給出了正確的結果）。

#!/usr/bin/perl 
use strict; 
use warnings; 

open my $jpn_fh, ">", 'o33.txt' or die $!; 
open my $other_fh, ">", 'o44.txt' or die $!; 

my $fh; 
while (<DATA>) { 
    if (/^NAME/) { 
     if (/JPN$/) { 
      $fh = $jpn_fh; 
     } 
     else { 
      $fh = $other_fh; 
     } 
    } 
    print $fh $_; 
} 

close $jpn_fh or die $!; 
close $other_fh or die $!; 

__DATA__ 
NAME|JOHN|TOKYO|JPN 
AGE|32|M 
INFO|SINGLE|PROFESSIONAL|IT 
NAME|MARK|MANILA|PH 
AGE|37|M 
INFO|MARRIED|PROFESSIONAL|BPO 
NAME|SAMANTHA|SYDNEY|AUS 
AGE|37|F 
INFO|MARRIED|PROFESSIONAL|OFFSHORE 
NAME|LUKE|TOKYO|JPN 
AGE|27|M 
INFO|SINGLE|PROFESSIONAL|IT 

Answer 2

你沒有說你需要哪方面的幫助，所以我假設它的未來與算法。這裏有一個好的：

1. 打開文件進行閱讀。
2. 打開JPN條目的文件。
3. 打開非JPN條目的文件。
4. 雖然不是eof，
   1. 閱讀一條線。
   2. 解析該行。
   3. 如果它是一個記錄的第一線，
      1. 如果使用者的國家是JPN，
         1. 設置當前文件句柄爲JPN項文件句柄。
      2. 否則，
         1. 設置當前文件句柄到非JPN項的文件句柄。
   4. 將行打印到當前文件句柄。

---

my $jpn_qfn = '...'; 
my $other_qfn = '...'; 

open(my $jpn_fh, '>', $jpn_qfn) 
    or die("Can't create $jpn_qfn: $!\n"); 
open(my $other_fh, '>', $other_qfn) 
    or die("Can't create $other_qfn: $!\n"); 

my $fh; 
while (<>) { 
    chomp; 
    my @fields = split /\|/; 
    if ($fields[0] eq 'NAME') { 
     $fh = $fields[3] eq 'JPN' ? $jpn_fh : $other_fh; 
    } 

    say $fh $_; 
} 

Answer 3

#!/usr/bin/env perl 

use 5.012; 
use autodie; 
use strict; 
use warnings; 

# store per country output filehandles 
my %output; 

# since this is just an example, read from __DATA__ section 

while (my $line = <DATA>) { 
    # split the fields 
    my @cells = split /[|]/, $line; 

    # if first field is NAME, this is a new record 
    if ($cells[0] eq 'NAME') { 
     # get the country code, strip trailing whitespace 
     (my $country = $cells[3]) =~ s/\s+\z//; 

     # if we haven't created and output file for this 
     # country, yet, do so 
     unless (defined $output{$country}) { 
      open my $fh, '>', "$country.out"; 
      $output{$country} = $fh; 
     } 
     my $out = $output{$country}; 

     # output this and the next two lines to 
     # country specific output file 
     print $out $line, scalar <DATA>, scalar <DATA>; 
    } 
} 

close $_ for values %output; 

__DATA__ 
NAME|JOHN|TOKYO|JPN 
AGE|32|M 
INFO|SINGLE|PROFESSIONAL|IT 
NAME|MARK|MANILA|PH 
AGE|37|M 
INFO|MARRIED|PROFESSIONAL|BPO 
NAME|SAMANTHA|SYDNEY|AUS 
AGE|37|F 
INFO|MARRIED|PROFESSIONAL|OFFSHORE 
NAME|LUKE|TOKYO|JPN 
AGE|27|M 
INFO|SINGLE|PROFESSIONAL|IT 

Answer 4

感謝您的幫助堆 我能夠在Perl解決了這個問題， 千恩萬謝

#!/usr/local/bin/perl 

use strict; 
use warnings; 
use Data::Dumper; 
use Carp qw(croak); 

my @fields; 
my $tmp_var; 
my ($rec_type, $country); 

my $filename = 'data.txt'; 


open (my $input_fh, '<', $filename) or croak "Can't open $filename: $!"; 


open my $OUTPUTA, ">", 'o33.txt' or die $!; 
open my $OUTPUTB, ">", 'o44.txt' or die $!; 

my $Combline; 
while (<$input_fh>) { 

    $_ = _trim($_); 
    @fields = split (/\|/, $_); 
    $rec_type = $fields[0]; 
    $country = $fields[3]; 

     if ($rec_type eq 'NAME') {   
      if ($country eq 'JPN') {        
       *Combline = $OUTPUTA; 
      }   
      else {        
       *Combline = $OUTPUTB; 
      } 
     }  
    print Combline; 
} 

close $OUTPUTA or die $!; 
close $OUTPUTB or die $!; 

sub _trim { 
    my $word = shift; 
    if ($word) {  
     $word =~ s/\s*\|/\|/g;  #remove trailing spaces 
     $word =~ s/"//g;  #remove double quotes 
    } 
    return $word; 
}