如何將一個數組和一個字符串作爲參數傳遞給函數？

Question

因爲我找不到一個方便的方法來檢查$str是否在@array，我試圖自己做一個，但它不工作。

我想這是因爲數組和字符串的混淆。它一直給0至$str。請讓我知道如何解決它。

use 5.010; 
use strict; 
use warnings; 

sub ifin { 
    my (@array, $str) = @_; 
    for my $i (@array) { 
     if ($i eq $str) { 
      return 1; 
     } 
    } 
    return 0; 
} 

my @f = (1, 2, 3, 4); 
my $k = 1; 
print ifin(@f, $k); 

Answer 1

您不能將數組傳遞給subs，只有標量列表。

ifin(@f, $k); 

相同

ifin($f[0], $f[1], $f[2], $f[3], $k); 

因爲@f評估其元素的列表。

將數組傳遞給子的一種方法是傳遞引用。

sub ifin { 
    my ($array, $str) = @_; 
    for my $e (@$array) { 
     return 1 if $e eq $str; 
    } 

    return 0; 
} 

my @f = (1,2,3,4); 
my $k = 1; 
print(ifin(\@f, $k), "\n"); 

順便說一句，這也可以寫成：

my @f = (1,2,3,4); 
my $k = 1; 
print((grep { $_ eq $k } @f) ? 1 : 0, "\n"); 

您可以通過使用pop保持現有的調用約定。

sub ifin { 
    my $str = pop(@_); 
    for my $e (@_) { 
     return 1 if $e eq $str; 
    } 

    return 0; 
} 

my @f = (1,2,3,4); 
my $k = 1; 
print(ifin(@f, $k), "\n"); 

Answer 2

你可以使用原型，但那些原型很脆弱。我會在參考傳遞給@f作爲第一個參數，像這樣：

use 5.010; 
use strict; 
use warnings; 

sub ifin 
{ 
my ($array,$str)=@_; 
for my $i (@$array) 
{ 
    if ($i eq $str) 
    { 
    return True 
    } 
} 
return False 
} 


my @f= (1,2,3,4); 
my $k=1; 
print ifin(\@f,$k); 

對於一個長長的清單，你避免犯每個列表元素的副本，以及。

Answer 3

您可能要檢查列表中的任何:: MoreUtils包，你只需要使用它喜歡：

use List::MoreUtils 'any'; 

my @f= qw(1 2 3 4); 
my $k=10; 

print "yes\n" if(any { $_ == $k } @f); 

檢查的文檔：

perldoc List::MoreUtils. 

Answer 4

你可以通過你的論點相反順序（print ifin($k, @f);），所以數組將繼續。當你從子程序中捕獲它們時，字符串會先出現，然後數組會被填充任何後面的列表項。

Answer 5

$str ~~ @arr如何在smartmatch？這在Perl 5.10中可用。

use 5.010; 
use strict; 
use warnings; 

my $str = 'three'; 
my @arr = qw(zero one two three four); 
my @badarr = qw(zero one two four eight); 

say '$str ', $str ~~ @arr? 'is' : 'is not', ' in $arr.'; 
say '$str ', $str ~~ @badarr? 'is' : 'is not', ' in $badarr.'; 

輸出，如預期：

$str is in $arr. 
$str is not in $badarr.