季度開始MS Access人年齡

Question

我有一個表（Service_records），其中包含以下字段;

客戶ID
年
季度（Q1，Q2，Q3，Q4）
服務
成本

還有一個表（Customer_records）與客戶的個人信息如名稱和DoB通過客戶ID鏈接到後續查詢中的上表）。

我也有一張表格，列出財政年度（Financial_years），例如

2015/16
2016/17
十八分之二千零十七

我創建了一個簡單的表格，有一個組合框，將顯示財政年度，然後一個按鈕打開一個查詢。

查詢目前是一個交叉表查詢與所有上述的表，它顯示了像

服務作爲行和區如列------------- --- Q1 -Q2 --- Q3 --- Q4
服務1 |
服務2 |
服務3 |

我想要做的是統計當年30-35歲（在本季度第一天> 30天）所選服務年份的客戶ID數量，我們的季度運行Q1-Apr-June，Q2-July-Sep，Q3-Sep-Dec，Q1-Mar-4。

可以這樣做嗎？

Answer 1

你首先需要一個函數來正確計算完全歲這樣的：

Public Function Years(_ 
    ByVal datDate1 As Date, _ 
    ByVal datDate2 As Date, _ 
    Optional ByVal booLinear As Boolean) _ 
    As Integer 

' Returns the difference in full years between datDate1 and datDate2. 
' 
' Calculates correctly for: 
' negative differences 
' leap years 
' dates of 29. February 
' date/time values with embedded time values 
' negative date/time values (prior to 1899-12-29) 
' 
' Optionally returns negative counts rounded down to provide a 
' linear sequence of year counts. 
' For a given datDate1, if datDate2 is decreased step wise one year from 
' returning a positive count to returning a negative count, one or two 
' occurrences of count zero will be returned. 
' If booLinear is False, the sequence will be: 
' 3, 2, 1, 0, 0, -1, -2 
' If booLinear is True, the sequence will be: 
' 3, 2, 1, 0, -1, -2, -3 
' 
' If booLinear is False, reversing datDate1 and datDate2 will return 
' results of same absolute Value, only the sign will change. 
' This behaviour mimics that of Fix(). 
' If booLinear is True, reversing datDate1 and datDate2 will return 
' results where the negative count is offset by -1. 
' This behaviour mimics that of Int(). 

' DateAdd() is used for check for month end of February as it correctly 
' returns Feb. 28. when adding a count of years to dates of Feb. 29. 
' when the resulting year is a common year. 
' 
' 2007-11-13. Cactus Data ApS, CPH. 

    Dim intDiff As Integer 
    Dim intSign As Integer 
    Dim intYears As Integer 

    ' Find difference in calendar years. 
    intYears = DateDiff("yyyy", datDate1, datDate2) 
    ' For positive resp. negative intervals, check if the second date 
    ' falls before, on, or after the crossing date for a full 12 months period 
    ' while at the same time correcting for February 29. of leap years. 
    If DateDiff("d", datDate1, datDate2) > 0 Then 
    intSign = Sgn(DateDiff("d", DateAdd("yyyy", intYears, datDate1), datDate2)) 
    intDiff = Abs(intSign < 0) 
    Else 
    intSign = Sgn(DateDiff("d", DateAdd("yyyy", -intYears, datDate2), datDate1)) 
    If intSign <> 0 Then 
     ' Offset negative count of years to continuous sequence if requested. 
     intDiff = Abs(booLinear) 
    End If 
    intDiff = intDiff - Abs(intSign < 0) 
    End If 

    ' Return count of years as count of full 12 months periods. 
    Years = intYears - intDiff 

End Function 

然後創建一個函數來計算你的宿舍的開始日期，例如：

Public Function CalendarQuarterStart(_ 
    ByVal FinancialYear As String, _ 
    ByVal FinancialQuarter As String) _ 
    As Date 

    Dim CalendarYear As Integer 
    Dim CalendarMonth As Integer 
    Dim DateStart As Date 

    CalendarYear = Val(FinancialYear) ' "2015/16" 
    CalendarMonth = 1 + 3 * Right(FinancialQuarter, 1) ' "Q3" 

    DateStart = DateSerial(CalendarYear, CalendarMonth, 1) 

    CalendarQuarterStart = DateStart 

End Function 

因此，在你的查詢中：

Age: Years([DateOfBirth], CalendarQuarterStart([FinancialYear],[FinancialQuarter]))