使用for循環動畫？

Question

我正在使用for循環將多個對象添加到舞臺上，從那裏我想製作動畫，但是當我嘗試只有一個球移動時。

這是我的代碼。

（球從外部類拉）

package 
{ 
    import flash.display.Sprite; 
    import flash.events.Event; 

    public class Main extends Sprite 
    { 

     private var ball:Ball; 
     private var ax:Number = 4; 

     public function Main() 
     { 
      init(); 
     } 
     private function init():void 
     { 
      for(var i:Number = 0; i < 10; i++) 
      { 
       ball = new Ball(); 
       ball.x = Math.random() * stage.stageWidth; 
       ball.y = Math.random() * stage.stageHeight; 
       addChild(ball); 
      } 

      addEventListener(Event.ENTER_FRAME, onEnterFrame1); 
     } 
     private function onEnterFrame1(event:Event):void 
     { 
      ball.x += ax; 
     } 
    } 
} 

謝謝！

Answer 1

你應該把你所有的對象放到數組中，併爲每個球改變x屬性。

package 
{ 
    import flash.display.Sprite; 
    import flash.events.Event; 

    public class Main extends Sprite 
    { 
     private var ball:Ball; 
     private var ax:Number = 4; 

     private var balls:Array; 

     public function Main() 
     { 
      init(); 
     } 

     private function init():void 
     { 
      balls = new Array(); 
      for(var i:Number = 0; i < 10; i++) 
      { 
       ball = new Ball(); 
       ball.x = Math.random() * stage.stageWidth; 
       ball.y = Math.random() * stage.stageHeight; 
       addChild(ball); 

       balls.push(ball); 
      } 

      addEventListener(Event.ENTER_FRAME, onEnterFrame1); 
     } 
     private function onEnterFrame1(event:Event):void 
     { 
      for(var i:int = 0; i < balls.length; i++) 
      { 
       balls[i].x += ax; 
      } 
     } 
    } 
} 

Answer 2

要創建10個球

1. 除去private var ball:Ball;
2. 在init方法添加一個var ball:Ball;，所述爲之前中庸之道。

如果你不這樣做，球對象，至極屬於主類，只是更新您的循環10次，但你仍然只有一個對象。

動畫10個球

你要保存你的球在一個容器中，至極有屬於你的主，因爲找你打算從你的類的幾個功能存取權限的。

package 
{ 
    import flash.display.MovieClip; 
    import flash.events.Event; 

    public class Main extends MovieClip 
    { 
     private var ballsContainer:MovieClip; 
     private var ax:Number; 

     public function Main() 
     { 
      init(); 
     } 

     private function init():void 
     { 
      ax = 4; 

      ballsContainer = new MovieClip(); 
      addChild(ballsContainer); 

      var ball:Ball; 
      for (var i:Number = 0; i < 10; i++) 
      { 
       ball = new Ball(); 
       ball.x = Math.random() * stage.stageWidth; 
       ball.y = Math.random() * stage.stageHeight; 
       ballsContainer.addChild(ball); 
      } 

      addEventListener(Event.ENTER_FRAME, onEnterFrame1); 
     } 

     private function onEnterFrame1(event:Event):void 
     {   
      for (var i:Number = 0; i < ballsContainer.numChildren; i++) 
      { 
       Ball(ballsContainer.getChildAt(i)).x += ax; 
      } 
     } 
    } 
} 

Answer 3

你可以讓球處理它自己的運動。

package 
{ 
    import flash.display.MovieClip; 
    import flash.events.Event; 
    import flash.utils.getTimer; 
    public class Ball extends MovieClip { 
    private var currentTime = getTimer(); 
    public function Ball(){ 
     addEventListener(Event.ENTER_FRAME, onEnterFrame); 
    } 
    private function onEnterFrame1(event:Event):void { 
     diff = currentTime - prevTime; 
     x += diff * ax 
     prevTime = currentTime;//update for next go around 
    } 
    } 
} 

那麼，爲什麼使用計時器而不是幀來動畫？那麼，你不需要，但是你不能總是確定兩幀之間的時間。在這種情況下，即使您的幀速率不是，您的速度始終保持不變。