我可以在Perl中訪問動態指定類中的靜態方法嗎？

Question

是否可以在Perl中動態指定一個類並訪問該類中的靜態方法？這是不行的，但足以說明我想做什麼：

use Test::Class1; 
    my $class = 'Test::Class1'; 
    $class::static_method();  

我知道我能做到這一點：

$class->static_method(); 

，並忽略傳遞給static_method類的名字，但我不知道是否有一個更好的方法。

Answer 1

我不知道這樣做的特別好的方式，但也有一些不太好的方面，比如這個程序：

#!/usr/bin/perl -w 

use strict; 

package Test::Class1; 

sub static_method { 
    print join(", ", @_) . "\n"; 
} 

package main; 

my $class = "Test::Class1"; 

{ 
    no strict "refs"; 
    &{${class}. "::static_method"}(1, 2, 3); 
} 

我已經包含了一個$class變量，因爲這是你怎麼問問題，並說明如何在運行時選擇課程名稱，但如果您事先知道該課程，則可以輕鬆地致電&{"Test::Class1::static_method"}(1, 2, 3);

請注意，如果您有開啓課程，則必須關閉strict "refs"。

Answer 2

您可以使用字符串eval：

#!/usr/bin/perl 

use strict; use warnings; 

package Test::Class1; 

sub static_method { 
    print join(", ", @_) . "\n"; 
} 

package main; 

my $class = 'Test::Class1'; 
my $static_method = 'static_method'; 

my $subref = eval q{ \&{ "${class}::${static_method}" } }; 
$subref->(1, 2, 3); 

輸出：

 
C:\Temp> z 
1, 2, 3 

基準：

#!/usr/bin/perl 

use strict; use warnings; 

package Test::Class1; 

sub static_method { "@_" } 

package main; 

use strict; use warnings; 
use Benchmark qw(cmpthese); 

my $class = 'Test::Class1'; 
my $static_method = 'static_method'; 

cmpthese -1, { 
    'can' => sub { my $r = $class->can($static_method); $r->(1, 2, 3) }, 
    'eval' => sub { 
     my $r = eval q/ \&{ "${class}::${static_method}" } /; 
     $r->(1, 2, 3); 
    }, 
    'nostrict' => sub { 
     no strict "refs"; 
     my $r = \&{ "${class}::static_method" }; 
     $r->(1, 2, 3); 
    } 
}; 

輸出：

 
      Rate  eval  can nostrict 
eval  12775/s  --  -94%  -95% 
can  206355/s 1515%  --  -15% 
nostrict 241889/s 1793%  17%  -- 

Answer 3

是！嚴格執行的方法是使用can。

package Foo::Bar; 
use strict; 
use warnings; 

sub baz 
{ 
    return "Passed in '@_' and ran baz!"; 
} 

package main; 
use strict; 
use warnings; 

my $class = 'Foo::Bar'; 

if (my $method = $class->can('baz')) 
{ 
    print "yup it can, and it "; 
    print $method->(); 
} 
else 
{ 
    print "No it can't!"; 
} 

can返回對方法undef/false的引用。然後您只需使用dereferene語法來調用該方法。

它提供：

 
    > perl foobar.pl 
    yup it can, and it Passed in '' and ran baz! 

Answer 4

有調用靜態函數方式主要有三種：

• $object->static_method()
• Classname->static_method()
• Classname::static_method()

你可以定義你的函數是這樣的：

# callable as $object->static_method() or Classname->static_method() 
sub static_method 
{ 
    my $class = shift; # ignore; not needed 
    # ... 
} 

或類似這樣的，這在所有三個調用場景的作品，而不會產生對來電者的側像羅伯特·普的解決方案的任何開銷的作用：

use UNIVERSAL qw(isa); 

sub static_method 
{ 
    my $class = shift if $_[0] and isa($_[0], __PACKAGE__); 
    # ... 
} 

Answer 5

與Perl一樣，there is more than one way to do it。

use strict; 
use warnings; 
{ 
    package Test::Class; 
    sub static_method{ print join(' ', @_), "\n" } 
} 

• 您可以使用特殊%::變量來訪問符號表。

  my $class = 'Test::Class'; 
  my @depth = split '::', $class; 
  
  my $ref = \%::; 
  $ref = $glob->{$_.'::'} for @depth; # $::{'Test::'}{'Class::'} 
  
  $code = $glob->{'static_method'}; 
  $code->('Hello','World'); 
  

• 您可以只使用一個symbolic reference;

  no strict 'refs'; 
  my $code = &{"${class}::static_method"}; 
  # or 
  my $code = *{"${class}::static_method"}{CODE}; 
  $code->('Hello','World'); 
  

• 您還可以使用字符串eval。

  eval "${class}::static_method('Hello','World')"; 
  

• 在這種情況下，簡單地說，是使用UNIVERSAL::can。

  $code = $class->can('static_method'); 
  $code->('Hello','World');