使用哈希映射並搜索逗號分隔文件

Question

下面是使用正則表達式搜索逗號分隔文件的示例。有誰知道如何將下面的代碼轉換爲哈希映射搜索。如果匹配，代碼應該從兩個文件中返回原始行。

您不必使用散列映射。您的解決方案可以包含任何其他更快的搜索數組的方法，例如grep，hash，智能搜索，第一等。

這些文檔中有成千上萬條記錄。目標是在file1.csv的第3列和file2.csv的第4列中找到類似的項目。如果有匹配，則從兩個文檔中加入這些行。

更新：忘了提，它應打印$一號線，如果它不@ DATA2陣列

my $data_file1 = "file1.csv"; #contains in this file "james,smith,3 kids" 
my $data_file2 = "file2.csv"; #contains in this file "jim,jones,tall,3 kids" 

my $handle1; 
my @temp_data1, @temp_data2; 

open $handle1, '<', $data_file1; 
chomp(@data1 = <$handle1>); 
close $handle1;  

open $handle1, '<', $data_file2; 
chomp(@data2 = <$handle1>); 
close $handle1; 

foreach my $line1 (@data1) 
{ 
    @temp_data1 = split /,/ , $line1; 
    $not_found =1; 
    foreach my $line2 (@data2) 
    {   
     @temp_data2 = split /,/ , $line2; 

     if($temp_data2[3] =~ /$temp_data1[2]$/) 
     { 
      $not_found =0; 
      say $line1 .",". $line2; 
     } 
    } 
    if($not_found) 
    { 
     say "$line1 was not found"; 
    } 
} 

Answer 1

在匹配任何使用鍵字段作爲哈希鍵和行填充的哈希作爲價值。然後瀏覽其他文件，在哈希中查找匹配項。

use Text::CSV_XS qw(); 

@ARGV == 2 
    or die("usage\n"); 

my ($data_file1, $data_file2) = @ARGV; 

open(my $fh1, '<', $data_file1); 
    or die("Can't open \"$data_file1\": $!\n"); 
open(my $fh2, '<', $data_file2); 
    or die("Can't open \"$data_file2\": $!\n"); 

my $csv = Text::CSV_XS->new({ auto_diag => 2, binary => 1 }); 

my %data; 
while (my $row = $csv->getline($fh2)) { 
    $data{ $row->[3] } = $row; 
} 

while (my $row = $csv->getline($fh1)) { 
    if (my $linked_row = $data{ $row->[2] }) { 
     $csv->say(\*STDOUT, [ @$row, @$linked_row ]); 
    } else { 
     $csv->say(\*STDERR, $row); 
    } 
} 

用法：

script file1.csv file2.csv >merged.csv 2>unpaired.csv 

• 假設第一個文件的第三列只包含唯一值。
• 假設第二個文件的第四列僅包含唯一值。

CPU：O（N + M）而不是O（N * M）。
Mem：O（M）代替O（N + M）。
其中N是第一個文件中元素的數量，
而M是第二個文件中元素的數量。

Answer 2

my $data_file1 = "file1.csv"; #contains in this file "james,smith,3 kids" 
my $data_file2 = "file2.csv"; #contains in this file "jim,jones,tall,3 kids" 

my $handle1; 

my %searchHash; 

open $handle1, '<', $data_file1; 
while (my $line = <$handle1>) { 
    chomp($line); 
    $searchHash{(split /,/,$line)[2]} = 0; 
} 
close $handle1;  

open $handle1, '<', $data_file2; 
while (my $line = <$handle1>) { 
    chomp($line); 
    my $key = (split /,/,$line)[3]; 
    $searchHash{$key}++ if(defined $searchHash{$key}); 
} 
close $handle1; 

foreach my $key (keys %searchHash) { 
    print "$key ($searchHash{$key})\n"; 
}