在Perl中執行多線程應該注意哪些模塊？

Question

我應該看看在Perl中使用多線程處理哪些模塊？

我期待做一些相當低的性能;我想要的線程是同時運行多個工作人員，他們每個人都睡眠不同的時間。

Answer 1

最新版本的Perl具有線程支持。運行perl -V:usethreads以查看它是否在您的系統中可用。

$ perl -V:usethreads 
usethreads='define' 

perldoc threads給出了一個很好的使用它們的介紹。

Answer 2

如果性能是不是一個大問題，然後fork荷蘭國際集團多個進程可能比處理線程容易得多。我經常使用Parallel::ForkManager這非常簡單，但非常擅長它。

Answer 3

這聽起來像你不需要先發制人的多線程;在這種情況下，請看POE的合作模式。由於您的代碼在您決定時只會屈服於其他線程，並且一次只能運行一個線程，所以開發和調試將更容易。

Answer 4

Coro是合作多任務一個很好的模塊。

99％的時間，這是你需要的，如果你想在Perl中的線程。

如果你想線程以加快你的代碼時，多個核心可用，你會走上錯誤的道路。 Perl比其他語言慢了50倍。將代碼重寫爲在兩個CPU上運行意味着它現在在一個CPU上的運行速度比其他語言慢25倍。最好花費精力將緩慢的部分移植到不同的語言。

但如果你只是不想IO阻止其他「線程」，然後科羅正是你想要的。

Answer 5

有很多原因可能導致您不想多線程。但是，如果您確實想要多線程，下面的代碼可能是一個有用的示例。它創建了一些作業，將它們放入一個線程安全的隊列中，然後啓動一些從隊列中取出作業並完成作業的線程。每個線程在循環中不斷從隊列中提取作業，直到看不到任何作業。程序等待所有線程完成，然後打印它在工作中花費的總時間。

#!/usr/bin/perl 

use threads; 
use Thread::Queue; 
use Modern::Perl; 

my $queue= Thread::Queue->new; 
my $thread_count= 4; 
my $job_count= 10; 
my $start_time= time; 
my $max_job_time= 10; 

# Come up with some jobs and put them in a thread-safe queue. Each job 
# is a string with an id and a number of seconds to sleep. Jobs consist 
# of sleeping for the specified number of seconds. 
my @jobs= map {"$_," . (int(rand $max_job_time) + 1)} (1 .. $job_count); 
$queue->enqueue(@jobs); 

# List the jobs 
say "Jobs IDs: ", join(", ", map {(split /,/, $_)[0]} @jobs); 

# Start the threads 
my @threads= map {threads->create(sub {function($_)})} (1 .. $thread_count); 

# Wait for all the threads to complete their work 
$_->join for (@threads); 

# We're all done 
say "All done! Total time: ", time - $start_time; 

# Here's what each thread does. Each thread starts, then fetches jobs 
# from the job queue until there are no more jobs in the queue. Then, 
# the thread exists. 
sub function { 
    my $thread_id= shift; 
    my ($job, $job_id, $seconds); 
    while($job= $queue->dequeue_nb) { 
    ($job_id, $seconds)= split /,/, $job; 
    say "Thread $thread_id starting on job $job_id ", 
     "(job will take $seconds seconds)."; 
    sleep $seconds; 
    say "Thread $thread_id done with job $job_id."; 
    } 
    say "No more jobs for thread $thread_id; thread exiting."; 
}