在未指定出現順序時處理XSLT中的子標籤

Question

我正在處理XSLT轉換。我有一個源文件，其中有一些名爲tag的標籤。

考慮我的源xml是這樣的。

<ABC> 
    <Name>Some Name </Name> 
    <ID>Some ID</ID> 
    <Address>Some Address</Address> 
    <Place>Some Place</Place> 
    <ID>Some ID</ID> 
    <Name>Some Name </Name> 
    <Name>Some Name </Name>  

</ABC> 

規則：

ABC is parent Tag which has 4 child tags. Name, ID, Address, Place. 
    These child tags can occur many times and in any ordrer. 
    Upon reading the tag , I want to change the name of the tag, and do some processing on the value present in the tag. 
    The input XML may have child tags in any order, and many times. 
    I want to write a common XSLT which will read the child tags in the order in which they occur, and display them as given under. 

我要顯示這樣的輸出。

 <Frame:Name> 
        <text>Some Name</text> 
     </Frame:Name> 
    <Frame:ID> 
        <text>Some ID</text> 
     </Frame:ID> 
     <Frame:ADdrress> 
        <text>Some Address</text> 
     </Frame:Address> 
     <Frame:Place> 
        <text>Some Place</text> 
     </Frame:Place> 
    <Frame:ID> 
        <text>Some ID</text> 
     </Frame:ID> 
     <Frame:Name> 
        <text>Some Name</text> 
     </Frame:Name> 
     <Frame:Name> 
        <text>Some Name</text> 
     </Frame:Name> 

我完全感到它是如何完成的。

如果源XML中子元素的出現順序發生變化，它也應該反映在輸出XML中。

有人可以分享評論。

謝謝。

Answer 1

的XSLT的辦法來解決這些問題是通過使用模板。其結果是更簡單，更短的和可以理解的代碼，通常沒有任何xsl:choose，xsl:when，xsl:otherwise，xsl:if或xsl:for-each：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:Frame="some:undefined namespace"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="/*"> 
    <t><xsl:apply-templates/></t> 
</xsl:template> 

<xsl:template match="*/*"> 
    <xsl:element name="Frame:{name()}" namespace="some:undefined namespace"> 
     <text><xsl:apply-templates /></text> 
    </xsl:element> 
</xsl:template> 
</xsl:stylesheet> 

當這種變換所提供的XML文檔應用：

<ABC> 
    <Name>Some Name </Name> 
    <ID>Some ID</ID> 
    <Address>Some Address</Address> 
    <Place>Some Place</Place> 
    <ID>Some ID</ID> 
    <Name>Some Name </Name> 
    <Name>Some Name </Name> 
</ABC> 

想要的，正確的結果產生：

<t xmlns:Frame="some:undefined namespace"> 
    <Frame:Name> 
     <text>Some Name </text> 
    </Frame:Name> 
    <Frame:ID> 
     <text>Some ID</text> 
    </Frame:ID> 
    <Frame:Address> 
     <text>Some Address</text> 
    </Frame:Address> 
    <Frame:Place> 
     <text>Some Place</text> 
    </Frame:Place> 
    <Frame:ID> 
     <text>Some ID</text> 
    </Frame:ID> 
    <Frame:Name> 
     <text>Some Name </text> 
    </Frame:Name> 
    <Frame:Name> 
     <text>Some Name </text> 
    </Frame:Name> 
</t> 

Answer 2

基於jeevan的建議。

<xsl:template match="ABC" > 
    <ABC> 
     <xsl:for-each select ="child::*"> 
     <xsl:choose> 
      <xsl:when test="name()='Name'"> 
      <xsl:element name="Frame:Name"> 
       <xsl:apply-templates select="."/> 
      </xsl:element> 
      </xsl:when> 

      <xsl:when test="name()='ID'"> 
      <Frame:ID> 
       <xsl:apply-templates select="."/> 
      </Frame:ID> 
      </xsl:when> 
      <xsl:when test="name()='Address'"> 
      <Frame:Address> 
       <xsl:apply-templates select="."/> 
      </Frame:Address> 
      </xsl:when> 

      <xsl:when test="name()='Place'"> 
      <Frame:Place> 
       <xsl:apply-templates select="."/> 
      </Frame:Place> 
      </xsl:when> 
    </xsl:choose> 
     </xsl:for-each>