通過VBA發送時，在Lotus Notes中設置「From」電子郵件地址

Question

我在Access數據庫中使用VBA函數來調用Lotus Notes以向客戶發送自動電子郵件。電子郵件正在從用戶個人Lotus帳戶發送，以便他們在已發送郵件中記錄已發送電子郵件的歷史記錄。但是，我不希望客戶看到我們的內部電子郵件地址。

我們正在指示客戶不要回覆電子郵件（而不是給我們打電話），並希望電子郵件看起來來自noreply@company.com。我能夠將'ReplyTo'字段設置爲像noreply@company.com這樣的東西，如果客戶回覆電子郵件但「發件人」字段仍然來自用戶的真實電子郵件地址並且客戶可以看到這些信息，並仍然發送電子郵件到我們的地址。

我已經嘗試設置以下屬性，但他們似乎並不工作：

.DisplaySent = "noreply@company.com" 
.iNetFrom = "noreply@company.com" 
.iNetPrincipal = "noreply@company.com" 

（我現在有這些註釋掉在下面的VBA，因爲他們似乎沒有任何效果）

下面是我正在使用的VBA。有什麼建議麼？ 謝謝！

Public Sub SendNotesMail(Subject As String, Attachment As String, Recipient As  Variant, BodyText As String, SaveIt As Boolean) 

    'Set up the objects required for Automation into lotus notes 
    Dim Maildb As Object 'The mail database 
    Dim UserName As String 'The current users notes name 
    Dim MailDbName As String 'THe current users notes mail database name 
    Dim MailDoc As Object 'The mail document itself 
    Dim AttachME As Object 'The attachment richtextfile object 
    Dim Session As Object 'The notes session 
    Dim EmbedObj As Object 'The embedded object (Attachment) 

    'Start a session to notes 
    Set Session = CreateObject("Notes.NotesSession") 

    'Next line only works with 5.x and above. Replace password with your password 
    'Session.Initialize ("password") 
    'Get the sessions username and then calculate the mail file name 
    'You may or may not need this as for MailDBname with some systems you 
    'can pass an empty string or using above password you can use other mailboxes. 
    UserName = Session.UserName 
    MailDbName = Left$(UserName, 1) & Right$(UserName, (Len(UserName) - InStr(1, UserName, " "))) & ".nsf" 

    'Open the mail database in notes 
    Set Maildb = Session.GETDATABASE("", MailDbName) 
    If Maildb.ISOPEN = True Then 
     'Already open for mail 
    Else 
     Maildb.OPENMAIL 
    End If 

    'Set up the new mail document 
    Set MailDoc = Maildb.CREATEDOCUMENT 
    MailDoc.principal = "noreply@company.com" 
    MailDoc.ReplyTo = "noreply@company.com" 
    'MailDoc.DisplaySent = "noreply@company.com" 
    'MailDoc.iNetFrom = "noreply@company.com" 
    'MailDoc.iNetPrincipal = "noreply@company.com" 
    MailDoc.Form = "Memo" 
    MailDoc.sendto = Recipient 
    MailDoc.Subject = Subject 
    MailDoc.Body = BodyText 
    MailDoc.SAVEMESSAGEONSEND = SaveIt 

    'Set up the embedded object and attachment and attach it 
    If Attachment <> "" Then 
     Set AttachME = MailDoc.CREATERICHTEXTITEM("Attachment") 
     Set EmbedObj = AttachME.EMBEDOBJECT(1454, "", Attachment, "Attachment") 
     MailDoc.CREATERICHTEXTITEM ("Attachment") 
    End If 

    'Send the document 
    MailDoc.PostedDate = Now() 'Gets the mail to appear in the sent items folder 
    MailDoc.SEND 0, Recipient 

    'Clean Up 
    Set Maildb = Nothing 
    Set MailDoc = Nothing 
    Set AttachME = Nothing 
    Set Session = Nothing 
    Set EmbedObj = Nothing 
End Sub 

Answer 1

您無法更改From這種方式。它將始終與原始發件人一起發送。

有兩種方法可以解決這個問題。 第1號爲noreply@company.com創建郵箱，並從該郵箱發送所有郵件，而不是用戶的郵箱。所有的郵件將有一個「發送」標誌的原始發件人。根據mailclient的不同，回覆將在中央郵箱或用戶框中結束。

第2號你直接在服務器mail.box中創建郵件，比你能夠操縱所有的字段。之後，您可以在用戶郵箱中創建與發送郵件所需的所有項目相同的文檔。

Answer 2

在代碼中使用@NotesDomain解決方法。只需更改代碼中的這一行：

MailDoc.Principal = "noreply@company.com@NotesDomain" 

它應該工作。 Domino服務器查找「@NotesDomain」路由郵件，如果Principal字段以該字符串結尾，則From和ReplyTo字段將設置爲「@NotesDomain」之前的字符串。

有關「@NotesDomain」方法的更多信息，請參見here，位於「我如何更改代理生成的郵件的表面發件人？」部分。