如何在動作腳本中將HEX轉換爲ASCII碼

Question

例如，ActionScript中是否存在可將0x4e544c4d轉換爲ASCII字符串「NTLM」的任何方法？

Answer 1

你可以嘗試這樣的：

function HexToASCII(s:String):String { 
    var hexChar:String; 
    var finalString:String = ""; 
    for (var i = 0; i < s.length/2; i++) { 
     hexChar = s.charAt(i*2).toString()+s.charAt((i*2)+1).toString(); 
     hexChar = "0x"+hexChar; 
     finalString = finalString+String.fromCharCode(parseInt(hexChar)); 
    } 
    return finalString; 
} 

Answer 2

我發現了 「原生方式」 才達到你的要求爲：

import flash.utils.ByteArray; 

var hex:String = '0x4e544c4d'; 
var hexNum:int = parseInt(hex); 
var bytes:ByteArray = new ByteArray(); 
bytes.writeInt(hexNum); 
trace(bytes.toString()); //prints NTLM 

：方法 writeInt/ writeByte和 flash.utils.ByteArray toString組合

當然你需要注意最大值parseInt返回（Number只能包含53位），以及在寫入ByteArray時如何匹配。我做了一個小函數來處理更長的十六進制字符串：

import flash.utils.ByteArray; 

var hex:String = '0x4e544c4d204e544c4d204e544c4d'; 
trace(hexToAscii(hex));//NTLM NTLM NTLM 

function hexToAscii(hex:String):String { 
    if (hex.indexOf('0x') === 0){ 
     hex = hex.substr(2); 
    } 
    var bytes:ByteArray = new ByteArray(); 
    while (hex.length > 1){ 
     bytes.writeByte(parseInt(hex.substr(0,2), 16)); 
     hex = hex.substr(2); 
    } 
    return bytes.toString(); 
} 

你可以用它玩：http://wonderfl.net/c/IUn2