接受所有表字段並更新這些值

Question

我通過幾個練習題工作，我已經過這個問題上運行存儲過程，我不斷收到試圖執行，說

程序時出現錯誤

消息156，級別15，狀態1，第1行的關鍵字 '過程'。」近
語法不正確

是否有人可以幫助？

寫程序UpdateTitle接受所有Title表列，並將用這些值更新標題。引發以下錯誤消息：ISBN不存在類別和/或發佈者代碼無效。

Create PROCEDURE UpdateTitle (@ISBN char(10), @SuggestedPrice smallmoney,@NumberInStock smallint,@PublisherCode int,@CategoryCode int) 
AS 
BEGIN 
IF @ISBN is null or @CategoryCode is null or @PublisherCode is null 
BEGIN 
RAISERROR ('ISBN,CategoryCode, or PublisherCode is not valid please enter valid data',16,1) 
END 
ELSE 
BEGIN  
IF (SELECT COUNT(*) FROM Title WHERE ISBN = @ISBN) = 0 
BEGIN 
    RAISERROR ('ISBN does not exist.',16,1) 
END 
ELSE 
BEGIN 
    SELECT 'Table Sucessfully Updated.'; 
    UPDATE Title 
    SET SuggestedPrice = @SuggestedPrice 
    WHERE ISBN = @ISBN; 

    BEGIN 
    IF (SELECT COUNT(*) FROM Title WHERE ISBN = @ISBN) = 0 
    BEGIN 
    RAISERROR ('ISBN does not exist.',16,1) 
END 
ELSE 
BEGIN 
    SELECT 'Table Sucessfully Updated.'; 
    UPDATE Title 
    SET NumberInStock = @NumberInStock 
    WHERE ISBN = @ISBN; 
    END 

      BEGIN 
    IF (SELECT COUNT(*) FROM Title WHERE ISBN = @ISBN) = 0 
    BEGIN 
    RAISERROR ('ISBN does not exist.',16,1) 
END 
ELSE 
BEGIN 
    SELECT 'Table Sucessfully Updated.'; 
    UPDATE Title 
    SET PublisherCode = @PublisherCode 
    WHERE ISBN = @ISBN; 
    END 
      BEGIN 
    IF (SELECT COUNT(*) FROM Title WHERE ISBN = @ISBN) = 0 
    BEGIN 
    RAISERROR ('ISBN does not exist.',16,1) 
END 
ELSE 
BEGIN 
    SELECT 'Table Sucessfully Updated.'; 
    UPDATE Title 
    SET CategoryCode = @CategoryCode 
    WHERE ISBN = @ISBN; 
    END 

END 
END 
END 
END 
END 
END 
GO 

然後

Execute Procedure UpdateTitle @ISBN ='1021031040', @suggestedproce ='40' , @NumberInStock ='10', @PublisherCode = '200', @CategoryCode = '1' 

Answer 1

Execute Procedure UpdateTitle ... 

應該是：

EXEC dbo.UpdateTitle ... 

一些其他意見：

• ISBN不再侷限於10 CHARACT （this change happened in 2007, if you believe WikiPedia）。
• Always use the schema prefix when creating or referencing objects。
• 您只需檢查ISBN是否有效一次。而且你不應該使用一個計數恕我直言，特別是因爲 - 大概 - 這是關鍵，它只能返回0或1。
• 您不應選擇「更新成功」，然後執行更新。在告訴用戶它已經成功之前，你應該確保更新成功。
• 沒有理由將其分成多個更新。
• 請自由回車，縮進和空格。可讀性的價值是值得輸入它的額外成本（因爲你只輸入一次，但你會多次閱讀它）。
• 使用RETURN;作爲退出機制，以便您不必多次嵌套IF和ELSE。
• 在程序開始時始終使用SET NOCOUNT ON;。
• 您可能想定製消息以告訴用戶哪些參數無效。
• 噢，和please future-proof your code by using semi-colons to terminate statements。

這裏是滿足您的所有需求更加簡潔的版本：

CREATE PROCEDURE dbo.UpdateTitle 
    @ISBN   CHAR(10), 
    @SuggestedPrice SMALLMONEY, 
    @NumberInStock SMALLINT, 
    @PublisherCode INT, 
    @CategoryCode INT 
AS 
BEGIN 
    SET NOCOUNT ON; 

    DECLARE @msg VARCHAR(255); 

    IF @ISBN IS NULL OR @CategoryCode IS NULL OR @PublisherCode IS NULL 
    BEGIN 
    SELECT @msg = 'The following parameter(s) were invalid:' 
     + CASE WHEN @ISBN IS NULL THEN ' @ISBN' ELSE '' END 
     + CASE WHEN @CategoryCode IS NULL THEN ' @CategoryCode' ELSE '' END 
     + CASE WHEN @PublisherCode IS NULL THEN ' @PublisherCode' ELSE '' END; 

    RAISERROR (@msg, 11, 1); 
    RETURN; 
    END 

    IF NOT EXISTS (SELECT 1 FROM dbo.Title WHERE ISBN = @ISBN) 
    BEGIN 
    SET @msg = 'ISBN %s does not exist.'; 
    RAISERROR(@msg, 11, 1, @ISBN); 
    RETURN; 
    END 

    BEGIN TRY 
    UPDATE dbo.Title 
     SET SuggestedPrice = @SuggestedPrice, 
      NumberInStock = @NumberInStock, 
      PublisherCode = @PublisherCode, 
      CategoryCode = @CategoryCode 
     WHERE ISBN = @ISBN; 

    SELECT 'Update successful.'; 
    END TRY 
    BEGIN CATCH 
    SET @msg = ERROR_MESSAGE(); 
    RAISERROR(@msg, 11, 1); 
    END CATCH 
END 
GO