是否有用於轉義HTML的Delphi標準函數？

Question

我有一個報告，應該採取網格控制並生成HTML輸出。網格中的一列可以顯示任意數量的值，或<Any>。當它輸出到HTML時，當然它最終會變成空白。

我可能會寫一些例程來使用StringReplace將其轉換爲<Any>，以便它能夠正確顯示此特定情況，但是我認爲RTL中可能有一個已經過測試並且正確的RTL。任何人都知道我在哪裏可以找到它？

Answer 1

我99％確定這樣的函數在RTL中不存在（截至Delphi 2009）。當然 - 然而，編寫這樣一個函數是微不足道的。

更新

HTTPUtil.HTMLEscape是你正在尋找：

function HTMLEscape(const Str: string): string; 

我不敢在這裏發佈的代碼（侵犯版權，可能），但例程非常簡單。它編碼 ​​「<」， 「>」， 「&」，和 「」」來<，>，&，和"，還替換字符＃92，＃160 ..＃255爲十進制碼，例如\。

後者步驟是不必要的，如果該文件是UTF-8，和還不合邏輯，因爲較高的特殊字符，如∮被原樣保留，而較低的特殊字符，如×，進行編碼。

更新2

爲了迴應Stijn Sanders的回答，我做了一個簡單的性能測試。

program Project1; 

{$APPTYPE CONSOLE} 

uses 
    Windows, SysUtils; 

var 
    t1, t2, t3, t4: Int64; 
    i: Integer; 
    str: string; 
const 
    N = 100000; 


function HTMLEncode(const Data: string): string; 
var 
    i: Integer; 
begin 

    result := ''; 
    for i := 1 to length(Data) do 
    case Data[i] of 
     '<': result := result + '&lt;'; 
     '>': result := result + '&gt;'; 
     '&': result := result + '&amp;'; 
     '"': result := result + '&quot;'; 
    else 
     result := result + Data[i]; 
    end; 

end; 

function HTMLEncode2(Data: string):string; 
begin 
    Result:= 
    StringReplace(
    StringReplace(
    StringReplace(
    StringReplace(
     Data, 
     '&','&amp;',[rfReplaceAll]), 
     '<','&lt;',[rfReplaceAll]), 
     '>','&gt;',[rfReplaceAll]), 
     '"','&quot;',[rfReplaceAll]); 
end; 

begin 

    QueryPerformanceCounter(t1); 
    for i := 0 to N - 1 do 
    str := HTMLEncode('Testing. Is 3*4<3+4? Do you like "A & B"'); 
    QueryPerformanceCounter(t2); 

    QueryPerformanceCounter(t3); 
    for i := 0 to N - 1 do 
    str := HTMLEncode2('Testing. Is 3*4<3+4? Do you like "A & B"'); 
    QueryPerformanceCounter(t4); 

    Writeln(IntToStr(t2-t1)); 
    Writeln(IntToStr(t4-t3)); 

    Readln; 


end. 

輸出是

532031 
801969 

Answer 2

我通常只使用此代碼：

function HTMLEncode(Data:string):string; 
begin 
    Result:= 
    StringReplace(
    StringReplace(
    StringReplace(
    StringReplace(
    StringReplace(
     Data, 
     '&','&',[rfReplaceAll]), 
     '<','&lt;',[rfReplaceAll]), 
     '>','&gt;',[rfReplaceAll]), 
     '"','&quot;',[rfReplaceAll]), 
     #13#10,'<br />'#13#10,[rfReplaceAll]); 
end; 

（？版權是open source）

Answer 3

看來這裏是一個小比賽:)這裏是一個更多的實現：

function HTMLEncode3(const Data: string): string; 
var 
    iPos, i: Integer; 

    procedure Encode(const AStr: String); 
    begin 
    Move(AStr[1], result[iPos], Length(AStr) * SizeOf(Char)); 
    Inc(iPos, Length(AStr)); 
    end; 

begin 
    SetLength(result, Length(Data) * 6); 
    iPos := 1; 
    for i := 1 to length(Data) do 
    case Data[i] of 
     '<': Encode('&lt;'); 
     '>': Encode('&gt;'); 
     '&': Encode('&amp;'); 
     '"': Encode('&quot;'); 
    else 
     result[iPos] := Data[i]; 
     Inc(iPos); 
    end; 
    SetLength(result, iPos - 1); 
end; 

更新1：更新最初提供了不正確的代碼。

更新2：與時代：

HTMLEncode : 2286508597 
HTMLEncode2: 3577001647 
HTMLEncode3: 361039770 

Answer 4

單位HTTPApp有一個稱爲的HTMLEncode功能。它還有其他HTML/HTTP相關功能。

Answer 5

怎麼樣的替代特殊字符的方式：

function HtmlWeg(sS: String): String; 
var 
    ix,cc: Integer; 
    sC, sR: String; 
begin 
    result := sS; 
    ix := pos('\u00',sS); 

    while ix >0 do 
    begin 
    sc := copy(sS,ix+4,2) ; 
    cc := StrtoIntdef('$' +sC,32); 
    sR := '' + chr(cc); 
    sS := Stringreplace(sS, '\u00'+sC,sR,[rfreplaceall]) ; 
    ix := pos('\u00',sS); 
    end; 
    result := sS; 
end; 

Answer 6

我的功能相結合的for循環用字符串的最小再分配：

function HtmlEncode(const Value: string): string; 
var 
    i: Integer; 

begin 
    Result := Value; 
    i := 1; 

    while i <= Length(Result) do 
    begin 
    if Result[i] = '<' then 
    begin 
     Result[i] := '&'; 
     Insert('lt;', Result, i + 1); 
     Inc(i, 4); 
    end 
    else if Result[i] = '>' then 
    begin 
     Result[i] := '&'; 
     Insert('gt;', Result, i + 1); 
     Inc(i, 4); 
    end 
    else if Result[i] = '"' then 
    begin 
     Result[i] := '&'; 
     Insert('quot;', Result, i + 1); 
     Inc(i, 6); 
    end 
    else if Result[i] = '&' then 
    begin 
     Insert('amp;', Result, i + 1); 
     Inc(i, 5); 
    end 
    else 
     Inc(i); 
    end; 
end; 

Answer 7

我不知道在哪個德爾福版本，它但有，System.NetEncoding單位有：

TNetEncoding.HTML.Encode 
TNetEncoding.HTML.Decode 

f unctions。閱讀here。你不需要外部庫了。