Perl - 從散列哈希中檢索值

我們如何在Perl中檢索哈希散列值中的鍵值？我試圖使用按鍵功能。我想刪除重複項，然後對它們進行排序，我可以使用uniq和sort函數做。我錯過了什麼？Perl - 從散列哈希中檢索值

#!/usr/bin/perl 

use warnings; 
use strict; 

sub ids { 
    my ($data) = @_; 

    my @allID = keys %{$data}; 

    my @unique = uniq @allID; 
    foreach (@unique) { 
     @allUniqueID = $_; 
    } 

    my @result = sort{$a<=>$b}(@allUniqueId); 
    return @result; 
} 

my $data = { 
    'first' => { 
     'second' => { 
      'third1' => [ 
       { id => 44, name => 'a', value => 'aa' }, 
       { id => 48, name => 'b', value => 'bb' }, 
       { id => 100, name => 'c', value => 'cc' } 
      ], 
      id => 19 
     }, 
     'third2' => [ 
      { id => 199, data => 'dd' }, 
      { id => 40, data => 'ee' }, 
      { id => 100, data => { name => 'f', value => 'ff' } } 
     ], 
     id => 55 
    }, 
    id => 1 
}; 

# should print 「1, 19, 40, 44, 48, 55, 100, 199」 
print join(', ', ids($data)) . "\n";

我知道它不完整，但我不知道如何繼續。任何幫助，將不勝感激。

來源

2014-09-29 abc

這個程序將遞歸走路的數據結構和拔出都對應一個哈希鍵id的價值觀，沒有對結果排序或消除重複：

sub all_keys { 
    my $obj = shift; 

    if (ref $obj eq 'HASH') { 
     return map { 
      my $value = $obj->{$_}; 
      $_ eq 'id' ? $value : ref $value ? all_keys($value) :(); 
     } keys %$obj; 

    } elsif (ref $obj eq 'ARRAY') { 
     return map all_keys($_), @$obj; 

    } else { 
     return; 
    } 
}

來進行排序/消滅，只是這樣稱呼它：

my @ids = sort { $a <=> $b } uniq(all_ids($data));

（我假設uniq程序別處定義。）

來源

2014-09-29 06:34:52 Sean

UNIQ是一個內置的，我使用的功能。 – abc 2014-09-29 06:42:41

'uniq'在['List :: Util']（https://metacpan.org/module/List::Util） – Borodin 2014-09-29 08:57:35

這裏是我的v該遞歸方法的版爲

use warnings; 
use strict; 

sub ids { 
    my ($data) = @_; 

    my @retval; 
    if (ref $data eq 'HASH') { 
     push @retval, $data->{id} if exists $data->{id}; 
     push @retval, ids($_) for values %$data; 
    } 
    elsif (ref $data eq 'ARRAY') { 
     push @retval, ids($_) for @$data; 
    } 
    @retval; 
} 

my $data = { 
    'first' => { 
     'second' => { 
      'third1' => [ 
       { id => 44, name => 'a', value => 'aa' }, 
       { id => 48, name => 'b', value => 'bb' }, 
       { id => 100, name => 'c', value => 'cc' } 
      ], 
      id => 19 
     }, 
     'third2' => [ 
      { id => 199, data => 'dd' }, 
      { id => 40, data => 'ee' }, 
      { id => 100, data => { name => 'f', value => 'ff' } } 
     ], 
     id => 55 
    }, 
    id => 1 
}; 

my @ids = sort { $a <=> $b } ids($data); 
print join(', ', @ids), "\n";

輸出

1, 19, 40, 44, 48, 55, 100, 100, 199

更新

在上述方案中的代碼的一個大的塊是有來解決如何以提取數據引用中的值列表。最近版本的Perl有一個實驗工具，它允許你在散列和數組上使用values運算符，並且也可以在兩個引用上使用，所以如果你運行的是Perl 5的版本14或更高版本並且很好地禁用實驗警告，那麼你可以寫ids這樣反而

use warnings; 
use strict; 
use 5.014; 

sub ids { 
    my ($data) = @_; 
    return unless my $type = ref $data; 

    no warnings 'experimental'; 
    if ($type eq 'HASH' and exists $data->{id}) { 
     $data->{id}, map ids($_), values $data; 
    } 
    else { 
     map ids($_), values $data; 
    } 
}

輸出是等同於以前的解決方案

來源

2014-09-29 07:32:21 Borodin

Perl - 從散列哈希中檢索值

回答

相關問題