如何在彙編語言中輸入字符串？

Question

請問有人知道如何用匯編語言編寫字符串輸入嗎？我正在使用int 21來顯示和輸入字符。

Answer 1

您可以使用function 0Ah讀取緩衝輸入。給定一個字符串緩衝區中ds:dx它讀取的最大長度是255。緩衝器佈局是一個字符串：

Byte 0 String length (0-255) 
Byte 1 Bytes read (0-255, filled by DOS on return) 
Bytes 2-..Length+2 (The character string including newline as read by DOS). 

讀取字符串，然後回聲回給用戶一個小COM文件的一個例子：

org 0x100 

start: 
    push cs 
    pop ds ; COM file, ds = cs 

    mov ah, 0x0A ; Function 0Ah Buffered input 
    mov dx, string_buf ; ds:dx points to string buffer 
    int 0x21 

    movzx si, byte [string_buf+1] ; get number of chars read 

    mov dx, string_buf + 2 ; start of actual string 

    add si, dx ; si points to string + number of chars read 
    mov byte [si], '$' ; Terminate string 

    mov ah, 0x09 ; Function 09h Print character string 
    int 0x21 ; ds:dx points to string 

    ; Exit 
    mov ax, 0x4c00 
    int 0x21 

string_buf: 
    db 255 ; size of buffer in characters 
    db 0 ; filled by DOS with actual size 
    times 255 db 0 ; actual string 

注意，這將覆蓋輸入線（它可能因此不看程序做任何事情！）

或者您可以使用function 01h和自己在一個循環中讀取的字符。像這樣的東西（注意如果超過255個字符被輸入，它將溢出後面的緩衝區）：

org 0x100 

start: 
    push cs 
    pop ax 
    mov ds, ax 
    mov es, ax; make sure ds = es = cs 

    mov di, string ; es:di points to string 
    cld ; clear direction flag (so stosb incremements rather than decrements) 
read_loop: 
    mov ah, 0x01 ; Function 01h Read character from stdin with echo 
    int 0x21 
    cmp al, 0x0D ; character is carriage return? 
    je read_done ; yes? exit the loop 
    stosb ; store the character at es:di and increment di 
    jmp read_loop ; loop again 
read_done: 
    mov al, '$' 
    stosb ; 'Make sure the string is '$' terminated 

    mov dx, string ; ds:dx points to string 
    mov ah, 0x09 ; Function 09h Print character string 
    int 0x21 

    ; Exit 
    mov ax, 0x4c00 
    int 0x21 

string: 
    times 255 db 0 ; reserve room for 255 characters 

Answer 2

字符串只是一系列字符，因此您可以在循環內部使用int 21代碼來獲取一個字符串，一次一個字符。在數據段中創建一個標籤以保存字符串，並且每次讀取字符時，都將其複製到該標籤（每次增加一個偏移量，以便順序存儲字符）。當某個字符被讀取時停止循環（也許輸入）。

手動執行所有這些操作非常繁瑣（想想backspace是如何工作的），但是你可以做到。或者，您可以鏈接到stdio，stdlib等，並調用庫函數爲您完成大部分工作。