Perl從調用模塊導入變量

Question

我有一個Perl模塊（Module.pm），用於初始化一些變量，其中一些我想將它導入（$ VAR2，$ VAR3）到其可能載入的其他子模塊中執行。

我目前正在設立Module.pm的方法如下：

package Module::SubModule1; 

use warnings; 
use strict; 
use Carp; 

use vars qw(); 

sub new { 
    my ($package) = @_; 
    my $self = {}; 
    bless ($self, $package); 
    return $self; 
} 

我希望能夠導入$ VAR2：

package Module; 

use warnings; 
use strict; 

use vars qw($SUBMODULES $VAR1 $VAR2 $VAR3); 

require Exporter; 
our @ISA = qw(Exporter); 
our @EXPORT = qw($VAR2 $VAR3); 

sub new { 
    my ($package) = @_; 
    my $self = {}; 
    bless ($self, $package); 
    return $self; 
} 

sub SubModules1 { 
    my $self = shift; 
    if($SUBMODULES->{'1'}) { return $SUBMODULES->{'1'}; } 

    # Load & cache submodule 
    require Module::SubModule1; 
    $SUBMODULES->{'1'} = Module::SubModule1->new(@_);  
    return $SUBMODULES->{'1'}; 
} 

sub SubModules2 { 
    my $self = shift; 
    if($SUBMODULES->{'2'}) { return $SUBMODULES->{'2'}; } 

    # Load & cache submodule 
    require Module::SubModule2; 
    $SUBMODULES->{'2'} = Module::SubModule2->new(@_);  
    return $SUBMODULES->{'2'}; 
} 

每個子模塊的結構如下和$ VAR3變量導入每個子模塊，而不必將它們作爲$ Module :: VAR2和$ Module :: VAR3引用。我注意到調用腳本能夠以所需的方式訪問我在Module.pm中導出的兩個變量，但是SubModule1.pm和SubModule2.pm仍需要將變量引用爲Module.pm。

我試圖更新每個子模塊如下不幸的是沒有工作，我希望：

package Module::SubModule1; 

use warnings; 
use strict; 
use Carp; 

use vars qw($VAR2 $VAR3); 

sub new { 
    my ($package) = @_; 
    my $self = {}; 
    bless ($self, $package); 
    $VAR2 = $Module::VAR2; 
    $VAR3 = $Module::VAR3; 
    return $self; 
} 

請讓我知道我能成功地從Module.pm出口$ VAR2和$ VAR3到每個子模塊。在此先感謝您的幫助！

Answer 1

在你的子模塊，你忘了說

use Module; 

？從另一個包（稱爲Module::Submodule9）調用use Module將嘗試運行Module::import方法。既然你沒有這個方法，它會調用Exporter::import方法，那就是將Module的變量輸出到Module::Submodule9命名空間的魔法會發生的地方。

---

在你的程序中只有一個Module命名空間，只有一個（全局）變量$Module::VAR2的實例。導出會在其他名稱空間中爲此變量創建別名，因此可以通過不同的方式訪問相同的變量。在一個單獨的腳本試試這個：

package Whatever; 
use Module; 
use strict; 
use vars qw($VAR2); 

$Module::VAR2 = 5; 
print $Whatever::VAR2; # should be 5. 
$VAR2 = 14;    # same as $Whatever::VAR2 = 14 
print $Module::VAR2;  # should be 14 

Answer 2

那麼有簡單的方法：

在M.pm：

package M; 

use strict; 
use warnings; 

#our is better than "use vars" for creating package variables 
#it creates an alias to $M::foo named $foo in the current lexical scope 
our $foo = 5; 

sub inM { print "$foo\n" } 

1; 

在M/S.pm

package M; 

#creates an alias to $M::foo that will last for the entire scope, 
#in this case the entire file 
our $foo; 

package M::S; 

use strict; 
use warnings; 

sub inMS { print "$foo\n" } 

1; 

在腳本中：

#!/usr/bin/perl 

use strict; 
use warnings; 

use M; 
use M::S; 

M::inM(); 
M::S::inMS(); 

但我會建議反對這一點。全局變量不是一種好的做法，模塊之間共享全局變量更加糟糕。