Writeln能夠支持Unicode嗎？

Question

考慮這個程序：

{$APPTYPE CONSOLE} 

begin 
    Writeln('АБВГДЕЖЅZЗИІКЛМНОПҀРСТȢѸФХѾЦЧШЩЪЫЬѢѤЮѦѪѨѬѠѺѮѰѲѴ'); 
end. 

它採用索拉字體我的控制檯上的輸出是：

 
????????Z?????????????????????????????????????? 

Windows控制檯是相當能夠支持Unicode的該程序證明：

{$APPTYPE CONSOLE} 

uses 
    Winapi.Windows; 

const 
    Text = 'АБВГДЕЖЅZЗИІКЛМНОПҀРСТȢѸФХѾЦЧШЩЪЫЬѢѤЮѦѪѨѬѠѺѮѰѲѴ'; 

var 
    NumWritten: DWORD; 

begin 
    WriteConsole(GetStdHandle(STD_OUTPUT_HANDLE), PChar(Text), Length(Text), NumWritten, nil); 
end. 

其中輸出爲：

 
АБВГДЕЖЅZЗИІКЛМНОПҀРСТȢѸФХѾЦЧШЩЪЫЬѢѤЮѦѪѨѬѠѺѮѰѲѴ 

可以說服Writeln尊重Unicode嗎？還是它本身就是殘廢？

Answer 1

只需通過SetConsoleOutputCP()程序設置控制檯輸出代碼頁，代碼頁cp_UTF8即可。

program Project1; 

{$APPTYPE CONSOLE} 

uses 
    System.SysUtils,Windows; 
Const 
    Text = 'АБВГДЕЖЅZЗИІКЛМНОПҀРСТȢѸФХѾЦЧШЩЪЫЬѢѤЮѦѪѨѬѠѺѮѰѲѴ'; 
VAR 
    NumWritten: DWORD; 
begin 
    ReadLn; // Make sure Consolas font is selected 
    try 
    WriteConsole(GetStdHandle(STD_OUTPUT_HANDLE), PChar(Text), Length(Text), NumWritten, nil);  
    SetConsoleOutputCP(CP_UTF8); 
    WriteLn; 
    WriteLn('АБВГДЕЖЅZЗИІКЛМНОПҀРСТȢѸФХѾЦЧШЩЪЫЬѢѤЮѦѪѨѬѠѺѮѰѲѴ'); 
    except 
    on E: Exception do 
     Writeln(E.ClassName, ': ', E.Message); 
    end; 
    ReadLn; 
end. 

輸出：

АБВГДЕЖЅZЗИІКЛМНОПҀРСТȢѸФХѾЦЧШЩЪЫЬѢѤЮѦѪѨѬѠѺѮѰѲѴ 
АБВГДЕЖЅZЗИІКЛМНОПҀРСТȢѸФХѾЦЧШЩЪЫЬѢѤЮѦѪѨѬѠѺѮѰѲѴ 

WriteLn()平移的Unicode UTF16字符串到所選擇的輸出代碼頁（CP_UTF8）內部。

---

更新：

在德爾福XE2以上上述作品。 在Delphi-XE中，您需要明確轉換爲UTF-8才能正常工作。

WriteLn(UTF8String('АБВГДЕЖЅZЗИІКЛМНОПҀРСТȢѸФХѾЦЧШЩЪЫЬѢѤЮѦѪѨѬѠѺѮѰѲѴ')); 

---

附錄：

如果輸出到控制檯在另一個代碼頁調用SetConsoleOutputCP(cp_UTF8)， 操作系統中utf-8將無法​​正確輸出文本之前完成。 這可以通過關閉/重新打開stdout處理程序來解決。

另一種選擇是爲utf-8聲明新的文本輸出處理程序。

var 
    toutUTF8: TextFile; 
... 
SetConsoleOutputCP(CP_UTF8); 
AssignFile(toutUTF8,'',cp_UTF8); // Works in XE2 and above 
Rewrite(toutUTF8); 
WriteLn(toutUTF8,'АБВГДЕЖЅZЗИІКЛМНОПҀРСТȢѸФХѾЦЧШЩЪЫЬѢѤЮѦѪѨѬѠѺѮѰѲѴ'); 

Answer 2

WriteConsoleW似乎是一個非常神奇的功能。

procedure WriteLnToConsoleUsingWriteFile(CP: Cardinal; AEncoding: TEncoding; const S: string); 
var 
    Buffer: TBytes; 
    NumWritten: Cardinal; 
begin 
    Buffer := AEncoding.GetBytes(S); 
    // This is a side effect and should be avoided ... 
    SetConsoleOutputCP(CP); 
    WriteFile(GetStdHandle(STD_OUTPUT_HANDLE), Buffer[0], Length(Buffer), NumWritten, nil); 
    WriteLn; 
end; 

procedure WriteLnToConsoleUsingWriteConsole(const S: string); 
var 
    NumWritten: Cardinal; 
begin 
    WriteConsole(GetStdHandle(STD_OUTPUT_HANDLE), PChar(S), Length(S), NumWritten, nil); 
    WriteLn; 
end; 

const 
    Text = 'АБВГДЕЖЅZЗИІКЛМНОПҀРСТȢѸФХѾЦЧШЩЪЫЬѢѤЮѦѪѨѬѠѺѮѰѲѴ'; 
begin 
    ReadLn; // Make sure Consolas font is selected 
    // Works, but changing the console CP is neccessary 
    WriteLnToConsoleUsingWriteFile(CP_UTF8, TEncoding.UTF8, Text); 
    // Doesn't work 
    WriteLnToConsoleUsingWriteFile(1200, TEncoding.Unicode, Text); 
    // This does and doesn't need the CP anymore 
    WriteLnToConsoleUsingWriteConsole(Text); 
    ReadLn; 
end. 

因此，在總結：

WriteConsoleW(GetStdHandle(STD_OUTPUT_HANDLE), ...)支持UTF-16。

WriteFile(GetStdHandle(STD_OUTPUT_HANDLE), ...)不支持UTF-16。

我的猜測是，爲了支持不同的ANSI編碼，經典的Pascal I/O使用WriteFile調用。

而且要記住，在文件，而不是控制檯使用時必須工作，以及：

unicode text file output differs between XE2 and Delphi 2009?

這意味着，盲目使用WriteConsole中斷輸出重定向。如果您使用WriteConsole你應該回落到WriteFile這樣的：

var 
    NumWritten: Cardinal; 
    Bytes: TBytes; 
begin 
    if not WriteConsole(GetStdHandle(STD_OUTPUT_HANDLE), PChar(S), Length(S), 
    NumWritten, nil) then 
    begin 
    Bytes := TEncoding.UTF8.GetBytes(S); 
    WriteFile(GetStdHandle(STD_OUTPUT_HANDLE), Bytes[0], Length(Bytes), 
     NumWritten, nil); 
    end; 
    WriteLn; 
end; 

注意與任何編碼，它輸出重定向在cmd.exe工作正常。它只是將輸出流寫入文件不變。

但是，PowerShell希望在輸出開始時包含ANSI輸出或正確的前導碼（/ BOM）到（或文件將被編碼！）。另外，PowerShell將始終使用前導碼將輸出轉換爲UTF-16。

使用GetConsoleMode，以找出是否標準手柄是一個控制檯手柄MSDN recommends，也BOM中提到：如果它是一個標準的句柄是 重定向到一個文件中使用

WriteConsole失敗。如果應用程序處理可重定向的多語言輸出 ，請確定輸出句柄是否爲 控制檯句柄（一種方法是調用GetConsoleMode函數， 檢查它是否成功）。如果手柄是控制檯手柄，請致電 WriteConsole。如果句柄不是控制檯句柄，則重定向輸出爲 ，您應該調用WriteFile來執行I/O。請確保以 爲Unicode純文本文件加上字節順序標記。有關更多 信息，請參閱使用字節順序標記。

Answer 3

的System單元聲明瞭一個名爲AlternateWriteUnicodeStringProc變量，允許的如何執行Writeln輸出定製。這個程序：

{$APPTYPE CONSOLE} 

uses 
    Winapi.Windows; 

function MyAlternateWriteUnicodeStringProc(var t: TTextRec; s: UnicodeString): Pointer; 
var 
    NumberOfCharsWritten, NumOfBytesWritten: DWORD; 
begin 
    Result := @t; 
    if t.Handle = GetStdHandle(STD_OUTPUT_HANDLE) then 
    WriteConsole(t.Handle, Pointer(s), Length(s), NumberOfCharsWritten, nil) 
    else 
    WriteFile(t.Handle, Pointer(s)^, Length(s)*SizeOf(WideChar), NumOfBytesWritten, nil); 
end; 

var 
    UserFile: Text; 

begin 
    AlternateWriteUnicodeStringProc := MyAlternateWriteUnicodeStringProc; 
    Writeln('АБВГДЕЖЅZЗИІКЛМНОПҀРСТȢѸФХѾЦЧШЩЪЫЬѢѤЮѦѪѨѬѠѺѮѰѲѴ'); 
    Readln; 
end. 

產生這樣的輸出：

 
АБВГДЕЖЅZЗИІКЛМНОПҀРСТȢѸФХѾЦЧШЩЪЫЬѢѤЮѦѪѨѬѠѺѮѰѲѴ 

我懷疑我是如何實現的MyAlternateWriteUnicodeStringProc以及如何將經典帕斯卡爾I/O交互。但是，它看起來像輸出到控制檯所期望的那樣。

的AlternateWriteUnicodeStringProc文檔目前說，等待它，...

Embarcadero Technologies公司目前還沒有任何其他信息。請使用討論頁面幫助我們記錄此主題！