Excel工作表：將數據從一個工作簿複製到另一個工作簿

Question

我無法將數據從一個工作簿複製到另一個工作簿。但在同一個工作簿中工作。運行宏程序後，目標工作表爲空。我有2個代碼。兩者都不起作用。我的源文件是.xlsx格式和目標文件是.xlsm格式。有什麼錯誤嗎？

代碼1：

Sub mycode() 

Workbooks.Open Filename:="source_file" 
Worksheets("Sheet1").Cells.Select 
Selection.Copy 


Workbooks.Open Filename:="destination_file" 
Worksheets("Sheet1").Cells.Select 
Selection.PasteSpecial 
ActiveWorkbook.Save 


End Sub 

代碼2

Sub foo2() 
Dim x As Workbook 
Dim y As Workbook 

Set x = Workbooks.Open("source file") 
Set y = Workbooks.Open("destination file") 

y.Sheets("Sheet1").Range("A1").Value = x.Sheets("Sheet1").Range("A1") 

x.Close 

End Sub 

Answer 1

我假設你正在寫下面代碼1和代碼2 Excel宏在單獨的文件，說copy_paste.xlsm：

代碼1工作時，您提供給Workbooks.open文件的完整路徑：

Sub mycode() 

Workbooks.Open Filename:="C:\Users\xyz\Documents\Excel-Problem\source_file.xlsx" 
Worksheets("Sheet1").Cells.Select 
Selection.Copy 

Workbooks.Open Filename:="C:\Users\xyz\Documents\Excel-Problem\destination_file.xlsm" 
Worksheets("Sheet1").Cells.Select 
Selection.PasteSpecial xlPasteValues    'xlPasteAll to paste everything 
ActiveWorkbook.Save 

ActiveWorkbook.Close SaveChanges:=True    'to close the file 
Workbooks("source_file").Close SaveChanges:=False 'to close the file 

End Sub 

要粘貼的一切（公式+值+格式），用漿糊類型xlPasteAll。

代碼2是工作壓力太大，你需要的是提供完整路徑和您在文件名失蹤_：

Sub foo2() 
Dim x As Workbook 
Dim y As Workbook 

Set x = Workbooks.Open("C:\Users\xyz\Documents\Excel-Problem\source_file.xlsx") 
Set y = Workbooks.Open("C:\Users\xyz\Documents\Excel-Problem\destination_file.xlsm") 

'it copies only Range("A1") i.e. single cell 
y.Sheets("Sheet1").Range("A1").Value = x.Sheets("Sheet1").Range("A1") 

x.Close SaveChanges:=False 
y.Close SaveChanges:=True 

End Sub 

Answer 2

編輯添加（最小）文件檢查

你必須指定完整的文件路徑，名稱和擴展名

你可以只打開目標文件，像這樣

Option Explicit 

Sub foo2() 
    Dim y As Workbook 
    Dim sourcePath As String, sourceFile As String, destFullPath As String '<--| not necessary, but useful not to clutter statements 

    sourcePath = "C:\Users\xyz\Documents\Excel-Problem\" '<--| specify your source file path down to the last backslash and with no source file name 
    sourceFile = "source_file.xlsx" '<--| specify your source file name only, with its extension 
    destFullPath = "C:\Users\xyz\Documents\Excel-Problem\destination_file.xlsm" '<--| specify your destination file FULL path 

    If Dir(destFullPath) = "" Then '<--| check is such a file actually exists 
     MsgBox "File " & vbCrLf & vbCrLf & destFullPath & vbCrLf & vbCrLf & "is not there!" & vbCrLf & vbCrLf & vbCrLf & "The macro stops!", vbCritical 
    Else 
     Set y = Workbooks.Open(destFullPath) 

     With y.Sheets("Sheet1").Range("A1") 
      .Formula = "='" & sourcePath & "[" & sourceFile & "]Sheet1'!$A$1" 
      .Value = .Value 
     End With 

     y.Close SaveChanges:=True 
    End If 
End Sub 

，你可以使用Excel4macro