如何在自定義任務中定義默認dependsOn

Question

我對gradle比較陌生。 爲了在集羣上創建自動部署腳本，我創建了一組相互依賴的自定義任務。例如：

class StartSchedulerTask extends SchedulerTask { 
    @TaskAction 
    void start() { 
     dependsOn env.nodes.name.collect {"startTomcat_$it"} 
     println "Starting quartz on node: ${node}" 
    } 
} 

中的build.gradle，我是動態創建的任務：

project.extensions.environment.nodes.each { TomcatNode n -> 
    String name = n.name 
    task "nodeInit_$name"(type: DeployToNodeInitTask) { 
       node(n) 
    } 
    task "stopWorker_$name"(type: StopWorkerTask) { 
     node(n) 
    } 
    task "stopTomcat_$name"(type: StopTomcatTask){ 
     node(n) 
    } 
    task "updateAppConfigs_$name"(type: UpdateAppConfigsTask){ 
     node(n) 
     apps(V3Application.ALL_APPS) 
     buildName('develop') 
    } 
    task "deployWars_$name"(type: DeployWarsTask){ 
     node(n) 
     apps(V3Application.ALL_APPS) 
     buildName('develop') 
    } 
    task "startTomcat_$name"(type: StartTomcatTask){ 
     node(n) 
    } 
    task "startWorker_$name"(type: StartWorkerTask){ 
     node(n) 
    } 
    task "terminateNode_$name"(type: DeployToNodeTerminationTask){ 
     node(n) 
    } 
} 
task stopScheduler(type: StopSchedulerTask) { 
    environment(environment) 
} 
task startScheduler(type: StartSchedulerTask) { 
    environment(environment) 
} 

默認任務配置爲startScheduler，這是部署過程的最後一步，這個想法因爲任務圖一旦建立，就會照顧我任務的正確執行順序。

但是，當我打印出任務圖時，列出的唯一任務是startScheduler。我錯過了什麼嗎？

Answer 1

感謝Peter Niederwieser和Jeffrey的評論，我能夠想出我想要的完整解決方案。我沒有標註彼得的答案，因爲完整的答案是低於，但它是一個必要的提示正確的解決方案：

我創建了一個接口DependencyAware：

public interface DependencyAware { 
    void declareDependencies() 
} 

每個任務都知道如何聲明它的依賴關係，實現這個接口。例如：

class StartSchedulerTask extends SchedulerTask { 

    @TaskAction 
    void start() { 
     println "Starting quartz on node: ${node}" 
    } 

    void declareDependencies() { 
     dependsOn env.nodes.name.collect {"startTomcat_$it"} 
    } 
} 

在我的構建腳本：

tasks.each { Task t -> 
    if (t instanceof DependencyAware) { 
     t.declareDependencies() 
    } 
} 

這就是它！

感謝您的指針彼得和Jeffrey

更新1

task deploy(dependsOn: ['backupWars', 'startScheduler']) 

task stopScheduler(type: StopSchedulerTask) 

task backupWars(type: BackupWarsTask) 

project.extensions.targetEnvironment.nodes.each { TomcatNode n -> 
    String name = n.name 
    [ 
     ("nodeInit_$name"): DeployToNodeInitTask, 
     ("stopWorker_$name"): StopWorkerTask, 
     ("stopTomcat_$name"): StopTomcatTask, 
     ("updateAppConfigs_$name"): UpdateAppConfigsTask, 
     ("deployWars_$name"): DeployWarsTask, 
     ("startTomcat_$name"): StartTomcatTask, 
     ("startWorker_$name"): StartWorkerTask, 
     ("terminateNode_$name"): DeployToNodeTerminationTask, 
    ].each { String taskName, Class taskType -> 
     task "$taskName"(type: taskType) { 
      node(n) 
     } 
    } 
} 

task startScheduler(type: StartSchedulerTask) { 
    dryRun(testMode) 
} 

不同的部署步驟之間的內在依存關係，是任務本身，例如：

class StartWorkerTask extends WorkerTask { 

    @TaskAction 
    void start() { 
     println "Starting worker ${node}" 
    } 

    void declareDependencies() { 
     dependsOn tomcatOnThisNodeHasBeenStarted() 
    } 

    String tomcatOnThisNodeHasBeenStarted() { 
     "startTomcat_${node.name}" 
    } 
} 

拓撲的聲明如下：

environments { 
    prod { 
     nodes { 
      (1..2).each { int i -> 
       "w${i}_prod" { 
        host = "prod-n$i" 
        userName = "xxxxx" 
        password = "xxxxx" 
        loadBalancer = 'lb_prod' 
        frontendJkManagerUrl = 'http://web01/jkmanager' 
       } 
      } 

      scheduler { 
       name = "w1_prod" 
      } 
     } 
    } 
    rc { 
    //rc topology here 
    } 
} 

Answer 2

這是因爲您在@TaskAction方法中聲明瞭依賴關係。 @TaskAction只在依賴圖形成後運行。

您可能會在您的@TaskActions方法中濫用DoFirst()來調用您的所有依賴關係，但這不會在依賴關係圖上顯示。

Answer 3

任務依賴性必須聲明在配置時間，而不是在執行時間。理論上你可以在任務的構造函數中這樣做，但更好的方法是在構建腳本或插件中執行此操作。