不能使用未定義的值作爲子程序引用

Question

作爲練習，我試圖實現一個堆棧來計算後綴表達式。

use strict; 
use warnings; 

use Scalar::Util qw(looks_like_number); 

my %operators = (
    '+' => \&sum, 
    '-' => \&subs, 
    '*' => \&mul, 
    '/' => \&div, 
); 

print 'Enter an expression to evaluate : '; 
chomp($_ = <STDIN>); 
my @lettres=split(//); 

my @stack; 

for(my $i = 0; $i < @lettres; $i++){ 
    if(looks_like_number($lettres[$i])){ 
     unshift @stack, $lettres[$i]; 
    } else { 
     my $nb1 = shift @stack; 
     my $nb2 = shift @stack; 
     unshift @stack, $operators{$lettres[$i]}->($nb1,$nb2); 
    } 
} 

print 'Answer : ' .shift @stack; 

sub sum { return $_[0] + $_[1];} 
sub mul { return $_[0] * $_[1];} 
sub subs { return $_[0] - $_[1];} 
sub div { return $_[0]/$_[1];} 

當運行它，我得到：

Can't use an undefined value as a subroutine reference at polonaise.pl line 25, 
<STDIN> line 1. 

第25行是：

unshift @stack, $operators{$lettres[$i]}->($nb1,$nb2); 

我懷疑$operators{$lettres[$i]}->($nb1,$nb2);是造成問題，但我不知道爲什麼，因爲我開始與Perl。

爲什麼會發生這種情況，我該如何解決這個問題？

Answer 1

首先，只考慮非空格字符的有效令牌序列。其次，如果令牌看起來不像數字，請確保%operators散列中的句柄exists。我發現push和pop在處理堆棧時更自然，但這並不重要;

#!/usr/bin/env perl 

use strict; 
use warnings; 

# Turn on autoflush 
local $| = 1; 

use Scalar::Util qw(looks_like_number); 

my %operators = (
    '+' => \&add, 
    '-' => \&subtract, 
    '*' => \&multiply, 
    '/' => \&divide, 
); 

print 'Enter an expression to evaluate : '; 

my $input = <STDIN>; 

my @tokens = split ' ', $input; 

my @stack; 

for my $token (@tokens) { 
    if (looks_like_number($token)) { 
     push @stack, $token; 
    } 
    else { 
     if (exists $operators{$token}) { 
      my $op = $operators{$token}; 
      my $x = pop @stack; 
      my $y = pop @stack; 
      push @stack, $op->($x, $y); 
     } 
     else { 
      warn "Unknown token '$token'\n"; 
     } 
    } 
} 

print "Answer: $stack[-1]\n"; 

sub add  { $_[0] + $_[1];} 
sub multiply { $_[0] * $_[1];} 
sub subtract { $_[0] - $_[1];} 
sub divide { $_[0]/$_[1];}