Perl程序返回兩個堆棧調用級別

Question

我的問題類似於： Is it possible for a Perl subroutine to force its caller to return? 但我需要程序方法。

我想用編程回一些消息處理過程，例如必需的代碼：

sub PrintMessage { 
    #this function can print to the screen and both to logfile 
    print "Script message: $_[0]\n"; 
} 

sub ReturnMessage { 
    PrintMessage($_[0]); 
    return $_[2]; # <-- we thinking about *this* return 
} 

sub WorkingProc { 
    PrintMessage("Job is started now"); 
    #some code 
    PrintMessage("processed 5 items"); 

    # this should return from WorkingProc with given exitcode 
    ReturnMessage("too many items!",5) if $items>100; 

    #another code 
    ReturnMessage("time exceded!",6) if $timespent>3600; 
    PrintMessage("All processed succesfully"); 
    return 0; 
} 

my $ExitCode=WorkingProc(); 
#finish something 
exit $ExitCode 

理念是，如何使用ReturnMessage函數內部回報率從WorkingProc功能指定的代碼退出？注意，ReturnMessage函數是從很多地方調用的。

Answer 1

這是不可能的。但是，可以明確地返回：

sub WorkingProc { 
    PrintMessage("Job is started now"); 
    ... 
    PrintMessage("processed 5 items"); 

    # this returns from WorkingProc with given exitcode 
    return ReturnMessage("to much items!", 5) if $items > 100; 

    ... 
    return ReturnMessage("time exceded!", 6) if $timespent > 3600; 
    PrintMessage("All processed succesfully"); 
    return 0; 
} 

一個子可以有任意數量return語句，所以這不是一個問題。

這樣的解決方案比通過調用堆棧進行黑客攻擊更可取，因爲控制流對讀者來說更爲明顯。你夢想的是一種GOTO，大多數不寫C或BASIC等的人已經放棄了45年前。

您的代碼依賴退出代碼來確定子例程中的錯誤。 *嘆*。 Perl有一個相當倒退的異常系統，但仍比那個更先進，即。

拋出致命錯誤die "Reason"或use Carp和croak "Reason"。使用Try::Tiny或TryCatch模塊捕獲錯誤。

sub WorkingProc { 
    PrintMessage("Job is started now"); 
    ... 
    PrintMessage("processed 5 items"); 

    # this should return from WorkingProc with given exitcode 
    die "Too much items!" if $items > 100; 

    ... 
    die "Time exceeded" if $timespent > 3600; 
    PrintMessage("All processed succesfully"); 
    return 0; 
} 

WorkingProc(); 

如果發生錯誤，將以非零狀態退出。

Answer 2

對於非本地返回而言，想到的方法是從最內層的函數中拋出一個異常（死）。

然後你需要有一些包裝代碼來處理它在頂層。你可以設計一套實用程序來自動設置。

Answer 3

使用與Exception::Class結合Log::Any和Log::Any::Adapter讓你把所有的作品以最小的大驚小怪和最大的靈活性在一起：

#!/usr/bin/env perl 

package My::Worker; 
use strict; use warnings; 

use Const::Fast; 
use Log::Any qw($log); 

use Exception::Class (
    JobException => { fields => [qw(exit_code)] }, 
     TooManyItemsException => { 
      isa => 'JobException', 
      description => 'The worker was given too many items to process', 
     }, 
     TimeExceededException => { 
      isa => 'JobException', 
      description => 'The worker spent too much time processing items', 
     }, 
); 

sub work { 
    my $jobid = shift; 
    my $items = shift; 

    const my $ITEM_LIMIT => 100; 
    const my $TIME_LIMIT => 10; 

    $log->infof('Job %s started', $jobid); 

    shift @$items for 1 .. 5; 
    $log->info('Processed 5 items'); 

    if (0.25 > rand) { 
     # throw this one with 25% probability 
     if (@$items > $ITEM_LIMIT) { 
      TooManyItemsException->throw(
       error => sprintf(
        '%d items remain. Limit is %d.', 
        scalar @$items, $ITEM_LIMIT, 
       ), 
       exit_code => 5, 
      ); 
     } 
    } 

    { # simulate some work that might take more than 10 seconds 
     local $| = 1; 
     for (1 .. 40) { 
      sleep 1 if 0.3 > rand; 
      print '.'; 
     } 
     print "\n"; 
    } 
    my $time_spent = time - $^T; 
    ($time_spent > $TIME_LIMIT) and 
     TimeExceededException->throw(
      error => sprintf (
       'Spent %d seconds. Limit is %d.', 
       $time_spent, $TIME_LIMIT, 
      ), 
      exit_code => 6); 
    $log->info('All processed succesfully'); 
    return; 
} 

package main; 

use strict; use warnings; 
use Log::Any qw($log); 
use Log::Any::Adapter ('Stderr'); 

eval { My::Worker::work(exceptional_job => [1 .. 200]) }; 
if (my $x = JobException->caught) { 
    $log->error($x->description); 
    $log->error($x->error); 
    exit $x->exit_code; 
} 

輸出示例：

Job exceptional_job started 
Processed 5 items 
........................................ 
The worker spent too much time processing items 
Spent 12 seconds. Limit is 10.

或

Job exceptional_job started 
Processed 5 items 
The worker was given too many items to process 
195 items remain. Limit is 100.