如何確保兩個節點之間的路徑通過中間節點的所有連接？

Question

我可能試圖以最愚蠢的方式解決問題，所以如果有更簡單的方法來解決問題，請糾正。我試圖通過圖來模擬一些條件。在這種情況下，我們有人員和健康計劃。

比方說，要符合健康計劃A的資格，您必須住在某個地方並且是全職的，或者您可以住在另一個地方並且是全職或兼職的。

我對這種建模的方式是在一個人和一個計劃之間的一系列路徑中，計劃之前的最後一個節點是「條件」節點。我認爲這個結構允許AND和OR關係。鏈接到計劃的多個條件表示OR（您可以處於一種狀態，或者您可以處於不同的狀態並且是全職的）。

下面是一個人（黃色節點：「FTai」不詢問名稱）和計劃（綠色節點）之間路徑的圖片。

紅色節點表示條件，並且規則是如果從人到條件通過所有條件的傳入連接都有一條路徑，則此人可以利用此健康計劃。我如何編寫一個查詢，針對某個特定的人收集他們可以訪問的所有計劃？

例如，對於其他人（「Hai」），查詢不應該生成計劃，因爲它們沒有連接到提供給Connection的Full Time節點。

Answer 1

有趣的問題。

如果所存在的關係對於評估條件都是有意義的（例如，否：與夏威夷的ONCE_LIVED_IN關係或可能導致條件錯誤評估爲真的類似關係），並提供關係方向到一個計劃都是單向的，沒有其他外向關係可能會使一條路徑變成一個不相關的子圖，它應該是相當直接的形式來查詢。

下面是在你的描述圖中的創建查詢：

create (p:Person{name:'FTai'}), (p2:Person{name:'Hai'}) 
create (hi:State{name:'Hawaii'}) 
create (con:Condition) 
create (hhc:Plan{name:'Hawaii Healthcare'}) 
create (ft:EmploymentStatus{name:'Full Time'}) 
create (pt:EmploymentStatus{name:'Part Time'}) 
create (con)-[:ALLOWS]->(hhc) 
create (ft)-[:REQUIRED_BY]->(con) 
create (hi)-[:REQUIRED_BY]->(con) 
create (p)-[:HAS_STATUS]->(ft) 
create (p)-[:LIVES_IN]->(hi) 
create (p2)-[:HAS_STATUS]->(pt) 
create (p2)-[:LIVES_IN]->(hi) 

下面是開始於一個查詢：人，直至達到如下傳出關係：條件。從那裏，對於每一個：匹配的條件，我們從這些路徑中收集不同的最後一個關係：條件（應該是：REQUIRED_BY關係），並將其與進入：條件的傳入：REQUIRED_BY關係的數量進行比較。如果關係數量相同，那麼我們已滿足：REQUIRED_BY關係到：Condition中，並且可以返回連接的Plan：Plan。

MATCH (p:Person{name:'FTai'})-[r*..5]->(con:Condition) 
WITH con, COLLECT(DISTINCT LAST(r)) as metRequirements 
WHERE SIZE(metRequirements) = SIZE(()-[:REQUIRED_BY]->(con)) 
MATCH (con)-[:ALLOWS]->(plan:Plan) 
RETURN DISTINCT plan 

編輯

我的創作查詢不包括：DEFINED_AS狀態和就業狀況之間的關係，以及這種關係的存在會導致我公司提供的不當匹配查詢（所以海會錯誤地履行條件）。

圍繞這種障礙有幾種方法。你可以做白名單或黑名單。對於白名單，您需要提供每個有效的關係以在可變長度關係中遍歷。

如果您的查詢不應該遍歷關係類型，那麼黑名單可能會更容易。下面是查詢的更新版本，將工作即使：DEFINED_AS關係到位：

// you can add to the blacklist as needed, and change to a parameter 
WITH ['DEFINED_AS'] as blacklist 
MATCH (p:Person{name:'Hai'})-[r*..5]->(con:Condition) 
WHERE NONE(rel in r WHERE TYPE(rel) in blacklist) 
WITH con, COLLECT(DISTINCT LAST(r)) as metRequirements 
WHERE SIZE(metRequirements) = SIZE(()-[:REQUIRED_BY]->(con)) 
MATCH (con)-[:ALLOWS]->(plan:Plan) 
RETURN DISTINCT plan 

Answer 2

也許我不明白您的查詢的有關像這樣的複雜性，但如何：

match (state:State)-[:REQUIRED_BY]->(and:Condition)<-[:REQUIRED_BY]-(status:EmploymentStatus) 
with state,status,and 
match (status)<-[:HAS_STATUS]-(person:Person)-[:LIVES_IN]->(state) 
with person, and 
match (and)-[:ALLOWS]->(plan:Plan) 
return person, plan