fortran 90函數的雙精度參數

Question

我試着用gfortran編譯下面的fortran90代碼，這個程序只是輸出雙精度函數distance（）的值，它有7個參數。當我試圖運行它 我得到的消息 「分段錯誤（核心轉儲）」，但如果我重寫

距離（Z1，Z2，Z3，Z4，z5,13.0d0，Z7） 到 距離（Z1 ，z2，z3，z4，z5，z6，z7）其中z6的值爲13.0d0並重新編譯它我得到 正確的值13.000 ...

有誰知道爲什麼？他們看起來和我一樣。謝謝

program distancetest 
implicit none 
double precision::drand,distance 
double precision::z1,z2,z3,z4,z5,z6,z7 
!********************************* 
z1=1.0d0 
z2=1.0d0 
z3=1.0d0 
z4=4.0d0 
z5=5.0d0 
z6=13.0d0 
z7=100.0d0 
write(*,*) distance(z1,z2,z3,z4,z5,13.0d0,z7) 
end program distancetest 
!********************************* 
double precision function distance(x1,y1,z1,x2,y2,z2,l) 
implicit none 
double precision::x1,x2,y1,y2,z1,z2,l,x,y,z 
x1=x1-l*dble(floor(x1/l)) 
y1=y1-l*dble(floor(y1/l)) 
z1=z1-l*dble(floor(z1/l)) 
x2=x2-l*dble(floor(x2/l)) 
y2=y2-l*dble(floor(y2/l)) 
z2=z2-l*dble(floor(z2/l)) 
x=min(abs(x1-x2),l-abs(x1-x2)) 
y=min(abs(y1-y2),l-abs(y1-y2)) 
z=min(abs(z1-z2),l-abs(z1-z2)) 
distance=sqrt(x*x+y*y+z*z) 
end function distance 

Answer 1

函數修改它的所有虛擬參數，條形碼l。將變量以外的任何變量與修改的虛擬參數相關聯是錯誤的。 13.0d0不是一個變量，z6是。

Answer 2

擴展IanH的答案，如果將程序放入模塊並使用這些模塊，以便編譯器可以檢查參數的一致性，並且指定參數意圖，那麼大多數Fortran編譯器都會爲您找到此問題。

module MyFunc 
    implicit none 
contains 
    double precision function distance(x1,y1,z1,x2,y2,z2,l) 
    implicit none 
    double precision, intent (inout)::x1,x2,y1,y2,z1,z2 
    double precision, intent (in) :: l 
    double precision :: x,y,z 
    x1=x1-l*dble(floor(x1/l)) 
    y1=y1-l*dble(floor(y1/l)) 
    z1=z1-l*dble(floor(z1/l)) 
    x2=x2-l*dble(floor(x2/l)) 
    y2=y2-l*dble(floor(y2/l)) 
    z2=z2-l*dble(floor(z2/l)) 
    x=min(abs(x1-x2),l-abs(x1-x2)) 
    y=min(abs(y1-y2),l-abs(y1-y2)) 
    z=min(abs(z1-z2),l-abs(z1-z2)) 
    distance=sqrt(x*x+y*y+z*z) 
    end function distance 
end module MyFunc 


program distancetest 
use MyFunc 
implicit none 
double precision::z1,z2,z3,z4,z5,z6,z7 
!********************************* 
z1=1.0d0 
z2=1.0d0 
z3=1.0d0 
z4=4.0d0 
z5=5.0d0 
z6=13.0d0 
z7=100.0d0 
write(*,*) distance(z1,z2,z3,z4,z5,13.0d0,z7) 
end program distancetest 

例如，來自gfortran：

write(*,*) distance(z1,z2,z3,z4,z5,13.0d0,z7) 
            1 
Error: Non-variable expression in variable definition context (actual argument to INTENT = OUT/INOUT) at (1)