如何更換 「單引號」，以 「雙單引號」 在XSLT

Question

如何更換一個XML值，例如：通過XSLT

<name>Linda O''Connel</name> 

：

<name>Linda O'Connel</name> 

什麼？

我需要這個，因爲我必須在powershell命令行和其他平臺上傳遞此值，因爲需要「雙單引號」來轉義撇號/單引號。

Answer 1

假設一個XSLT 1.0處理器，則需要使用遞歸命名模板爲此，e.g：通話

<xsl:template name="replace"> 
    <xsl:param name="text"/> 
    <xsl:param name="searchString">'</xsl:param> 
    <xsl:param name="replaceString">''</xsl:param> 
    <xsl:choose> 
     <xsl:when test="contains($text,$searchString)"> 
      <xsl:value-of select="substring-before($text,$searchString)"/> 
      <xsl:value-of select="$replaceString"/> 
      <!-- recursive call --> 
      <xsl:call-template name="replace"> 
       <xsl:with-param name="text" select="substring-after($text,$searchString)"/> 
       <xsl:with-param name="searchString" select="$searchString"/> 
       <xsl:with-param name="replaceString" select="$replaceString"/> 
      </xsl:call-template> 
     </xsl:when> 
     <xsl:otherwise> 
      <xsl:value-of select="$text"/> 
     </xsl:otherwise> 
    </xsl:choose> 
</xsl:template> 

例子：

<xsl:template match="name"> 
    <xsl:copy> 
     <xsl:call-template name="replace"> 
      <xsl:with-param name="text" select="."/> 
     </xsl:call-template> 
    </xsl:copy> 
</xsl:template> 

Answer 2

您也可以嘗試以下。

<xsl:variable name="temp">'</xsl:variable> 
    <name> 
    <xsl:value-of select="concat(substring-before(name,$temp),$temp,$temp,substring-after(name,$temp))"/> 
    </name>