計劃壓縮函數與可能不均勻列表

Question

我知道這個問題已被問及之前，我的解決方案是相同的許多答案，但我有一個特殊的測試用例，不能正常工作與這個問題的常見解決方案。

，我已經找到了許多人一樣的zip問題的解決方案是

(define (zip l1 l2)(map list l1 l2)) 

。 。 。其中與給定的參數如

(zip '(a b c) '(1 2 3)) => ((a 1) (b 2) (c 3)) 

，但我也希望壓縮函數來在我的論據並不像

(zip '(a b c) '(1)) => ((a 1) (b()) (c())) 

匹配長度情況下工作的偉大工程，我還沒有找到一個解決這個問題，並不確定如何處理它，每個列表可以是任意長度。

Answer 1

首先，對於只有2只列出了工作的簡單的迭代版本：

(define (zip lst1 lst2 (placeholder '())) 

    (define (my-car lst) 
    (if (empty? lst) placeholder (car lst))) 
    (define (my-cdr lst) 
    (if (empty? lst) lst (cdr lst))) 

    (let loop ((lst1 lst1) (lst2 lst2) (res '())) 
    (if (and (empty? lst1) (empty? lst2)) 
     (reverse res) 
     (loop (my-cdr lst1) (my-cdr lst2) 
       (cons (list (my-car lst1) (my-car lst2)) res))))) 

如

(zip '(a b c) '(1 2 3)) 
=> '((a 1) (b 2) (c 3)) 

(zip '(a b c) '(1)) 
=> '((a 1) (b()) (c())) 

這個，你可以概括爲n的列表，但要避免關鍵字參數必須先放置佔位符參數：

(define (zip placeholder . lsts) 

    (define (my-car lst) 
    (if (empty? lst) placeholder (car lst))) 
    (define (my-cdr lst) 
    (if (empty? lst) lst (cdr lst))) 

    (let loop ((lsts lsts) (res '())) 
    (if (andmap empty? lsts) 
     (reverse res) 
     (loop (map my-cdr lsts) 
       (cons (apply list (map my-car lsts)) res))))) 

如

(zip '() '(a b c) '(1 2 3)) 
==> '((a 1) (b 2) (c 3)) 

(zip '() '(a b c) '(1)) 
==> '((a 1) (b()) (c())) 

(zip '() '(a b c) '(1) '(x y)) 
=> '((a 1 x) (b() y) (c()())) 

我相信andmap是這裏唯一特定拍功能，它可能有一些計劃或SRFI等值積分，取決於您的實現。

編輯

由於該解決方案的基礎是創建等長的名單，而不是複製壓縮算法，也可以先做經典地圖列表東西前添加佔位符列表：

(define (zip placeholder . lsts) 
    (let* ((max-len (apply max (map length lsts))) ; the length of the longest lists 
     (equal-length-lists      ; adjusts all lists to the same length, 
      (map         ; filling with placeholder 
      (lambda (lst) (append lst (make-list (- max-len (length lst)) placeholder))) 
      lsts))) 
    (apply map list equal-length-lists)))  ; classical zip 

Answer 2

(zip '(a b c) '(1)) =>((a 1) (b()) (c()))（除非您專門使用()作爲佔位符值），它的語義不正確; ((a 1) (b) (c))更合理。下面是實現了一個實現：

(define (zip-with-uneven . lists) 
    (define (advance lst) 
    (if (null? lst) 
     lst 
     (cdr lst))) 
    (define (firsts lists) 
    (let loop ((lists lists) 
       (result '())) 
     (cond ((null? lists) (reverse result)) 
      ((null? (car lists)) (loop (cdr lists) result)) 
      (else (loop (cdr lists) (cons (caar lists) result)))))) 

    (let loop ((lists lists) 
      (results '())) 
    (if (andmap null? lists) 
     (reverse results) 
     (loop (map advance lists) 
       (cons (firsts lists) results))))) 

andmap是從球拍。如果您不使用Racket，則可以使用SRFI 1中的every。

---

如果你真的想使用一個佔位符，這裏有一個（具體球拍）版本支持的佔位符。默認的佔位符是(void)，我認爲這絕不是您想要放入結果列表中的有效值。

(define (zip-with-uneven #:placeholder (ph (void)) . lists) 
    (define (advance lst) 
    (if (null? lst) 
     lst 
     (cdr lst))) 
    (define (cons-with-placeholder a d) 
    (if (void? a) 
     d 
     (cons a d))) 
    (define (firsts lists) 
    (let loop ((lists lists) 
       (result '())) 
     (cond ((null? lists) (reverse result)) 
      ((null? (car lists)) 
      (loop (cdr lists) (cons-with-placeholder ph result))) 
      (else (loop (cdr lists) (cons (caar lists) result)))))) 

    (let loop ((lists lists) 
      (results '())) 
    (if (andmap null? lists) 
     (reverse results) 
     (loop (map advance lists) 
       (cons (firsts lists) results)))))