XSLT：我想基於使用XSLT 1.0

Question

正在嘗試使用XSLT 1.0

源XML扁平化基礎上的子元素名稱的XML元素的子元素的名字拼合XML元素：

<Contact> 
    <ContactPurpose> 
    <PurposeAsPlainText xmlns="cds_dt">Call</PurposeAsPlainText> 
    </ContactPurpose> 
    <ContactPurpose> 
    <PurposeAsEnum xmlns="cds_dt">Call</PurposeAsEnum> 
    </ContactPurpose> 
</Contact> 

應變換爲下面的XML：

<Contact> 
    <ContactPurpose>O</ContactPurpose> 
    <ContactPurpose>Call</ContactPurpose> 
</Contact> 

的邏輯是：

如果子元素名稱是「PurposeAsPlainText「目的地THEN 集‘O’爲其他

ELSEIF子元素名稱是‘PurposeAsEnum’THEN 源值複製到目標

編輯1：我可能會更清楚，因爲沒有任何解決方案將XML解壓縮，請參閱修訂的源和目標XML。

編輯2：這是我測試的XML。下面的兩個轉換解決方案實際上可以在我的原始xml上工作，但不是我使用.NET 4.0 XslCompiledTransform進行測試的修訂後的xml。或者我應該提出一個新問題？

<MyDS xmlns="cds" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema"> 
    <PatientRecord> 
    <Demographics> 
     <Contact> 
     <ContactPurpose> 
      <PurposeAsPlainText xmlns="cds_dt">Call</PurposeAsPlainText> 
     </ContactPurpose> 
     <ContactPurpose> 
      <PurposeAsEnum xmlns="cds_dt">Call</PurposeAsEnum> 
     </ContactPurpose> 
     </Contact> 
    </Demographics> 
    </PatientRecord> 
</MyDS> 

Answer 1

這可以在一個簡單的和短期的方式來完成（沒有明確的條件語句）：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:x="cds_dt" exclude-result-prefixes="x"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="ContactPurpose/x:PurposeAsPlainText/text()">0</xsl:template> 

<xsl:template match="ContactPurpose/*"><xsl:apply-templates/></xsl:template> 
</xsl:stylesheet> 

當施加到下面的XML文檔（擴展到encorporate感興趣這兩種情況下）：

<Contact> 
    <ContactPurpose> 
     <PurposeAsPlainText xmlns="cds_dt">Call</PurposeAsPlainText> 
    </ContactPurpose> 
    <ContactPurpose> 
     <PurposeAsEnum xmlns="cds_dt">Call</PurposeAsEnum> 
    </ContactPurpose> 
</Contact> 

產生想要的，正確的結果：

<Contact> 
    <ContactPurpose>0</ContactPurpose> 
    <ContactPurpose>Call</ContactPurpose> 
</Contact> 

說明：

重寫identity rule和適當使用的模板/匹配模式。

更新：該任擇議定書已經修改了他的XML文檔，這是現在在默認命名空間：

<MyDS xmlns="cds" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" 
xmlns:xsd="http://www.w3.org/2001/XMLSchema"> 
    <PatientRecord> 
     <Demographics> 
      <Contact> 
       <ContactPurpose> 
        <PurposeAsPlainText xmlns="cds_dt">Call</PurposeAsPlainText> 
       </ContactPurpose> 
       <ContactPurpose> 
        <PurposeAsEnum xmlns="cds_dt">Call</PurposeAsEnum> 
       </ContactPurpose> 
      </Contact> 
     </Demographics> 
    </PatientRecord> 
</MyDS> 

因此，這裏是產生想要的結果略微修改後的轉換：

<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:x="cds_dt" xmlns:c="cds" exclude-result-prefixes="c x"> 
    <xsl:output omit-xml-declaration="yes" indent="yes"/> 
    <xsl:strip-space elements="*"/> 

    <xsl:template match="node()|@*"> 
     <xsl:copy> 
      <xsl:apply-templates select="node()|@*"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="c:ContactPurpose/x:PurposeAsPlainText/text()">0</xsl:template> 

    <xsl:template match="c:ContactPurpose/*"><xsl:apply-templates/></xsl:template> 
</xsl:stylesheet> 

將此轉換應用於新XML文檔（最接近的上面）時，新的想要的正確結果是produc編號：

<MyDS xmlns="cds" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" 
xmlns:xsd="http://www.w3.org/2001/XMLSchema"> 
    <PatientRecord> 
     <Demographics> 
     <Contact> 
      <ContactPurpose>0</ContactPurpose> 
      <ContactPurpose>Call</ContactPurpose> 
     </Contact> 
     </Demographics> 
    </PatientRecord> 
</MyDS> 

Answer 2

<?xml version="1.0" encoding="iso-8859-1"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:cds="cds_dt" exclude-result-prefixes="cds"> 
<!-- identity transform - just copy things that don't have a better rule --> 
<xsl:template match="@* | node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@* | node()"/> 
    </xsl:copy> 
</xsl:template> 

<!- a rule for what needs changing --> 
<xsl:template match="ContactPurpose[cds:PurposeAsPlainText] "> 
    <ContactPurpose>O</ContactPurpose> 
</xsl:template> 
</xsl:stylesheet> 

Answer 3

更新：修改了答案，以適應變化的XML源文檔。

的描述不是很清楚，但這裏是我認爲你正在試圖做的：

<xsl:stylesheet version="1.0" xmlns:cds_dt="cds_dt" xmlns:cds="cds" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

<!-- Identity transform --> 
<xsl:template match="@* | node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@* | node()"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="cds:ContactPurpose"> 
    <xsl:copy> 
     <xsl:choose> 
     <!-- when there is a child element PurposeAsPlainText 
      in the cds_dt namespace: --> 
     <xsl:when test="cds_dt:PurposeAsPlainText">0</xsl:when> 
     <!-- I'm guessing that PurposeAsEnum is also supposed to be 
      in the cds_dt namespace. --> 
     <xsl:otherwise> 
      <xsl:value-of select="cds_dt:PurposeAsEnum" /> 
     </xsl:otherwise> 
     </xsl:choose> 
    </xsl:copy> 
</xsl:template> 

</xsl:stylesheet>