xsl：將變量傳入xsl文件路徑

Question

有沒有辦法將一個屬性，變量組合直接導入到帶有xsl的url路徑中？

實施例：

http://something.xsl?asdf=12&attribute2=1234 

我想用這些屬性和值，以使XSL文件內某些標誌。

Answer 1

使用concat()

<xsl:variable name="url" select="concat($currURL, 'flag=true')" /> 

Answer 2

呀，你只需要逃避&爲&

Answer 3

我想你的意思是可以將樣式表訪問自己的URI來訪問參數。在XSLT2中，您可以使用static-base-uri（）函數來訪問URI，然後您可以將其拆分，以使用正則表達式字符串函數提取查詢參數。在XSLT1中，這是不可能的，您需要以樣式表參數傳遞信息，而XSLT1樣式表無法訪問源或其自身的URI。

Answer 4

下面是一個完整XSLT 1.0溶液中，假定URL被作爲外部參數來變換通過：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:ext="http://exslt.org/common" exclude-result-prefixes="ext"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 

<xsl:param name="pUrl" select= 
"'http://something.xsl?asdf=12&amp;attribute2=1234'"/> 

<xsl:template match="/"> 
    <xsl:variable name="vQuery" select="substring-after($pUrl, '?')"/> 

    <xsl:variable name="vrtfQueryItems"> 
    <xsl:call-template name="buildQueryItems"> 
    <xsl:with-param name="pQuery" select="$vQuery"/> 
    </xsl:call-template> 
    </xsl:variable> 

    <xsl:variable name="vQueryItems" 
    select="ext:node-set($vrtfQueryItems)/*"/> 

    <xsl:copy-of select="$vQueryItems"/> 
</xsl:template> 

<xsl:template name="buildQueryItems"> 
    <xsl:param name="pQuery"/> 

    <xsl:if test= 
    "string-length($pQuery) > 0"> 

    <xsl:variable name="vQuery" select="concat($pQuery, '&amp;')"/> 
    <xsl:variable name="vItem" select="substring-before($vQuery, '&amp;')"/> 

    <param name="{substring-before(concat($vItem, '='), '=')}"> 
    <xsl:value-of select="substring-after($vItem, '=')"/> 
    </param> 


    <xsl:call-template name="buildQueryItems"> 
    <xsl:with-param name="pQuery" select="substring-after($pQuery, '&amp;')"/> 
    </xsl:call-template> 
    </xsl:if> 
</xsl:template> 
</xsl:stylesheet> 

當這種轉化是在任何XML文檔（未使用）施加產生想要的結果：

<param name="asdf">12</param> 
<param name="attribute2">1234</param>