VBA excel如何檢查單元格的偏移量是否指工作表內的單元格

Question

我想檢查單元格中有多少個鄰居爲空。 如果我不知道我的手機是否有8個鄰居或更少，我該怎麼做？ 這是我的代碼。它只適用於我的單元格不在工作表的第一行或最後一行或列。

Sub neighbors() 
Dim count%, i%, j% 
count = 0 
For i = -1 To 1 
    For j = -1 To 1 
     If VBA.IsEmpty(ActiveCell.Offset(i, j)) Then count = count + 1 
    Next j 
Next i 
' If activecell is empty - don't count it 
If VBA.IsEmpty(ActiveCell) Then count = count - 1 
MsgBox count 
End Sub 

Answer 1

創建計算邊界的數組，並用它來定義你的「鄰居」細胞塊。

Option Explicit 

Sub neighbors() 
    Dim n As Long, bounds As Variant 

    With ActiveCell 
     bounds = Array(Application.Max(1, .Row - 1), _ 
         Application.Max(1, .Column - 1), _ 
         Application.Min(.Parent.Rows.count, .Row + 1), _ 
         Application.Min(.Parent.Columns.count, .Column + 1)) 
    End With 
    With ActiveCell.Parent 
     With .Range(.Cells(bounds(0), bounds(1)), .Cells(bounds(2), bounds(3))) 
      Debug.Print .Address(0, 0) 
      n = Application.CountBlank(.Cells) + CBool(IsEmpty(ActiveCell)) 
     End With 
    End With 

    MsgBox n 
End Sub 

Answer 2

嘗試下面的代碼，你需要檢查ActiveCell.Row和ActiveCell.Column，看看他們是首當其衝。

代碼

Option Explicit 

Sub neighbors() 

Dim count As Long, i As Long, j As Long 
Dim firstRow As Long, FirstCol As Long 

count = 0 
If ActiveCell.Row < 2 Then '<-- first row 
    firstRow = 0 
Else 
    firstRow = -1 
End If 
If ActiveCell.Column < 2 Then '<-- first column ("A") 
    FirstCol = 0 
Else 
    FirstCol = -1 
End If 

For i = firstRow To 1 
    For j = FirstCol To 1 
     If IsEmpty(ActiveCell.Offset(i, j)) Then count = count + 1 
    Next j 
Next i 

' If activecell is empty - don't count it 
If IsEmpty(ActiveCell) Then count = count - 1 
MsgBox count 

End Sub