如何插入Julia「for」表達式？

Question

我正在寫一個基於Python的列表解析和一個條件子句以簡潔的方式過濾元素的宏@vcomp（矢量解釋）。

macro vcomp(comprehension::Expr, when::Symbol, condition) 
    comp_head, comp_args = comprehension.head, comprehension.args 
    comp_head ∉ [:comprehension, :typed_comprehension] && error("@vcomp not a comprehension") 
    when ≠ :when && error("@vcomp expected `when`, got: `$when`") 
    T = comp_head == :typed_comprehension ? comp_args[1] : nothing 
    if VERSION < v"0.5-" 
     element = comp_head == :comprehension ? comp_args[1] : comp_args[2] 
     sequence = comp_head == :comprehension ? comp_args[2] : comp_args[3] 
    else 
     element = comp_head == :comprehension ? comp_args[1].args[1] : comp_args[2].args[1] 
     sequence = comp_head == :comprehension ? comp_args[1].args[2] : comp_args[2].args[2] 
    end 
    result = T ≠ nothing ? :($T[]) : :([]) 
    block = Expr(:let, Expr(:block, 
       Expr(:(=), :res, result), 
       Expr(:for, sequence, 
        Expr(:if, condition, 
         Expr(:call, :push!, :res, element))), 
       :res)) 
    return esc(block) 
end 

像這樣來使用：

julia> @vcomp Int[i^3 for i in 1:10] when i % 2 == 0 
5-element Array{Int64,1}: 
    8 
    64 
    216 
    512 
1000 

哪個擴展成：

julia> macroexpand(:(@vcomp Int[i^3 for i in 1:15] when i % 2 == 0)) 
:(let 
     res = Int[] 
     for i = 1:15 
      if i % 2 == 0 
       push!(res,i^3) 
      end 
     end 
     res 
    end) 

我期待能夠寫block這樣的：

block = quote 
    let 
     res = $result 
     for $sequence 
      if $condition 
       push!(res, $element) 
      end 
     end 
     res 
    end 
end 

其中提供了以下錯誤：

• ERROR: syntax: invalid iteration specification

相反的方式，我想出了：

block = Expr(:let, Expr(:block, 
      Expr(:(=), :res, result), 
      Expr(:for, sequence, 
       Expr(:if, condition, 
        Expr(:call, :push!, :res, element))), 
      :res)) 

但是我能夠使用Expr(:for, ...)直接做如上圖所示並據我瞭解這是一個解析器錯誤（這是一個錯誤？）。我也一直無法找到這種插值法的例子，這是我已經試過：

julia> ex₁ = :(i in 1:10) 
:($(Expr(:in, :i, :(1:10)))) 

julia> ex₂ = :(i = 1:10) 
:(i = 1:10) 

julia> quote 
      for $ex₁ 
ERROR: syntax: invalid iteration specification 

julia> quote 
      for $ex₂ 
ERROR: syntax: invalid iteration specification 

構建整個表達式並檢查：

julia> ex₃ = quote 
      for i in 1:10 
       print(i) 
      end 
     end 
quote # none, line 2: 
    for i = 1:10 # none, line 3: 
     print(i) 
    end 
end 

julia> ex₃.args 
2-element Array{Any,1}: 
:(# none, line 2:) 
:(for i = 1:10 # none, line 3: 
     print(i) 
    end) 

julia> ex₃.args[2].args 
2-element Array{Any,1}: 
:(i = 1:10) 
quote # none, line 3: 
    print(i) 
end 

julia> ex₃.args[2].args[1] 
:(i = 1:10) 

julia> ex₃.args[2].args[1] == ex₂ # what's the difference then? 
true 

這工作，但就是不易閱讀：

julia> ex₄ = Expr(:for, ex₁, :(print(i))) 
:(for $(Expr(:in, :i, :(1:10))) 
     print(i) 
    end) 

julia> ex₅ = Expr(:for, ex₂, :(print(i))) 
:(for i = 1:10 
     print(i) 
    end) 

julia> eval(ex₃) 
12345678910 
julia> eval(ex₄) 
12345678910  
julia> eval(ex₅) 
12345678910  

有沒有一種方法可以使用更簡潔的語法呢？與我期待寫的相比，我發現目前的實現難以閱讀和推理。

Answer 1

首先，我相信帶衛兵的理解來到茱莉亞（v0.5？）。

要回答您的問題：解析器希望能夠驗證其輸入在語法上是否正確，而無需查看插值的實際值。試試例如：

x, y = :i, :(1:10) 
quote 
    for $x = $y 
    end 
end 

現在解析器可以識別語法的相關部分。 （如果你使用for $x in $y代替，你應該得到相同的AST。）