範圍鏈接到最後一個單元格在相鄰的列

Question

我有一個工作表，有4列，我寫了一個宏來將公式放在A + B列中，這些列依賴於D列中的內容，然後將其作爲值複製並粘貼到啓用這些列的過濾。我的問題是，每週的列D變得更長。我不希望要不斷改變我的宏的值A + B（A2：A69422）的範圍，其中69422是列在最後使用的細胞D.

Worksheets("salesinfo").Range("B2").Formula = "= MID(D3,3,5)" 
    Range("B2").Select 
     Selection.AutoFill Destination:=Range("B2:B69422") 
     Range("B2:B69422").Select 
     Selection.Copy 
     Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _ 
      :=False, Transpose:=False 

    Selection.Value = Selection.Value 

    Range("A2").Formula = "= VLOOKUP(B2,[Data.xlsb]Stores!$A:$X,4,0)" 

    Range("A2").Select 
     Selection.AutoFill Destination:=Range("A2:A69422") 
     Range("A2:A69422").Select 
     Selection.Copy 
     Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _ 
      :=False, Transpose:=False 

      Workbooks("Data.xlsb").Close SaveChanges:=False 

      Application.CutCopyMode = False 

      Range("A2").Select 

Answer 1

使用以下語法確定列D中的最後一行，然後將其分配給變量Long或Integer變量。在我的例子我使用lRow作爲我的變量：

Dim lRow As Long 

With ActiveSheet 

    lRow = .Cells(.Rows.Count, 4).End(xlUp).Row 

End With 

然後，只需在單元格地址的行引用使用lRow + 1。

Answer 2

如TheGuyThatDoesn'tKnowMuch所述，聲明一個Long類型變量並存儲模式相關列的最後一個已填充行最好通過從下往上查看來完成。這相當於從工作表底部開始並點擊Ctrl + ▲。

以下是一些可以改進代碼的其他方法。

• 定義你Workbook Object和Worksheet Object與With ... End With statement，並通過與.像.Range(...)前綴每個Range object使用該引用。請勿將.Parent工作表引用隱含;總是讓他們明確。
• 一次寫下所有的公式;無需使用Range.AutoFill method。
• 直接值轉移比複製&選擇性粘貼特殊值更有效，並且不涉及剪貼板。
• 避免使用Range.Select和Range.Activate方法¹。他們可能是開始使用VBA的好方法，但他們也是您應該畢業的第一件事。
  

引用列A：外部工作簿中的X在VLOOKUP function內，當您只需要A：D時效率低下;在任何情況下，一個INDEX/MATCH函數對可能對於大量的行更好。

您正在向列A中寫入一個引用外部工作簿Data.xlsb的公式，因此我知道這不是包含salesinfo工作表的工作表。您應該調整下面的工作簿參考以避免使用ActiveWorkbook property。

Dim lr As Long 

    With ActiveWorkbook 
     With .Worksheets("salesinfo") 
      lr = .Cells(.Rows.Count, "D").End(xlUp).Row 
      With .Range("B2:B" & lr) 
       .Formula = "=MID(D3, 3, 5)" 
       .Value = .Value 
      End With 
      With .Range("A2:A" & lr) 
       .Formula = "=VLOOKUP(B2, [Data.xlsb]Stores!$A:$X, 4, FALSE)" 
       'alternate formula 
       '.Formula = "=INDEX([Data.xlsb]Stores!$D:$D, MATCH(B2, [Data.xlsb]Stores!$A:$A, 0))" 
       .Value = .Value 
      End With 
      .Range("A2").Activate 
     End With 
    End With 

    Workbooks("Data.xlsb").Close SaveChanges:=False 

針對列B的公式涉及到我一點。您正在使用B2中的公式引用D3。這意味着如果公式在列B中填充以匹配列D中的所有值，則最後公式實際上將引用列D中最後一個填充單元格下方的空白單元格。

如果遇到計算滯後問題（花費太長時間）將兩列公式寫入近70K行，字典對象和變體數組可能會非常明顯地加快速度。

---

.¹_{見How to avoid using Select in Excel VBA macros更多的方法從依靠選擇越來越遠，並激活，以實現自己的目標。}