的ActionScript 3 - 解析XML值

Question

我有下面的XML：

<document> 
    <homeitems> 
     <homeitem> 
      <itemURL>URL1.html</itemURL> 
     </homeitem> 
     <homeitem> 
      <itemURL>URL2.html</itemURL> 
     </homeitem> 
     <homeitem> 
      <itemURL>URL3.html</itemURL> 
      <itemImage>image3.jpg</itemImage> 
     </homeitem> 
    </homeitems> 
</document> 

而下面的代碼，將其解析：

var XMLData:XML = new XML(LoaderMax.getContent("xmlDoc")); // loads XML 
var numitems = XMLData.homeitems.homeitem.length(); 

for (var i=0;i<numitems;i++) { 
    if ((XMLData.homeitems.homeitem[i].itemImage) && (XMLData.homeitems.homeitem[i].itemImage!=="")) { 
     trace("Loading image "+XMLData.homeitems.homeitem[i].itemImage); 
    } 
} 

跟蹤結果：

Loading image 
Loading image 
Loading image image3.jpg 

WHY？ ？！？它不應該跳過沒有圖像的項目嗎？我是愚蠢的嗎？

Answer 1

你可以看到你的測試if (XMLData.homeitems.homeitem[i].itemImage)計算爲true（只是做一個trace(Boolean(XMLData.homeitems.homeitem[i].itemImage)你會看到真正的）這是不夠的。

也不要比作String節點使用節點的toString方法或明確地將它轉換爲String（即String(XMLData.homeitems.homeitem[i].itemImage)!=""或XMLData.homeitems.homeitem[i].itemImage.toString()!=""）

有多種方式待辦事項它：

---

您可以測試該節點是不確定的：

if (XMLData.homeitems.homeitem[i].itemImage != undefined) 

---

使用hasOwnProperty方法：

if (XMLData.homeitems.homeitem[i].hasOwnProperty('itemImage')) 

---

而且你還可以投你itemImage爲String，看看它是否是!= ""：

if (String(XMLData.homeitems.homeitem[i].itemImage) != "") 

---

使用E4X和foreach你可以有您的循環清潔代碼：

for each(var homeItem:XML in XMLData.homeitems.homeitem) { 
    var itemImage:String = String(homeItem.itemImage) 
    if (itemImage!="") { 
     trace("Loading image "+itemImage); 
    } 
} 

Answer 2

，如果你有!=比較不!==

if ((XMLData.homeitems.homeitem[i].itemImage) && (XMLData.homeitems.homeitem[i].itemImage!="")) { 
    /* do somethong here */ 
}