使用perl的未知二維數組的所有可能的陣列組合

Question

我正嘗試爲使用用戶輸入文件生成的二維數組生成所有可能的組合。我需要用perl來獲得這個。 例如：

假設從輸入文件所形成的2D陣列是這樣的 -

[a, b, c] 
[d, e] 
[f, g] 

此輸入的預期輸出是如下 -

[a, d, f] 
[a, d, g] 
[a, e, f] 
[a, e, g] 
[b, d, f] 
[b, d, g] 
[b, e, f] 
[b, e, g] 
[c, d, f] 
[c, d, g] 
[c, e, f] 
[c, e, g] 

自一個用戶輸入文件的數目行和列可以是任何東西，因此我無法使用固定數量的循環來創建這種組合。

Answer 1

以下是查看它的一種方法。如果你已經有一些數字陣列的結果和需要增加的額外一個，你會做這樣的事情：

sub get_combinations { 
    my ($existing_results, $new_array) = @_; 
    my $new_results; 
    for my $existing_result (@$existing_results) { 
     for my $value (@$new_array) { 
      push @$new_results, [ @$existing_result, $value ]; 
     } 
    } 
    return $new_results; 
} 

現在，你可以簡單地循環在你的二維數組：

​​

Answer 2

你想cartesian product，

使用CPAN模塊，

use Set::CrossProduct; 

my @arr = (
    [qw(a b c)], 
    [qw(d e)], 
    [qw(f g)], 
); 
my $iterator = Set::CrossProduct->new(\@arr); 

use Data::Dumper; 
print Dumper $iterator->combinations; 

或

use strict; 
use warnings; 

my @arr = (
    [qw(a b c)], 
    [qw(d e)], 
    [qw(f g)], 
); 

local $" = ", "; 
for my $aref (getCartesian(@arr)) { 
    print "[@$aref]\n"; 
} 

sub getCartesian { 
# 
    my @input = @_; 
    my @ret = map [$_], @{ shift @input }; 

    for my $a2 (@input) { 
    @ret = map { 
     my $v = $_; 
     map [@$v, $_], @$a2; 
    } 
    @ret; 
    } 
    return @ret; 
} 

輸出

[a, d, f] 
[a, d, g] 
[a, e, f] 
[a, e, g] 
[b, d, f] 
[b, d, g] 
[b, e, f] 
[b, e, g] 
[c, d, f] 
[c, d, g] 
[c, e, f] 
[c, e, g] 

Answer 3

這裏的另一種選擇：

use strict; 
use warnings; 
use v5.14; 

my @arr = ([qw(a b c)], [qw(d e)], [qw(f g)]); 

print "[$_]\n" for map s/-/, /gr, glob 
    join '-', map { '{' . (join ',', @$_) . '}' } @arr; 

輸出：

[a, d, f] 
[a, d, g] 
[a, e, f] 
[a, e, g] 
[b, d, f] 
[b, d, g] 
[b, e, f] 
[b, e, g] 
[c, d, f] 
[c, d, g] 
[c, e, f] 
[c, e, g]