Clojure：在循環另一個集合的同時循環一個集合？

Question

我有兩個系列x和y，都有不同數量的項目。我想通過x循環，並做一些副作用，而通過y騎自行車。我不想在通過x循環時重複y。既doseq和for重複y：

(for [x (range 5) 
     y ["A" "B"]] 
    [x y]) 

這產生([0 "A"] [0 "B"] [1 "A"] [1 "B"] [2 "A"] [2 "B"] [3 "A"] [3 "B"] [4 "A"] [4 "B"])。

我想要的是會產生的東西：([0 "A"] [1 "B"] [2 "A"] [3 "B"] [4 "A"])。

背景，我有一個文件行和core.async渠道（比如5），我希望把每行到下一個通道在我的收藏，是這樣的：

(defn load-data 
    [file chans] 
    (with-open [rdr (io/reader file)] 
    (go 
     (doseq [l (line-seq rdr) 
       ch chans] 
     (>! ch l))))) 

Answer 1

如果傳遞到多個序列map它在鎖步驟中逐步通過它們中的每一個來調用具有來自每個當前位置的值的映射函數。當其中一個序列用完時停止。

user> (map vector (range 5) (cycle ["A" "B"])) 
([0 "A"] [1 "B"] [2 "A"] [3 "B"] [4 "A"]) 

在這種情況下，從(cycle ["A" "B"])序列將繼續生產As和燒烤永遠雖然地圖會停止食用它們(range 5)結束序列時。每一步然後用這兩個參數調用向量函數，並將結果添加到輸出序列中。

和第二例使用去環是散開的輸入序列的一個相當標準的方法：

user> (require '[clojure.core.async :refer [go go-loop <! <!! >!! >! chan close!]]) 
nil 
user> (defn fanout [channels file-lines] 
     (go-loop [[ch & chans] (cycle channels) 
        [line & lines] file-lines] 
      (if line 
      (do 
       (>! ch line) 
       (recur chans lines)) 
      (doseq [c channels] 
       (close! c))))) 
#'user/fanout 
user> (def lines ["first" "second" "third" "fourth" "fifth"]) 
#'user/lines 
user> (def test-chans [(chan) (chan) (chan)]) 
#'user/test-chans 
user> (fanout test-chans lines) 
#<ManyToManyChannel clojure.core.async.impl.channels.ManyToManyChannel@3b363fc5> 
user> (map <!! test-chans) 
("first" "second" "third") 
user> (map <!! test-chans) 
("fourth" "fifth" nil)