播放位於隨機文件夾/子文件夾中的第一個視頻

Question

我想製作一個.bat文件，該文件將在與.bat文件相同的位置打開隨機文件夾/子文件夾內的第一個文件。

我目前只有打開一個隨機文件的代碼。

@echo off 
setlocal enableextensions disabledelayedexpansion 

set "rootFolder=G:\Movies\Anime" 

for /f "usebackq tokens=1,* delims=:" %%a in (` 
    cmd /q /v /e /c "for /f delims^= %%a in ('dir /a-d /s /b "%rootFolder%"') do echo(!random!:%%a" 
    ^| sort 2^>nul 
    ^| cmd /q /e /v /c "set /p ".^=" & echo(!.!" 
`) do start "" "%%~b" 

我也有一個.bat文件生成與同一位置的所有文件夾列表的文本文件。我不確定是否可以更容易地引用它。

dir /b > Animelist.txt 

而且如果可能的話如何排除它打開特定類型的文件，如JPEG /其他.bat文件？

Answer 1

你可以用這個

@echo off 
    setlocal enableextensions disabledelayedexpansion 

    set "rootFolder=%cd%" 
    set fileTypes= "*.avi" "*.mpeg" "*.mkv" 

    pushd "%rootFolder%" && (
     for /f "usebackq tokens=1,* delims=:" %%a in (` 
      cmd /q /v /e /c "set p=&for /r %%a in (%fileTypes%) do if not !f!==%%~dpa (set f=%%~dpa&set /a ((%random% %% 16273^)+1^)*!random!&echo :%%~dpa)" 
      ^| sort 2^>nul 
      ^| cmd /q /e /v /c "set /p ".^=" && echo(!.!" 
     `) do pushd "%%~b." && (
      for /f "delims=" %%c in (' 
       dir /b /a-d /on %fileTypes% 2^>nul 
       ^| cmd /q /e /v /c "set /p ".^=" && echo(!.!" 
      ') do start "" "%%~fc" 
      popd 
     ) 
     popd 
    ) 

嘗試在片將任務分解

• 配置到哪裏去尋找什麼搜索（前兩個set）
• 變化到起始文件夾（pushd）
  • 執行鍼對所指示的文件類型和輸出，其中該文件已被找到的文件夾的名稱（第一cmd遞歸搜索內部for /f
    • 作爲除以上一個文件可以在同一個文件夾中，檢查，我們將不輸出一個重複元件（if第一cmd內部）
  • 對於每個文件夾，生成芳andom號作爲前綴（set /a）和輸出文件夾（echo）
  • 排序隨機數列表（sort）
  • 獲取列表中的第一個文件夾。由於名單上的隨機數進行排序，此文件夾已隨機選擇（第二cmd內for /f %%a）
  • 丟棄的隨機數，只檢索的文件夾（在for /f %%a爲delims和tokens的原因）
• 更改所選文件夾（pushd）
  • 列表指示類型選擇的文件夾內的文件（dir）
  • 從這個列表中選擇上LY第一文件（cmd）
  • 檢索所選擇的文件（for /f %%c）
  • 開始選定的文件（start）
  • 返回（前一個文件夾（popd）
• 返回到起始夾popd ）

Answer 2

隨機選擇一個文件夾是明確的。
first video file有點困難。如果使用帶有多個擴展名（如@aschipfl）的dir，則會預先確定要查找哪些擴展名並找到它們。
排除文件類型的另一種方法比較乏味，不知道可能會出現哪些類型。

這裏我的批處理編輯簡化的某些部分：

@echo off 
setlocal enableextensions Enabledelayedexpansion 
Set Cnt=0 
Set "Exclude=.bat$ .cmd$ .jpg$ .jpeg$ .txt$" 

Pushd "G:\Movies\Anime" 
(Echo::: Numbered List of folders 
    For /f "delims=" %%F in (
    'Dir /B/S/AD/ON' 
) Do Set /A Cnt+=1&Echo:!Cnt!:%%F 
)>DirList.txt 

:: Get Random num 1..Cnt 
Set /A RndDir=%Random% %% Cnt+1 

:: Get random folder name 
For /f "tokens=1,* Delims=:" %%F in (
    'Findstr "^%RndDir%:" DirList.txt ' 
) Do Set "DirName=%%G" 
Echo selected %RndDir% of %Cnt% = folder %DirName% 
Pushd "%DirName% 

Set "FileName" 
For /f "Delims=" %%F in (
    'Dir /B/A-D ^|findstr /i /V "%Exclude%"' 
) Do If Not defined FileName Set "FileName=%%~F" 
If defined FileName Start "" "%FileName%" 
Popd 
Popd 
Goto :Eof