Applescript度假村堆數字

Question

我想訴諸一堆數字與Applescript。我對這門語言很陌生，我想我會請你幫忙。

我有一組數字，看起來像這樣在我的文本編輯文件：

v 0.186472 0.578063 1.566364 
v -0.186472 0.578063 1.566364 
v 0.335649 0.578063 1.771483 

我需要的是，求助於這些數字的腳本，使它看起來像這樣：

(0.186472, 0.578063, 1.566364), 
(-0.186472, 0.578063, 1.566364), 
(0.335649, 0.578063, 1.771483), 

所以在每個數字之後，必須有一個逗號，並且總是必須將一行中的三個數字放在括號（）中。最後，在每一行必須被刪除之前，每個括號中的三個組和v之後必須有另一個逗號。

我只到目前爲止設法擺脫每一個「V」使用：

set stringToFind to "v" 
set stringToReplace to "" 

但我現在卡住了，我希望尋求幫助。

Answer 1

要在AppleScript中查找和替換字符串，原生方法是使用text item delimiters。在每行上有用空格（或製表符）分隔的固定數量的值，使用text item delimiters,text items和字符串連接我們可以解決您的問題。

我在字符串的前面和後面添加了換行，以顯示不包含4個單詞的行被忽略。

set theString to " 
v 0.186472 0.578063 1.566364 
v -0.186472 0.578063 1.566364 
v 0.335649 0.578063 1.771483 
" 
set theLines to paragraphs of theString 

set oldTIDs to AppleScript's text item delimiters 


repeat with i from 1 to count theLines 
    set AppleScript's text item delimiters to {space, tab} 
    if (count of text items of item i of theLines) = 4 then 
     set theNumbers to text items 2 thru -1 of item i of theLines 
     set AppleScript's text item delimiters to ", " 
     set item i of theLines to "(" & (theNumbers as string) & ")," 
    else 
     set item i of theLines to missing value 
    end if 
end repeat 

set theLines to text of theLines 
set AppleScript's text item delimiters to linefeed 
set newString to theLines as string 
set AppleScript's text item delimiters to oldTIDs 
return newString