AppData \ LocalLow常量？

Question

目前訪問LocalLow我用這個：

{%USERPROFILE}\AppData\LocalLow 

但我想知道是否有用於在INNO一組常數，因爲這兩個Roaming和Local有一個。

Answer 1

AppData\LocalLow沒有常數。

您可以使用Pascal腳本來解決它。

要解決「LocalLow」，必須使用SHGetKnownFolderPath。
另請參閱Detect the location of AppData\LocalLow。

由於在Unicode Inno Setup中缺少（廣泛的）PChar類型，因此實施涉及很少的黑客行爲。

const 
    MAX_PATH = 260; 
    AppDataLocalLowGUID = '{A520A1A4-1780-4FF6-BD18-167343C5AF16}'; 

{ There's no PChar in Unicode Inno Setup, } 
{ pretend the function returns a pointer to an Integer } 
function SHGetKnownFolderPath(rfid: TGUID; dwFlags: DWORD; hToken: THandle; 
    var ppszPath: Integer): Integer; 
    external 'SHGetKnownFolderPath@Shell32.dll stdcall'; 

{ And allow the Integer to be copied to string } 
function StrCpy(Dest: string; Source: Integer): Integer; 
    external 'StrCpyW@Shlwapi.dll stdcall'; 

{ And allow the Integer pointer to be released } 
procedure CoTaskMemFreeAsInteger(pv: Integer); 
    external 'CoTaskMemFree@Ole32.dll stdcall'; 

function GetAppDataLocalLow: string; 
var 
    Path: Integer; 
    I: Integer; 
begin 
    if SHGetKnownFolderPath(StringToGUID(AppDataLocalLowGUID), 0, 0, Path) = 0 then 
    begin 
    { The path should not be longer than MAX_PATH } 
    SetLength(Result, MAX_PATH); 

    StrCpy(Result, Path); 

    CoTaskMemFreeAsInteger(Path); 

    { Look for NUL character and adjust the length accordingly } 
    for I := 1 to MAX_PATH do 
    begin 
     if Result[I] = #0 then 
     begin 
     SetLength(Result, I - 1); 
     Break; 
     end; 
    end; 
    end; 
end; 

---

如果您需要使用非Code部分的路徑（Pascal腳本之外），你可以使用一個scripted constant：

[Files] 
Source: myfile.txt; DestDir: {code:GetAppDataLocalLow} 

而且你需要更改功能簽名採取虛擬參數：

function GetAppDataLocalLow(Param: string): string; 

Answer 2

例如，刪除文件時卸載m LocalLow with INNO：

[UninstallDelete] 
Type: filesandordirs; Name: "{userappdata}\..\LocalLow\MyFile.txt"