Excel VBA - 始終顯示打開的工作表

Question

如何滿足VBA代碼的以下條件？

1. 特定的工作表始終顯示在打開狀態，即使在未啓用宏的情況下打開了worbook。
2. 工作簿用戶可以在任何工作表上工作時保存工作簿。
3. 的保存必須不干擾用戶 - 沒有遠離導航到不同的片材，沒有消息框等
4. 常規保存功能（Ctrl鍵 - 小號，點擊保存）在使用時必須保持可用和必須遵守上述標準。

我想避免我在此問題底部列出的嘗試解決方案。

詳情：
工作簿使用Office 2007在Windows 7機器上創建的。這是一個包含2個工作表，「計劃程序」和「信息」的.xlsm工作簿。工作表標籤不可見。並非所有用戶都將在打開工作簿時啓用宏。

• 「信息」顯示，如果宏被禁用了，基本上會告訴你誰打開一個宏需要是工作簿的人：

  在打開的工作簿，用戶將只如下暴露於一種表啓用完整的工作簿功能。如果此時啓用了宏，則會啓動「調度程序」。

• 「調度程序」是存儲和編輯數據的地方，如果啓用了宏，它將自動顯示。在未啓用宏的情況下打開工作簿時，不會顯示給用戶。

如果工作簿打開且宏被禁用，則「Info」必須首先顯示。

嘗試的解決方案（我在尋找更好的解決方案！）：

• 在Workbook.BeforeSave事件配售代碼。這會在激活「信息」時進行保存，以便在工作簿打開時顯示。但是，如果用戶處於「調度程序」而未完成，我無法在保存後在此事件中找到重新激活「調度程序」的方法。
• 使用Application.OnKey重新映射按Ctrl - 小號和按Ctrl - 小號按鍵。不幸的是，這留下了使用鼠標進行保存的用戶（單擊文件...保存或辦公按鈕...保存）。
• 檢查每個操作過程中是否需要激活「調度程序」。換句話說，將代碼插入Workbook.SheetActivate或.SheetChange事件中，以便在激活「信息」後進行保存後，將「調度程序」重新置於焦點。這會不斷運行VBA代碼，並將其作爲讓工作簿中的其他代碼陷入困境的好方法。
• 在Worksheet("Info").Activate事件配售代碼，將焦點更改回「調度」。這導致「調度程序」而不是「信息」的結果顯示工作簿何時打開，即使禁用了宏。

Answer 1

我沒有時間來測試這一點，但你可能能夠在您的BeforeSave事件處理程序來做到這一點使用Application.OnTime。喜歡的東西：

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean) 
    Dim objActiveSheet 
    Set objActiveSheet = Me.ActiveSheet 
    If objActiveSheet Is InfoSheet Then Exit Sub 
    If Module1.PreviousSheet Is Nothing Then 
     Set Module1.PreviousSheet = objActiveSheet 
     InfoSheet.Activate 
     Application.OnTime Now, "ActivatePreviousSheet" 
    End If 
End Sub 

然後在模塊1：

Public PreviousSheet As Worksheet 

Public Sub ActivatePreviousSheet() 
    If Not PreviousSheet Is Nothing Then 
     PreviousSheet.Activate 
     Set PreviousSheet = Nothing 
    End If 
End Sub 

Answer 2

這是否會無法工作？ 更新處理節能優雅

Private Sub Workbook_Open() 
    ThisWorkbook.Worksheets("Scheduler").Activate 
End Sub 

Private Sub Workbook_BeforeClose(Cancel As Boolean) 
    ThisWorkbook.Worksheets("Info").Activate 
    If (ShouldSaveBeforeClose()) Then 
     Me.Save 
    Else 
     Me.Saved = True ' Prevents Excel Save prompt. 
    End If 
End Sub 

Private Function ShouldSaveBeforeClose() As Boolean 
    Dim workbookDirty As Boolean 
    workbookDirty = (Not Me.Saved) 
    If (Not workbookDirty) Then 
     ShouldSaveBeforeClose= False 
     Exit Function 
    End If 

    Dim response As Integer 
    response = MsgBox("Save changes to WorkBook?", vbYesNo, "Attention") 
    ShouldSaveBeforeClose= (response = VbMsgBoxResult.vbYes) 
End Function 

Answer 3

編輯2：這是一個重新寫了不使用AfterSave。您可能需要根據您的需要調整從GetSaveAsFilename創建的對話框。

這依賴於覆蓋默認保存行爲並處理自己保存。

Private actSheet As Worksheet 
Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean) 
    Cancel = True 
    PrepareForSave 
    manualSave SaveAsUI 
    AfterSave ThisWorkbook.Saved 
End Sub 
Private Sub PrepareForSave() 
    Set actSheet = ThisWorkbook.ActiveSheet 
    ThisWorkbook.Sheets("Info").Activate 
    hidesheets 
End Sub 
Private Sub manualSave(ByVal SaveAsUI As Boolean) 
    On Error GoTo SaveError 'To catch failed save as 
    Application.EnableEvents = False 
    If SaveAsUI Then 
     If Val(Application.Version) >= 12 Then 
      sPathname = Application.GetSaveAsFilename(FileFilter:="Excel Files (*.xlsm), *.xlsm") 
      If sPathname = False Then 'User hit Cancel 
       GoTo CleanUp 
      End If 
      ThisWorkbook.SaveAs Filename:=sPathname, FileFormat:=52 
     Else 
      sPathname = Application.GetSaveAsFilename(FileFilter:="Excel Files (*.xls), *.xls") 
      If sPathname = False Then 
       GoTo CleanUp 
      End If 
      ThisWorkbook.SaveAs Filename:=sPathname, FileFormat:=xlNormal 
     End If 
    Else 
     ThisWorkbook.Save 
    End If 
SaveError: 
    If Err.Number = 1004 Then 
     'Cannot access save location 
     'User clicked no to overwrite 
     'Or hit cancel 
    End If 
CleanUp: 
    Application.EnableEvents = True 
End Sub 

Private Sub AfterSave(ByVal bSaved As Boolean) 
    showsheets 
    If actSheet Is Nothing Then 
     ThisWorkbook.Sheets("Scheduler").Activate 
    Else 
     actSheet.Activate 
     Set actSheet = Nothing 
    End If 
    If bSaved Then 
     ThisWorkbook.Saved = True 
    End If 
End Sub 
Private Sub hidesheets() 
    For Each ws In ThisWorkbook.Worksheets 
     If ws.Name <> "Info" Then 
      ws.Visible = xlVeryHidden 
     End If 
    Next 
End Sub 
Private Sub showsheets() 
    For Each ws In ThisWorkbook.Worksheets 
     ws.Visible = True 
    Next 
End Sub 
Private Sub Workbook_Open() 
    AfterSave True 
End Sub 

使Info顯示第一個未啓用宏的唯一方法是如果是這樣的工作簿是如何保存的。這是保存時最合理的處理方式。

除非我誤解你的問題，而不是使用BeforeSave似乎誤入歧途。請確保使用AfterSave。下面是一個示例：

Private actSheet As Worksheet 
Private Sub Workbook_AfterSave(ByVal Success As Boolean) 
    showsheets 
    actSheet.Activate 
    Set actSheet = Nothing 
    Thisworkbook.Saved = true 'To prevent save prompt from appearing 
End Sub 

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean) 
    Set actSheet = ThisWorkbook.activeSheet 
    ThisWorkbook.Sheets("Info").Activate 
    hidesheets 
End Sub 

Private Sub Workbook_Open() 
    showsheets 
    ThisWorkbook.Sheets("Scheduler").Activate 
End Sub 
Private Sub hidesheets() 
    For Each ws In ThisWorkbook.Worksheets 
     If ws.Name <> "Info" Then 
      ws.Visible = xlVeryHidden 
     End If 
    Next 
End Sub 
Private Sub showsheets() 
    For Each ws In ThisWorkbook.Worksheets 
     ws.Visible = True 
    Next 
End Sub 

使用私人對象actSheet允許在保存後重新選擇「ActiveSheet」。

編輯：我注意到你在評論中有更多的要求。代碼已經更新，現在保存後，只有信息表可見，但是在打開或保存後，每個表格都會重新出現。

這使得以使任何用戶打開該文件，而無需宏將不能與活化的不同片保存，甚至查看其他片材。這肯定會有助於激勵他們啓用宏！

Answer 4

此問題已被鞭打死過去，它只是很難找到實際工作的解決方案。看看這個代碼應該做你需要的。基本上它會顯示一個啓動畫面，如果用戶不啓用宏，則隱藏所有其他工作表。如果用戶點擊保存並且不會干擾他們的工作，它仍然可以正常保存。如果他們在工作表打開的情況下保存，它將在下次打開時仍然只顯示啓動畫面。下載下面的示例文件，你可以自己測試，確保你下載Reafidy發佈的文件有超過400個視圖。如果您需要進一步修改，請告訴我。

Private Sub Workbook_BeforeClose(Cancel As Boolean) 
    bIsClosing = True 
End Sub 
Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean) 
    Dim wsArray() As Variant 
    Dim iCnt As Integer 
    Application.ScreenUpdating = 0 

    Splash.Visible = True 

    For Each wsSht In ThisWorkbook.Worksheets 
     If Not wsSht.CodeName = "Splash" Then 
      If wsSht.Visible = True Then 
       iCnt = iCnt + 1: Redim Preserve wsArray(1 To iCnt) 
       wsArray(iCnt) = wsSht.Name 
      End If 
      wsSht.Visible = xlSheetVeryHidden 
     End If 
    Next 

    Application.EnableEvents = 0 
    ThisWorkbook.Save 
    Application.EnableEvents = 1 

    If Not bIsClosing Then 
     For iCnt = 1 To UBound(wsArray) 
      Worksheets(wsArray(iCnt)).Visible = True 
     Next iCnt 
     Splash.Visible = False 
     Cancel = True 
    End If 

    Application.ScreenUpdating = 1 
End Sub 
Private Sub Workbook_Open() 
    Dim wsSht As Worksheet 

    For Each wsSht In ThisWorkbook.Worksheets 
     wsSht.Visible = xlSheetVisible 
    Next wsSht 

    Splash.Visible = xlSheetVeryHidden 

    bIsClosing = False 
End Sub 

的樣本文件可以發現here.

Answer 5

如何使用 '代理工作簿'。

的「代理工作簿」

• 是直接由用戶
• 打開的唯一工作簿包含的信息表
• 包含VBA打開你的「真正的工作簿」使用Workbooks.Open（正如我在默認情況下Workbooks.Open文檔檢查是否需要VBA代碼甚至可以確保它不會在文件名添加到您最近的文件歷史記錄，除非你設置AddToMru參數爲true）
• 你的「目標工作簿'是值得信賴的（我找到了一些樣本代碼here）

「目標工作簿」

• 包含您的日程和任何其他表
• 如果在「代理服務器工作簿」 VBA代碼被執行
• 可以保存只能打開由用戶在任何時候像往常一樣

我沒有Office 2007手頭測試這個，但認爲它應該這樣做。