使用XSLT 1.0

Question

給出的以下XML文檔選擇元件組的第一元素：

<foo> 
    <bar> 
    <type>1</type> 
    <id>1</id> 
    <a1>0</a1> 
    <other_stuff/> 
    </bar> 
    <bar> 
    <type>1</type> 
    <id>1</id> 
    <a1>0</a1> 
    <other_stuff/> 
    </bar> 
    <bar> 
    <type>1</type> 
    <id>2</id> 
    <a1>0</a1> 
    <other_stuff/> 
    </bar> 
    <bar> 
    <type>1</type> 
    <id>2</id> 
    <a1>0</a1> 
    <other_stuff/> 
    </bar> 
</foo> 

bar是列表元素，按類型和id邏輯上分組的XML元素。因此，示例文檔包含兩個有序列表（type = 1和id = 1，type = 1和id = 2），每個列表包含兩個元素。在真實文檔中，還有更多不同長度的列表（使用不同類型和ID）。

現在我需要用不同的值更新每個列表的第一個元素a1，下列文件中：

<foo> 
    <bar> 
    <type>1</type> 
    <id>1</id> 
    <a1>-100</a1> 
    <other_stuff/> 
    </bar> 
    <bar> 
    <type>1</type> 
    <id>1</id> 
    <a1>0</a1> 
    <other_stuff/> 
    </bar> 
    <bar> 
    <type>1</type> 
    <id>2</id> 
    <a1>-100</a1> 
    <other_stuff/> 
    </bar> 
    <bar> 
    <type>1</type> 
    <id>2</id> 
    <a1>0</a1> 
    <other_stuff/> 
    </bar> 
</foo> 

在僞SQL這可能會是這樣的：

update bar set a1 = -100 where position() = 1 group by type, id 

這是可能的XSLT 1.0？我認爲可以歸結爲能夠編寫一個XPath表達式，其結果與我的僞SQL語句相同。

Answer 1

使用Muenchian grouping每個組中確定的第一項和改變孩子，其餘與身份轉換複製：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    version="1.0"> 

    <xsl:param name="new-value" select="-100"/> 

    <xsl:key name="group" match="bar" use="concat(type, '|', id)"/> 

    <xsl:template match="@* | node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@* | node()"></xsl:apply-templates> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="bar[generate-id() = generate-id(key('group', concat(type, '|', id))[1])]/a1"> 
     <xsl:copy> 
      <xsl:value-of select="$new-value"/> 
     </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet> 

至於進一步的解釋，關鍵定義<xsl:key name="group" match="bar" use="concat(type, '|', id)"/>讓XSLT處理器指數barconcat(type, '|', id)上的元素，以便我們可以使用例如key('group', '1|1')找到所有bar元素的值爲concat(type, '|', id)。

你只需要改變第一bar元素每組所以我們需要有一種方法來識別謂語的內部的第一項bar[...]，我們需要找到一個表達的條件

bar[. is the first item in its group] 

模式

我們得到與key('group', concat(type, '|', id))模式裏面，所以我們要編寫一個條件

bar[. is the first item in key('group', concat(type, '|', id))] 

，我們可以用近字面上表達XSLT 2.0組10操作員和圖案

bar[. is key('group', concat(type, '|', id))[1]] 

隨着XSLT 1.0，我們可以使用產生-ID表達它，如在

bar[generate-id() = generate-id(key('group', concat(type, '|', id))[1])] 

，其選擇進行/那些bar元件的量，生成的ID等於匹配由key('group', concat(type, '|', id))計算的組中第一個（[1]）項目的生成ID。