從fla文件到actionscript 3.0中的類

Question

我正在嘗試製作一個「Achtung！die kurve」 - 就像Actionscript 3.0中的遊戲一樣。

到目前爲止，我已經完成了「蠕蟲」之一的運動，並且它工作正常。

我想分成不同的類文件，但我似乎無法得到它的工作。 我有一個.fla文件和4個.as文件。到目前爲止，我只有其中兩個代碼。當我將所有代碼直接放入fla文件中時，它的工作狀況非常好，但是當我將它放入我的播放器類時，它不會「添加孩子」到舞臺上。

這是我的球員。至於文件：http://pastebin.com/hZSxT9cu

爲什麼我評論的的addChild的原因，是因爲我想在我的mainFile.as

這是從主文件做到這一點：http://pastebin.com/TAwUYrTU 我我不太確定如何在主文件中調用它，所以我猜這是問題所在。

所有文件都被命名並正確放置在同一個文件夾中，並且Flash說我的每個.as文件都以.fla文件爲目標，所以這似乎不是問題。

任何幫助，非常感謝。此外，如果有人知道我可以如何改變我的精靈的速度，那真是太棒了！似乎無法讓這個工作。

問候 加斯帕

Answer 1

看着遊戲中你參考，很明顯，你會需要一些碰撞檢測。關於pixel-level collision detection的本教程可能對您的入門有所幫助。

使用您當前的設置，我可以看到提高繪圖速度的唯一方法就是提高幀率。

由於目前無法訪問播放器實例，因此無法將播放器實例作爲子類添加到主類中。實際上，在你的播放器類中創建多個精靈是非常低效的。更有效的方法是直接在播放器實例的圖形實例中繪製矩形。

我認爲以下可能是您嘗試做的一個很好的起點。再次，我已經收錄了一些我希望能解釋我在做什麼的評論。

將此設爲您的FLA的文檔類：

package { 

    import flash.display.MovieClip; 
    import flash.events.KeyboardEvent; 
    import flash.ui.Keyboard; 

    public class MainTrink extends MovieClip { 

     // define a list of players, their color, and controls 
     // this should make it easier to vary the number of players 
     private var players:Array = [ 
      {color: 0xff0000, left: Keyboard.A, right: Keyboard.S}, 
      {color: 0x0000ff, left: Keyboard.O, right: Keyboard.P}, 
      {color: 0x00ff00, left: Keyboard.NUMBER_1, right: Keyboard.NUMBER_2}, 
      {color: 0xffff00, left: Keyboard.LEFT, right: Keyboard.RIGHT}, 
     ]; 

     public function MainTrink() { 

      var playerData:Object; 
      var player:PlayerTrink; 

      // Create a player instance for each player specified in the players array 
      for (var i:int = 0; i < players.length; i ++) 
      { 
       playerData = players[i]; 

       player = new PlayerTrink(); 
       player.color = playerData.color; 
       player.init(); 

       this.addChild(player); 

       // Add a reference to the instance back onto the players 
       // list so that we can access it easily in other methods 
       playerData.player = player; 
      } 

      // add listeners for keyboard events 
      this.stage.addEventListener(KeyboardEvent.KEY_DOWN, _onKeyDown); 
      this.stage.addEventListener(KeyboardEvent.KEY_UP, _onKeyUp); 
     } 

     private function _onKeyDown(event:KeyboardEvent):void 
     { 
      var playerData:Object; 
      var player:PlayerTrink; 

      // Check whether pressed key is a control for one of our players 
      for (var i:int = 0; i < players.length; i ++) 
      { 
       playerData = players[i]; 
       player = PlayerTrink(playerData.player); 

       if (event.keyCode == playerData.left) 
        player.leftKeyDown = true; 

       if (event.keyCode == playerData.right) 
        player.rightKeyDown = true; 
      } 
     } 

     private function _onKeyUp(event:KeyboardEvent):void 
     { 
      var playerData:Object; 
      var player:PlayerTrink; 

      for (var i:int = 0; i < players.length; i ++) 
      { 
       playerData = players[i]; 
       player = PlayerTrink(playerData.player); 

       if (event.keyCode == playerData.left) 
        player.leftKeyDown = false; 

       if (event.keyCode == playerData.right) 
        player.rightKeyDown = false; 
      } 
     } 
    } 

}

，包括在同一目錄中的FLA文件：

package { 

    // Need to import other classes referenced within this class 
    import flash.display.MovieClip; 
    import flash.display.Sprite; 
    import flash.events.KeyboardEvent; 
    import flash.events.Event; 
    import flash.ui.Keyboard; 

    // By convention classes are usually named using CamelCase 
    public class PlayerTrink extends MovieClip { 

     // Move your properties out of your class constructor 
     private const TURNSPEED:Number = 0.1; 

     private var posX:Number = 50; 
     private var posY:Number = 50; 
     private var dirX:Number = 1; 
     private var dirY:Number = 1; 
     private var dir:Number = 0; 

     private var _leftKeyDown:Boolean = false; 
     private var _rightKeyDown:Boolean = false; 

     private var _color:Number; 

     public function PlayerTrink() { 
      // constructor code 
     } 

     public function init():void 
     { 
      this.addEventListener(Event.ENTER_FRAME, _onEnterFrame); 
     } 

     private function _onEnterFrame(e:Event):void { 
      if(_leftKeyDown) dir -= TURNSPEED; 
      if(_rightKeyDown) dir += TURNSPEED; 
      dirX = Math.cos(dir); 
      dirY = Math.sin(dir); 
      posX += dirX; 
      posY += dirY; 
      drawRect(posX, posY); 
     } 

     private function drawRect(x:Number, y:Number):void { 
      this.graphics.beginFill(_color); 
      this.graphics.drawRect(x, y, 4, 4); 
      this.graphics.endFill(); 
     }       

     public function set leftKeyDown(value:Boolean):void 
     { 
      _leftKeyDown = value; 
     } 

     public function set rightKeyDown(value:Boolean):void 
     { 
      _rightKeyDown = value; 
     }     

     public function set color(value:Number):void 
     { 
      _color = value; 
     }   
    } 
}