帶空格和括號的批處理文件變量

Question

我已閱讀了不同方法獲取windows批處理文件解析器以正確處理具有空格，括號和其他特殊字符的變量的許多線程，但似乎沒有任何建議可以解決我遇到的問題。

這裏是腳本（之前嘗試的任何變通辦法），其目標是建立發現variable01和variable02基於價值variable03值：

set variable01="C:\Program Files (x86)\SomeProgram\Subfolder" 
set variable02="${macro}" 

set variable01=%variable01:"=% 
set variable02=%variable02:"=% 

set variable03="" 

if %variable02:~0,1%==$ (
    if %variable01:~0,1%==$ (
     set variable03=%variable03:"=% 
    ) else (
     set variable03=-o '%variable01%' 
    ) 
) 

... variable01的價值觀和variable02並不是事先知道的 - 在運行腳本之前它們會被另一個程序替代，所以上面的腳本顯示了在替換完成後變量01和變量02的一組示例值。

我得到當此腳本運行錯誤是：

\SomeProgram\Subfolder' was unexpected at this time. 

...這對應於上述腳本中的最後「設置」行。我認爲這個錯誤是由於variable01的括號中的。

如果我把上面一行是：

set "variable03=-o '%variable01%'" 

...然後我得到這個錯誤：

Files was unexpected at this time. 

...這似乎表明，它試圖來標記的變量01中的空格，解析器仍然不滿意。

如果我再在腳本的頂部添加這一行：

setlocal enableextensions enableDelayedExpansion 

...並更改％variable01％至variable01！我仍然得到同樣的錯誤。

很顯然，我不明白是什麼批處理文件分析器需要滿足我的要求，即variable03的值具有以下值：

-o 'C:\Program Files (x86)\SomeProgram\Subfolder' 

...有什麼建議？

Answer 1

問題是variable01的括號中的值。由於它的擴展條件是if，因此這些括號被解釋爲流量控制。通過始終將其放在雙引號中進行修復。

set variable01="C:\Program Files (x86)\SomeProgram\Subfolder" 
set variable02="${macro}" 

set variable01=%variable01:"=% 
set variable02=%variable02:"=% 

set variable03="" 

if "%variable02:~0,1%"=="$" (
    if "%variable01:~0,1%"=="$" (
     set variable03=%variable03:"=% 
    ) else (
     call :set3 "%variable01%" 
    ) 
) 
goto :eof 

REM If it is important to have single quotes instead of double then 
REM I found I had to call a subroutine. Otherwise the set could be 
REM left up in the else. 
:set3 
set variable03=-o '%~1' 
goto :eof 

Answer 2

正如Nate寫的，這裏的問題是括號，但是完整的代碼仍然不穩定。

使用延遲擴展總是更好，因爲這對任何特殊字符都是安全的。
你應該使用SETset "variable=content"的擴展語法用引號括完整的表達式，那麼它幾乎是安全的，且報價不添加到內容。
而且您不需要稍後刪除引號。

這應與VAR1任何內容工作，VAR2

setlocal EnableDelayedExpansion 
set "variable01=C:\Program Files (x86)\SomeProgram\Subfolder" 
set "variable02=${macro}" 

set "variable03=" 

if "!variable02:~0,1!"=="$" (
    if "!variable01:~0,1!"=="$" (
     rem 
    ) else (
     set "variable03=-o '!variable01!'" 
    ) 
) 
echo(!variable03!