明確子句語法（DCG）的Prolog（作業）

Question

我試圖寫一個謂語和N={Expression,Number,Digit,Operator,Variable}

T={1,2,3,+,-,*,(,),X,Y,Z}和S是表達和程序P定義爲

Expression-->Number 
**Expression-->(Expression) Operator (Expression)** 
Number-->Digit 
**Number --> Digit Number** 
Digit-->1 
Digit-->2 
Digit-->3 
Operator-->+ 
Operator-->- 
Operator-->* 
Variable-->X 
Variable-->Y 
Variable-->Z 

我認爲然而，我實現許多份無法實現大膽的部分！

，通過根據程序P描述端子我序言代碼：

expression(S,S). 
    expression(S,R):-number(S,R). 
    expression(S,R):-expression(S,R),-operator(S,['('|S]),expression(S,[')'|R]). 
    expression(S,R):-operator(S,[','|S1]),expression(S1,R). 
    expression(S,R):-variable(S,[','|S1]),expression(S1,R). 
    number(S,R):-digit(S,R). 
    digit(['1'|R],R). 
    digit(['2'|R],R). 
    digit(['3'|R],R). 
    operator(['+'|R],R). 
    operator(['-'|R],R). 
    operator(['*'|R],R). 
    variable(['X'|R],R). 
    variable(['Y'|R],R). 
    variable(['Z'|R],R). 

請幫助我。

Answer 1

這裏可能是dcg你的意思是：

:- set_prolog_flag(double_quotes, chars). 

expression --> number. 
expression --> variable. 
expression --> "(", expression, operator, expression, ")". 

number --> digit. 
number --> digit, number. 

digit --> "1". 
digit --> "2". 
digit --> "3". 

operator --> "+"|"-"|"*". % more compact notation 
variable --> "X"|"Y"|"Z". 

使用它像這樣產生的長下令所有的句子：

?- length(L, N), phrase(expression, L). 
L = ['1'], 
N = 1 ; 
L = ['2'], 
N = 1 ; 
L = ['3'], 
N = 1 ; 
L = ['X'], 
N = 1 ; 
L = ['Y'], 
N = 1 ; 
L = ['Z'], 
N = 1 ; 
L = ['1', '1'], 
N = 2 ; 
L = ['1', '2'], 
N = 2 ... 

而且獲得最緊湊和可讀的答案見this更多。也就是說，下載下面的模塊：

?- use_module(double_quotes).

?- length(L, N), phrase(expression, L). 
L = "1", 
N = 1 ; 
L = "2", 
N = 1 ; 
L = "3", 
N = 1 ; 
L = "X", 
N = 1 ; 
L = "Y", 
N = 1 ; 
L = "Z", 
N = 1 ; 
L = "11", 
N = 2 ; 
L = "12", 
N = 2 

要查看DCG是如何實現的，說listing對每個非終端。例如：

?- listing(expression). 
expression(A, B) :- 
     number(A, B). 
expression(A, B) :- 
     variable(A, B). 
expression(['('|A], E) :- 
     expression(A, B), 
     operator(B, C), 
     expression(C, D), 
     D=[')'|E].