創建一個存儲過程，如果它不存在

Question

我想檢查是否存在一個存儲過程列表。我希望這一切都能在1個腳本中逐一完成。到目前爲止，我有這樣的格式：

USE [myDatabase] 
GO 

IF NOT EXISTS (SELECT * FROM sys.objects WHERE type = 'P' AND name = 'sp_1') 
BEGIN 
CREATE PROCEDURE sp_1 
AS 
................. 
END 
GO 

IF NOT EXISTS (SELECT * FROM sys.objects WHERE type = 'P' AND name = 'sp_2') 
BEGIN 
CREATE PROCEDURE sp_2 
AS 
................. 
END 
GO 

等等。但是，我收到以下錯誤：

Incorrect syntax near the keyword 'Procedure'.

爲什麼不是我在做的工作正常？

Answer 1

CREATE PROCEDURE必須是該批次中的第一條語句。我平時做這樣的事情：

IF EXISTS (
     SELECT type_desc, type 
     FROM sys.procedures WITH(NOLOCK) 
     WHERE NAME = 'procname' 
      AND type = 'P' 
    ) 
    DROP PROCEDURE dbo.procname 
GO 

CREATE PROC dbo.procname 

AS 
.... 

    GO 
    GRANT EXECUTE ON dbo.MyProc TO MyUser 

還有一兩件事，當你正在部署存儲過程考慮（如果你重新創建PROC不要忘了GRANT語句，因爲他們會丟失）是一滴可以成功，一個創建失敗。如果出現問題，我總是使用回滾編寫SQL腳本。只要確保你不小心在最後刪除提交/回滾代碼，否則你的DBA威力起重機踢你在氣管:)

BEGIN TRAN 
IF EXISTS (
     SELECT type_desc, type 
     FROM sys.procedures WITH(NOLOCK) 
     WHERE NAME = 'myProc' 
      AND type = 'P' 
    ) 
DROP PROCEDURE myProc GO 
CREATE PROCEDURE myProc 

AS 
    --proc logic here 

GO 
-- BEGIN DO NOT REMOVE THIS CODE (it commits or rolls back the stored procedure drop) IF EXISTS (
     SELECT 1 
     FROM sys.procedures WITH(NOLOCK) 
     WHERE NAME = 'DatasetDeleteCleanup' 
      AND type = 'P' 
    ) 
COMMIT TRAN 
ELSE 
ROLLBACK TRAN 
-- END DO NOT REMOVE THIS CODE 

Answer 2

USE [myDatabase] 
GO 

IF EXISTS (SELECT * FROM sys.objects WHERE type = 'P' AND name = 'sp_1') 
BEGIN 
    DROP PROCEDURE sp_1 
END 
GO --<-- Add a Batch Separator here 



CREATE PROCEDURE sp_1 
AS 
................. 
END 
GO 

Answer 3

一個成語，我一直在使用最近我喜歡相當多的是：

if exists (select 1 from sys.objects where object_id = object_id('dbo.yourProc')) 
    set noexec on 
go 
create procedure dbo.yourProc as 
begin 
    select 1 as [not yet implemented] 
end 
go 
set noexec off 
alter procedure dbo.yourProc as 
begin 
    /*body of procedure here*/ 
end 

本質上講，你要創建一個存根如果程序不存在，然後改變無論是存根（如果它剛剛創建的）或現有的預處理過程。關於這一點的好處在於，您不會丟棄預先存在的過程，從而也會丟棄所有權限。您也可以在任何恰好需要它的應用程序中在不存在的情況下導致問題。

[編輯2018-02-09] - 在SQL 2016 SP1中，create procedure和drop procedure得到了一些有助於這種事情的語法糖。具體來說，你現在可以這樣做：

create or alter dbo.yourProc as 
go 

drop procedure if exists dbo.yourProc; 

雙方提供預定語句冪等（即您可以運行它多次，理想狀態）。這就是我現在要做的（假設你使用的是支持它的SQL Server版本）。

Answer 4

我喜歡用ALTER所以我不失去權限，如果你有一個語法錯誤，舊版本依然存在：

BEGIN TRY 
    --if procedure does not exist, create a simple version that the ALTER will replace. if it does exist, the BEGIN CATCH will eliminate any error message or batch stoppage 
    EXEC ('CREATE PROCEDURE AAAAAAAA AS DECLARE @A varchar(100); SET @A=ISNULL(OBJECT_NAME(@@PROCID), ''unknown'')+'' was not created!''; RAISERROR(@A,16,1);return 9999') 
END TRY BEGIN CATCH END CATCH 
GO 

ALTER PROCEDURE AAAAAAAA 
(
    @ParamsHere varchar(10) 
) 
AS 
PRINT 'HERE IN '+(OBJECT_NAME(@@PROCID)) 
GO 

Answer 5

你可以執行以下命令：

DROP PROCEDURE IF EXISTS name_of_procedure; 
CREATE PROCEDURE name_of_procedure(....) 

Answer 6

我知道有一個可以接受的答案，但答案並不能完全解決原始問題的問題，即如果該過程不存在，則創建該過程。以下內容總是有效，並且具有不需要刪除程序的好處，如果您使用的是SQL身份驗證，則可能會出現問題。

USE [MyDataBase] 
GO 

IF OBJECT_ID('mySchema.myProc') IS NULL 
EXEC('CREATE PROCEDURE mySchema.myProc AS SET NOCOUNT ON;') 
GO 

ALTER PROCEDURE mySchema.myProc 
    @DeclaredParmsGoHere DataType 

AS 
    BEGIN 
     DECLARE @AnyVariablesINeed Their DataType 
    SELECT myColumn FROM myTable WHERE myIndex = @IndexParm