從兩個線程保護字符串緩衝區？

Question

我正在通過Indy套接字處理流式數據包字符串，並且在客戶端，我有一個線程，它從TIdTCPClient中讀取傳入數據並不斷將此數據附加到單個字符串緩衝區的末尾。我有另一個線程，它從頭開始連續讀取此緩衝區，根據需要複製（和刪除）數據（一次完成一個完整的數據包）。

我知道在任何情況下，訪問相同變量的兩個線程都可能是危險的。但這是否也適用於字符串？或者只是對象？我能從兩個不同的線程讀取/寫入相同的字符串，感覺安全嗎？如果不是，那麼我應該怎麼做才能保護這個字符串？這是一個簡單的字符串，稱爲FBuffer。

我將數據追加到最後，像這樣：

procedure TListenThread.CheckForData; 
begin 
    if FClientSocket.Connected then begin 
    FClientSocket.IOHandler.CheckForDataOnSource(5000); 
    if not FClientSocket.IOHandler.InputBufferIsEmpty then 
     FBuffer:= FBuffer + FClientSocket.IOHandler.InputBufferAsString; 
    end; 
end; 

而另一個線程正在讀它，像這樣：

procedeure TPacketThread.CheckForPacket; 
var 
    P: Integer; //Deliminator position 
    T: String; //Temp copying string 
    Z: Integer; //Expected packet size 
begin 
    P:= Pos('#', FBuffer); 
    if P > 0 then begin //Is the deliminator found? 
    T:= Copy(FBuffer, 1, P-1); //Copy up to deliminator... 
    Z:= StrToIntDef(T, 0); //Convert packet size to integer... 
    if Z > 0 then begin 
     //Is there a full packet waiting in buffer? 
     if Length(FBuffer) >= Z then begin 
     //First, delete size definition and deliminator... 
     Delete(FBuffer, 1, P); 
     //Now grab the rest of it up to the packet size... 
     T:= Copy(FBuffer, 1, Z); 
     //Delete what we just copied... 
     Delete(FBuffer, 1, Z); 
     //Finally, pass this packet string for further processing... 
     ProcessPacket(T); 
     end; 
    end; 
    end; 
end; 

的代碼是我的代碼的簡化版本，只是展示我需要做的所有工作FBuffer。

Answer 1

是的，您必須保護字符串緩衝區免受併發訪問。印地有一個TIdThreadSafeString類，你可以用於這一目的，例如：

FBuffer: TIdThreadSafeString; 
// make sure to Create() and Free() as needed.. 

。

procedure TListenThread.CheckForData; 
begin 
    if FClientSocket.Connected then begin 
    FClientSocket.IOHandler.CheckForDataOnSource(5000); 
    if not FClientSocket.IOHandler.InputBufferIsEmpty then 
     FBuffer.Append(FClientSocket.IOHandler.InputBufferAsString); 
    end; 
end; 

。

procedure TPacketThread.CheckForPacket; 
var 
    P: Integer; //Deliminator position 
    T: String; //Temp copying string 
    Z: Integer; //Expected packet size 
begin 
    FBuffer.Lock; 
    try 
    P:= Pos('#', FBuffer.Value); 
    if P > 0 then begin //Is the deliminator found? 
     T := Copy(FBuffer.Value, 1, P-1); //Copy up to deliminator... 
     Z := StrToIntDef(T, 0); //Convert packet size to integer... 
     if Z > 0 then begin 
     //Is there a full packet waiting in buffer? 
     if Length(FBuffer.Value) >= Z then begin 
      //First, delete size definition and deliminator... 
      FBuffer.Value := Copy(FBuffer.Value, P+1, MaxInt); 
      //Now grab the rest of it up to the packet size... 
      T := Copy(FBuffer.Value, 1, Z); 
      //Delete what we just copied... 
      FBuffer.Value := Copy(FBuffer.Value, Z+1, MaxInt); 
      //Finally, pass this packet string for further processing... 
      ProcessPacket(T); 
     end; 
     end; 
    end; 
    finally 
    FBuffer.Unlock; 
    end; 
end; 

雖這麼說，給你表明了對數據包的格式是什麼，我會採取不同的策略，而不是：

FBuffer: TIdThreadSafeStringList; 
// make sure to Create() and Free() as needed.. 

。

procedure TListenThread.CheckForData; 
var 
    T: String; //Temp copying string 
    Z: Integer; //Expected packet size 
begin 
    if FClientSocket.Connected then begin 
    if FClientSocket.IOHandler.InputBufferIsEmpty then begin 
     FClientSocket.IOHandler.CheckForDataOnSource(5000); 
     if FClientSocket.IOHandler.InputBufferIsEmpty then Exit; 
    end; 
    // data is available, keep reading as long as packets are present... 
    repeat 
     T := FClientSocket.IOHandler.ReadLn('#'); 
     Z := StrToIntDef(T, 0); 
     if Z > 0 then begin 
     T := FClientSocket.IOHandler.ReadString(Z); 
     FBuffer.Add(T); 
     end; 
    until FClientSocket.IOHandler.InputBufferIsEmpty; 
    end; 
end; 

。

procedure TPacketThread.CheckForPacket; 
var 
    L: TStringList; 
    T: String; 
begin 
    L := FBuffer.Lock; 
    try 
    if L.Count = 0 then Exit; 
    T := L[0]; 
    L.Delete(0); 
    finally 
    FBuffer.Unlock; 
    end; 
    ProcessPacket(T); 
end; 

Answer 2

是的，您必須保護從多個線程訪問時的字符串，您可以使用crtical部分。看看EnterCriticalSection,LeaveCriticalSection,InitializeCriticalSection和DeleteCriticalSection的功能。