如何在xsl翻譯時忽略命名空間

Question

我有一個如下所示的xml。

<?xml version="1.0" encoding="UTF-8"?> 
<books xmlns="http://www.books.com/SRK"> 
    <name>English</name> 
</books 

我需要使用xsl進行翻譯後的以下輸出。

<?xml version="1.0" encoding="UTF-8"?> 
<books> 
    <name>English</name> 
</books> 

我需要一個xsl來忽略命名空間。我嘗試了一些東西，但它沒有與命名空間一起工作。

我需要你的幫助。你的幫助將不勝感激。

Answer 1

這種轉變：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="@*|node()[not(self::*)]"> 
    <xsl:copy/> 
</xsl:template> 

<xsl:template match="*"> 
    <xsl:element name="{local-name()}"> 
    <xsl:apply-templates select="node()|@*"/> 
    </xsl:element> 
</xsl:template> 
</xsl:stylesheet> 

當應用於提供的XML文檔：

<books xmlns="http://www.books.com/SRK"> 
    <name>English</name> 
</books> 

產生想要的，正確的結果：

<books> 
    <name>English</name> 
</books> 

Answer 2

其工作只有當我包括上述模板，如果我添加一些其他模板比以上一個，那麼翻譯是不是工作。沒有模板得到執行。

可能您錯過了book元素的名稱空間聲明。例如：

<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:b="http://www.books.com/SRK" 
    exclude-result-prefixes="b"> 

    <xsl:output omit-xml-declaration="yes" indent="yes"/> 
    <xsl:strip-space elements="*"/> 

     <!-- @dimitre's answer templates --> 

    <xsl:template match="b:name"> 
      <!-- your template for name --> 
    </xsl:template> 

</xsl:stylesheet> 

此外，請務必使用local-name()函數來獲取元素的名稱，沒有相關的命名空間。

---

例

<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:b="http://www.books.com/SRK" 
    exclude-result-prefixes="b"> 
    <xsl:output method="xml" encoding="UTF-8" indent="yes"/> 


    <xsl:template match="b:input"> 
     <xsl:element name="{local-name(.)}"> 
       <xsl:apply-templates select="b:name"/> 
     </xsl:element> 
    </xsl:template> 

    <xsl:template match="b:name"> 
     <xsl:element name="{local-name()}"> 
      <xsl:value-of select="."/> 
     </xsl:element> 
      <lhs> 
       <xsl:apply-templates select="following-sibling::b:lhs/b:evaluate"/> 
      </lhs> 
    </xsl:template> 

    <xsl:template match="b:evaluate"> 
     Something to evaluate...  
    </xsl:template> 

</xsl:stylesheet> 

得到：

<?xml version="1.0" encoding="UTF-8"?> 
<input> 
<name>English</name> 
<lhs> 
     Something to evaluate...  
    </lhs> 
</input> 

---

第二示例

您可以創建一個名爲local @ identity.xsl的單獨轉換，其中包含@Dimitre解決方案。然後你可以在你的轉換中導入它。因爲你有一個命名空間，搭配元素，你必須改變所有您的XPath，包括您將在變換聲明前綴，如下面的例子：

<xsl:stylesheet 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:brl="http://www.xyz.com/BRL" 
    exclude-result-prefixes="brl" 
    version="1.0"> 

    <xsl:import href="local-identity.xsl"/> 

    <xsl:output method="xml" indent="yes"/> 
    <xsl:strip-space elements="*"/> 


    <xsl:template match="/brl:rule"> 
    <!-- do your staff, select using brl prefix --> 
    <xsl:apply-templates/> 
    </xsl:template> 

</xsl:stylesheet>