在SQL Server中處理多個參數

Question

我正在使用存儲過程在我的數據庫中搜索並篩選參數上的結果，我需要篩選未知的多個參數。

我該如何編寫一個處理這個問題的存儲過程？

這裏是我的存儲過程：

CREATE PROCEDURE ComplaintRefListOnDistrict 
    @District nvarchar(max) = '' 
AS 
BEGIN 
    SET NOCOUNT ON; 

    SELECT 
     ComplaintFullID, CustomerName, Customer_Address, CustomerEmail, 
     Date, ContractID, CustomerPhoneNumber,ID, Complaintreference_ID, State 
    FROM 
     dbo.ComplaintsSmartObject 
    LEFT JOIN 
     dbo.UsersDistricts ON dbo.UsersDistricts.District = dbo.ComplaintsSmartObject.District 
    WHERE 
     (dbo.UsersDistricts.District = @District) 
END 
GO 

謝謝！

Answer 1

我說的是使用這種動態SQL。

CREATE PROCEDURE ComplaintRefListOnDistrict 
     @District nvarchar(max) = '' 
    AS 
    BEGIN 
     SET NOCOUNT ON; 

    declare @sql nvarchar(max) 

    set @sql = 'SELECT 
      ComplaintFullID, CustomerName, Customer_Address, CustomerEmail, 
      Date, ContractID, CustomerPhoneNumber,ID, Complaintreference_ID, State 
     FROM 
      dbo.ComplaintsSmartObject 
     LEFT JOIN 
      dbo.UsersDistricts ON dbo.UsersDistricts.District = dbo.ComplaintsSmartObject.District 
     WHERE 
      (dbo.UsersDistricts.District in (' + @District + '))' 

    EXEC sp_executesql @sql 
    END 

Answer 2

CREATE PROCEDURE ComplaintRefListOnDistrict 
(
@District nvarchar(max) = NULL 
) 
AS 
BEGIN 

SET NOCOUNT ON; 
SELECT 
CSC.ComplaintFullID, CSC.CustomerName, CSC.Customer_Address, CSC.CustomerEmail, 
CSC.Date, UD.ContractID, UD.CustomerPhoneNumber,UD.ID, UD.Complaintreference_ID, UD.State 
FROM 
    dbo.ComplaintsSmartObject CSC 
    LEFT JOIN dbo.UsersDistricts UD 
    ON UD.District = CSC.District 
WHERE 
(
      UD.District LIKE '%' + @District + '%' 
      OR @District IS NULL 
      OR @District = '' 
      ) 

    ORDER BY CSC.ComplaintFullID, 
    CSC.CustomerName, 
    CSC.Customer_Address, 
    CSC.CustomerEmail, 
CSC.Date, UD.ContractID, UD.CustomerPhoneNumber,UD.ID, UD.Complaintreference_ID, UD.State 


END 
GO 

Answer 3

您可以創建在您使用的參數不明WHERE子句或檢查它是否是空

WHERE (dbo.UsersDistricts.District = @District OR District IS NULL) 
AND (SomeOtherColumn = @OtherParameter OR OtherParameter IS NULL) 

等。

Answer 4

首先添加一個輔助函數，該函數會將傳遞給它的字符串拆分成行。

CREATE FUNCTION SplitString 
( 
    @string NVARCHAR(MAX), 
    @delimiter CHAR(1) 
) 
RETURNS 
    @output TABLE(Data NVARCHAR(MAX)) 
BEGIN 
    DECLARE @start INT, @end INT 
    SELECT @start = 1, @end = CHARINDEX(@delimiter, @string) 
    WHILE @start < LEN(@string) + 1 
    BEGIN 
     IF (@end = 0) SET @end = LEN(@string) + 1 
     INSERT INTO @output (Data) VALUES(SUBSTRING(@string, @start, @end - @start)) 
     SET @start = @end + 1 
     SET @end = CHARINDEX(@delimiter, @string, @start) 
    END 
    RETURN 
END 

現在一切都非常簡單。使用SQL IN運營商：

CREATE PROCEDURE ComplaintRefListOnDistrict 
    @District nvarchar(max) = '' 
AS 
BEGIN 
    SET NOCOUNT ON; 

    SELECT 
     ComplaintFullID, CustomerName, Customer_Address, CustomerEmail, 
     Date, ContractID, CustomerPhoneNumber,ID, Complaintreference_ID, State 
    FROM 
     dbo.ComplaintsSmartObject 
    LEFT JOIN 
     dbo.UsersDistricts ON dbo.UsersDistricts.District = dbo.ComplaintsSmartObject.District 
    WHERE 
     (dbo.UsersDistricts.District IN (SELECT Data FROM dbo.SplitString(@District, ','))) 
END 

HTH。