的Neo4j - 創建從JSON名單

Question

我正在學習如何使用的Neo4j和我使用的一些數據，我有一個JSON文件建立一個比較大的社交網絡關係。

文件結構如下所示：

{ 
    "users": [ 
       {"id":"1", "name":"Bob", friends: ["2","3"]}, 
       {"id":"2", "name":"Alice", friends: ["1"]}, 
       {"id":"3", "name":"Robert", friends: ["1","4","5"]}, 
       ... 
    ]  
} 

繼this guide我設法用下面的Cypher支架查詢創建的所有節點：

WITH {json} AS data 
UNWIND data.users AS user 
MERGE (u:User {user_id: user.id, name: user.name}) 

但現在我卡住了我m不太清楚如何創建friends字段中定義的節點之間的關係。我應該UNWINDfriends字段嗎？我是否應該以某種方式遍歷我創建的每個節點並與其朋友建立關係？也許這是一個基本問題，但我剛剛開始與Cypher。

Answer 1

是的，你應該也UNWINDfriends列。您可以第二次通過同一組數據，通過id找到用戶和他們的朋友，然後將其掛鉤。

像這樣的工作

WITH {json} AS data 
UNWIND data.users AS user 

// for each collection of friends 
UNWIND user.friends as friend 

// find the current user and their friends 
MATCH (u:User {user_id: user.id}), (f:User {user_id: friend}) 
MERGE (u)-[:FRIENDS]-(f) 

更妙的是找到用戶只有一次，而不是每一位朋友，然後每個朋友匹配在一個單獨的條款和掛鉤起來。

WITH {json} AS data 
UNWIND data.users AS user 

// first create/find the user in the graph 
MATCH (u:User {user_id: user.id}) 
WITH user, u 

// iterate through each collection of friends 
UNWIND user.friends as friend 

// find each friend 
MATCH (f:User {user_id: friend}) 

// hook them up 
MERGE (u)-[:FRIENDS]-(f) 

，或者你可以做它在列表中的一個通...

WITH {json} AS data 
UNWIND data.users AS user 

// first create/find the user in the graph 
MERGE (u:User {user_id: user.id}) 
ON CREATE SET u.name = user.name 
WITH u, user 

// iterate through each collection of friends 
UNWIND user.friends as friend 

// find/create stub for each of the friends 
MERGE (f:User {user_id: friend}) 

// hookup friends 
MERGE (u)-[:FRIENDS]-(f)