將Excel字符串數組傳遞給用戶定義的VBA函數

Question

我希望使用Excel數組函數來生成一個字符串數組，然後將其傳遞給用戶定義的函數以去除空格並連接由","分隔的字符串。

我有一個函數在從VBA宏調用時執行此操作。當我嘗試將它用作用戶定義的功能時，例如=ConcStr({"A","B","C"})，我得到一個#Value!錯誤。

功能如下：

Sub StrTest() 
    Dim StaticArray(1 To 3) As String 
    Dim Result As String 
    StaticArray(1) = "A" 
    StaticArray(2) = "B" 
    StaticArray(3) = "C" 
    Result = ConcStr(Arr:=StaticArray) 
    MsgBox Result 
End Sub 

Function ConcStr(Arr() As String) As String 
    MsgBox "started" 
    Dim N As Long 
    Dim Total As String 
    For N = LBound(Arr) To UBound(Arr) 
     MsgBox Arr(N) 
     Total = Total & "," & Arr(N) 
    Next N 
    ConcStr = Total 
End Function 

Answer 1

我能得到你想要的東西有：

Public Function ConcatString(ByVal arr As Variant) As String 
    ConcatString = vbNullString 
    Dim i As Long, n As Long, z as Long 
    z = LBound(arr) : n = UBound(arr) 
    For i = z To n 
     ConcatString = ConcatString + arr(i) 
    Next i 
End Function 

Answer 2

申報，暗淡，分配並在傳遞數組作爲一個變種。

Sub StrTest() 
    Dim StaticArray As Variant, Result As String 

    ReDim StaticArray(1 To 3) 

    StaticArray(1) = "A" 
    StaticArray(2) = "B" 
    StaticArray(3) = "C" 

    Result = ConcStr(Arr:=StaticArray) 
    MsgBox Result 
    Result = ConcStr2(Arr:=StaticArray) 
    MsgBox Result 

End Sub 

Function ConcStr(Arr As Variant) As String 
    MsgBox "started" 

    Dim N As Long, Total As String 

    For N = LBound(Arr) To UBound(Arr) 
     MsgBox Arr(N) 
     Total = Total & "," & Arr(N) 
    Next N 

    ConcStr = Mid(Total, 2) 'Mid to get rid of the first comma 

End Function 

Function ConcStr2(Arr As Variant) As String 
    'could just be like this, 
    ConcStr2 = Join(Arr, ",") 
End Function 

我已經添加了一個替代Join Function版本simplfy的事情，並與Mid function修改你的函數刪除前導逗號。

Answer 3

如果您將UDF重寫爲接受Variant，則應該起作用。此外，您可以使用Join函數來完成您所需要的功能：

Function ConcStr(arr As Variant) As String 
    ConcStr = Join(arr, ",") 
End Function