禁用所有非聚集索引

Question

我選擇了一些非聚集索引的從我的數據庫具有以下內容：

SELECT sys.objects.name tableName, 
     sys.indexes.name indexName 
FROM sys.indexes 
     JOIN sys.objects ON sys.indexes.object_id = sys.objects.object_id 
WHERE sys.indexes.type_desc = 'NONCLUSTERED' 
     AND sys.objects.type_desc = 'USER_TABLE' 

我想運行下面的在每個結果：

ALTER INDEX indexName ON tableName DISABLE 

我該怎麼做呢？有沒有更好的辦法？

編輯

我這樣做是爲截斷表的目的，然後與重建「ALTER INDEX ON BLA表重建」。這需要實現自動化，因此丟棄和重建將是我寧願避免的稍高的維護活動。這是一個糟糕的計劃嗎？我需要一種以最小開銷清空表格的方法。

Answer 1

您可以建立查詢到select語句，就像這樣：

DECLARE @sql AS VARCHAR(MAX)=''; 

SELECT @sql = @sql + 
'ALTER INDEX ' + sys.indexes.name + ' ON ' + sys.objects.name + ' DISABLE;' +CHAR(13)+CHAR(10) 
FROM 
    sys.indexes 
JOIN 
    sys.objects 
    ON sys.indexes.object_id = sys.objects.object_id 
WHERE sys.indexes.type_desc = 'NONCLUSTERED' 
    AND sys.objects.type_desc = 'USER_TABLE'; 

EXEC(@sql); 

字符數13和10是換行/回車符號，這樣你就可以用PRINT更換EXEC檢查輸出，它會更具可讀性。

Answer 2

用索引和表名建立一個表變量。使用循環遍歷它們，併爲它們中的每一個執行動態SQL語句。

declare @Indexes table 
(
    Num  int identity(1,1) primary key clustered, 
    TableName nvarchar(255), 
    IndexName nvarchar(255) 
) 

INSERT INTO @Indexes 
(
    TableName, 
    IndexName 
) 
SELECT sys.objects.name tableName, 
     sys.indexes.name indexName 
FROM sys.indexes 
     JOIN sys.objects ON sys.indexes.object_id = sys.objects.object_id 
WHERE sys.indexes.type_desc = 'NONCLUSTERED' 
     AND sys.objects.type_desc = 'USER_TABLE' 

DECLARE @Max INT 
SET @Max = @@ROWCOUNT 

SELECT @Max as 'max' 
SELECT * FROM @Indexes 

DECLARE @I INT 
SET @I = 1 

DECLARE @TblName NVARCHAR(255), @IdxName NVARCHAR(255) 

DECLARE @SQL NVARCHAR(MAX) 

WHILE @I <= @Max 
BEGIN 
    SELECT @TblName = TableName, @IdxName = IndexName FROM @Indexes WHERE Num = @I 
    SELECT @SQL = N'ALTER INDEX ' + @IdxName + N' ON ' + @TblName + ' DISABLE;' 

    EXEC sp_sqlexec @SQL  

    SET @I = @I + 1 

END 

Answer 3

OTOH它可能會更好DROP寧可DISABLE（或者是Oracle和MS SQL？之間的小律語法差異:-)我提到的原因是，我記得是再增殖和excplicilty非規範化表每天兩次，我們刪除所有索引，以便在我們加載新日期並重建所有索引後強制DB重建索引和sproc執行計劃。

當然，我們有單獨的腳本，因爲一旦你放下它們，索引就不再在系統表中了。

Answer 4

使用遊標來編寫腳本比使用臨時表（稍微簡單些）更具慣用性。要重新啓用索引，請用REBUILD替換DISABLE。

DECLARE cur_indexes CURSOR FOR 
SELECT sys.objects.name tableName, 
     sys.indexes.name indexName 
FROM sys.indexes 
     JOIN sys.objects ON sys.indexes.object_id = sys.objects.object_id 
WHERE sys.indexes.type_desc = 'NONCLUSTERED' 
     AND sys.objects.type_desc = 'USER_TABLE' 

DECLARE @TblName NVARCHAR(255), @IdxName NVARCHAR(255) 

DECLARE @SQL NVARCHAR(MAX) 

open cur_indexes 
fetch next from cur_indexes into @TblName, @IdxName 

WHILE @@FETCH_STATUS = 0 
BEGIN 
    SELECT @SQL = N'ALTER INDEX ' + @IdxName + N' ON ' + @TblName + ' DISABLE;' 

    EXEC sp_sqlexec @SQL  

    fetch next from cur_indexes into @TblName, @IdxName 
END 

close cur_indexes 
deallocate cur_indexes