Clojure：讀取數據庫的元數據

Question

我想從sqlite數據庫中獲取元數據。目前的主要目的是獲得表格列表。

代碼如下（從這裏開始：link）：

(defn db-get-tables 
"Demonstrate getting table info" 
[] 
(sql/with-connection db 
    (into [] 
     (resultset-seq 
     (-> (sql/connection) 
      (.getMetaData) 
      (.getTables nil nil nil (into-array ["TABLE" "VIEW"]))))))) 

這給了我與有關的元數據在數據庫中的表映射列表。但是，如果我嘗試遍歷這個列表（使用「對」或「第一」）它給了我：

"Don't know how to create ISeq from proj00.operations.database$tables-list" 

我認爲，必須有一個簡單的方法來做到這一點。但我無法在網上找到正確的信息。另外，我不明白錯誤來自哪裏。

Answer 1

這可能是因爲與數據庫的連接只在「sql/with connection db」的範圍內打開。如果我使用Microsoft SQL像這樣遍歷集合，則會出現連接已關閉的錯誤。

如果將resultset-seq包裝在doall中，則應該修復此問題。儘管有利於將所有結果存入內存並能夠關閉連接，但這會打破懶惰。如果你想保持懶惰，你應該把迭代放在「with-connection」範圍內，但是你會保持連接打開，直到完成。

此外，您還可以概括這個功能爲通過使本的宏（感謝VerneriÅberg的回答我的問題），支持所有元數據的方法：

(defmacro get-sql-metadata [db method & args] 
    `(with-connection 
    ~db 
    (doall 
     (resultset-seq 
     (~method 
      (.getMetaData (connection)) 
      ~@args))))) 

所以，現在你可以調用與元數據元數據的方法和它自己的參數，像這樣：

(get-sql-metadata db .getTables nil nil nil (into-array ["TABLE" "VIEW"])) 
or 
(get-sql-metadata db .getColumns nil nil nil nil) 

跟帖： 創建一個testdatabase，連接，一切都應該像這樣工作。

Leiningen

(defproject sqlitetest "1.0.0-SNAPSHOT" 
    :description "FIXME: write description" 
    :dependencies [[org.clojure/clojure "1.3.0"] 
        [org.xerial/sqlite-jdbc "3.6.16"] 
        [org.clojure/java.jdbc "0.1.0"]]) 

計劃

(ns sqlitetest 
    (:use [clojure.java.jdbc])) 

(def db { :classname "org.sqlite.JDBC" 
      :subprotocol "sqlite" 
      :subname "E:/temp/chinook.db"}) 

(defmacro get-sql-metadata [db method & args] 
    `(with-connection 
    ~db 
    (doall 
     (resultset-seq 
     (~method 
      (.getMetaData (connection)) 
      ~@args))))) 

(def tables-list 
    (get-sql-metadata db .getTables nil nil nil (into-array ["TABLE" "VIEW"]))) 

REPL

sqlitetest=>(map :table_name tables-list) 
("SQLITE_SEQUENCE" "ALBUM" "ARTIST" "CUSTOMER" "EMPLOYEE" "GENRE" "INVOICE" "INVOICELINE" "MEDIATYPE" "PLAYLIST" "PLAYLISTTRACK" "TRACK") 

sqlitetest=>(first tables-list) 
{:self_referencing_col_name nil, :table_name "SQLITE_SEQUENCE", :type_schem nil, :ref_generation nil, :table_type "TABLE", :table_schem nil, :table_cat nil, :type_cat nil, :type_name nil, :remarks nil} 

您的評論備註，並回答 錯誤是由做的DEFN代替DEF引起的問題在桌子上在你的評論中的電子列表。如果我使用defn，我會遇到同樣的錯誤。